blob: 80ae4dce45b17f21fe6aef4bc82a9dfe12a53ec0 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
|
TEMPLATE = lib
TARGET = translationplugin
QT += qml quick
CONFIG += qt plugin c++11
uri = com.pelagicore.translation
load(qmlplugin)
SOURCES += \
plugin.cpp \
translation.cpp \
HEADERS += \
translation.h \
# var, prepend, append
defineReplace(prependAll) {
for(a,$$1):result += $$2$${a}$$3
return($$result)
}
assetsPath = $$PWD/../../imports/assets
qmlSysUiPath = $$PWD/../../sysui
# See qml files to scan while running lupdate/lrelease
lupdate_only {
SOURCES += $$files($$shell_quote($$shell_path($${qmlSysUiPath}/))*.qml, true)
}
target.path = $$installPath
supportedLocales = \
de_DE \
en_GB \
en_US \
in_ID
TRANSLATIONS = $$prependAll(supportedLocales, $$assetsPath/translations/, .ts)
qtPrepareTool(LUPDATE, lupdate)
qtPrepareTool(LRELEASE, lrelease)
ts.commands = $$LUPDATE $$shell_quote($$_PRO_FILE_)
QMAKE_EXTRA_TARGETS += ts
qm.input = TRANSLATIONS
qm.output = $$shadowed($$assetsPath/translations)/${QMAKE_FILE_BASE}.qm
qm.variable_out = PRE_TARGETDEPS
qm.commands = $${LRELEASE} -idbased ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
qm.name = LRELEASE ${QMAKE_FILE_IN}
qm.CONFIG += no_link
QMAKE_EXTRA_COMPILERS += qm
qmfiles.files = $$prependAll(supportedLocales, $$shadowed($$assetsPath/translations)/, .qm)
qmfiles.path = $$INSTALL_PREFIX/neptune/imports/assets/translations
qmfiles.CONFIG += no_check_exist
INSTALLS += qmfiles
|
