TEMPLATE = app
TARGET = hyperui
DEPENDPATH += .

target.path = $$PREFIX/bin
INSTALLS += target

include(../shared/shared.pri)

symbian {
    TARGET.UID3 = 0xe1234569
    ICON = hyperui.svg
    isEmpty(RESOLUTION) {
        RESOLUTION = "640x360"
    }
}

HEADERS += mainwindow.h \
           pagemenu.h \
           view.h \
           global.h \
           pageview.h \
           menuview.h \
           phoneview.h \
           draggablepreview.h \
           clockwidget.h \
           contactlist.h \
           contactresource.h \
           ../shared/utils.h \
           ../shared/button.h \
           ../shared/label.h \
           ../shared/scrollarea.h \
           ../shared/pixmapwidget.h \
           ../shared/kineticscroll.h \
           ../shared/dataresource.h

SOURCES += main.cpp \
           mainwindow.cpp \
           pagemenu.cpp \
           view.cpp \
           global.cpp \
           pageview.cpp \
           menuview.cpp \
           phoneview.cpp \
           draggablepreview.cpp \
           clockwidget.cpp \
           contactlist.cpp \
           contactresource.cpp \
           ../shared/utils.cpp \
           ../shared/button.cpp \
           ../shared/label.cpp \
           ../shared/scrollarea.cpp \
           ../shared/pixmapwidget.cpp \
           ../shared/kineticscroll.cpp \
           ../shared/dataresource.cpp

isEmpty(RESOLUTION) {
    RESOLUTION = "800x480"
}

!isEmpty(USE_RASTER) {
    DEFINES += USE_RASTER_GRAPHICS_SYSTEM
}

RESOURCES = resource/$$RESOLUTION/hyperui.qrc