qml_pkg.pri


1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38

# Manages deploying the QML files and resources along with the binary

mt {
    distInstalls.files = qml
    distInstalls.path = /opt/mt/applications/$$TARGET
    INSTALLS += distInstalls
} else {
    distInstalls.files = qml
    distInstalls.path = $$QT3D_INSTALL_DATA/quick3d/examples/$$TARGET
    INSTALLS += distInstalls
}

win32 {
    QMAKE_DEL_FILE = del /q
    QMAKE_DEL_DIR = rmdir /s /q
}

qmlResources.files = qml
symbian {
    DEPLOYMENT += qmlResources
    qmlDeployment.sources = qml\*
    qmlDeployment.path = qml
    DEPLOYMENT += qmlDeployment
} else {
    macx {
        qmlResources.path = Contents/Resources
        QMAKE_BUNDLE_DATA += qmlResources
    } else {
        !package {
            qmlResources.input = qmlResources.files
            qmlResources.output = $$OUT_PWD/../../../bin/resources/examples/$$TARGET/qml
            qmlResources.commands = $$QMAKE_COPY_DIR ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
            qmlResources.CONFIG += no_link_no_clean
            qmlResources.variable_out = POST_TARGETDEPS
            QMAKE_EXTRA_COMPILERS += qmlResources
        }
    }
}