/****************************************************************************
**
** Copyright (c) 2011 Nokia Corporation and/or its subsidiary(-ies).
** All rights reserved.
** Contact: Yoann Lopes (yoann.lopes@nokia.com)
**
** This file is part of the MeeSpot project.
**
** Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions
** are met:
**
** Redistributions of source code must retain the above copyright notice,
** this list of conditions and the following disclaimer.
**
** Redistributions in binary form must reproduce the above copyright
** notice, this list of conditions and the following disclaimer in the
** documentation and/or other materials provided with the distribution.
**
** Neither the name of Nokia Corporation and its Subsidiary(-ies) nor the names of its
** contributors may be used to endorse or promote products derived from
** this software without specific prior written permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
** FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** HOLDER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED
** TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
** PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
** LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
** NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
** SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
**
** If you have questions regarding the use of this file, please contact
** Nokia at qt-info@nokia.com.
**
****************************************************************************/


import QtQuick 1.1
import com.nokia.meego 1.0
import "UIConstants.js" as UI

Rectangle {
    id: player
    width: parent.width
    height: screen.currentOrientation == Screen.Portrait ? 818 : 444
    color: theme.inverted ? UI.COLOR_INVERTED_BACKGROUND : UI.COLOR_BACKGROUND
    y: -height

    property bool openRequested: false
    property bool hidden: true
    property bool inOpenPosition: y > -quickControls.y

    property bool openedOnce: false
    onOpenRequestedChanged: if (openRequested) openedOnce = true

    MouseArea {
        anchors.fill: parent
    }

    FullControls {
        id: fullControls
        anchors.top: parent.top
        anchors.bottom: quickControls.top
    }

    QuickControls {
        id: quickControls
        anchors.bottom: parent.bottom
    }

    states: [
        State {
            when: openRequested && !hidden
            name: "open"
            PropertyChanges { target: player; y: 0 }
        },
        State {
            when: !openRequested && !hidden
            name: "small"
            PropertyChanges { target: player; y: -quickControls.y }
        }
    ]

    transitions: Transition {
        NumberAnimation { properties: "y"; easing.type: Easing.OutQuart; duration: 500 }
    }

    Connections {
        target: spotifySession
        onCurrentTrackChanged: hidden = !spotifySession.hasCurrentTrack
    }

    onHiddenChanged: {
        if (hidden)
            openRequested = false;
    }
}