blob: ceadb08bcc67204a6f1384a05ceafc07ef9cf7f5 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
|
TEMPLATE = app
TARGET = shoppinglist
# All generated files goes same directory
OBJECTS_DIR = build
MOC_DIR = build
UI_DIR = build
DESTDIR = build
linux-g++-maemo5 {
INSTALLS += desktop
desktop.path = /usr/share/applications/hildon
desktop.files = data/shoppinglist.desktop
INSTALLS += icon64
icon64.path = /usr/share/icons/hicolor/64x64/apps
icon64.files = data/icon-shoppinglist.png
INSTALLS += confFile
confFile.path = /usr/share/applications
confFile.files = data/shoppinglist.conf
INSTALLS += script
script.path = /usr/bin/
script.files = shoppinglist
}
include(src/src.pri)
include(../shared/shared.pri)
HEADERS += ../shared/scrollbar.h \
../shared/flickablearea.h \
../shared/pageslider.h \
../shared/lineedit.h
SOURCES += ../shared/scrollbar.cpp \
../shared/flickablearea.cpp \
../shared/pageslider.cpp \
../shared/lineedit.cpp
target.path = $$PREFIX/bin
INSTALLS += target
QMAKE_MACOSX_DEPLOYMENT_TARGET = 10.5
# S60
symbian {
RESOLUTION = "640x360"
TARGET = shoppinglist
TARGET.EPOCHEAPSIZE = 0x20000 0x2000000
TARGET.UID3 = 0xe123459a
ICON = data/icon-shoppinglist.svg
shoppinglist.sources = data/shoppinglist.conf
shoppinglist.path = c:\\DATA\\.config\\openBossa
DEPLOYMENT += shoppinglist
}
# Maemo 5
linux-g++-maemo5{
# Targets for debian source and binary package creation
debian-src.commands = dpkg-buildpackage -S -r -us -uc -d
debian-bin.commands = dpkg-buildpackage -b -r -uc -d
debian-all.depends = debian-src debian-bin
# Clean all but Makefile
compiler_clean.commands = -$(DEL_FILE) $(TARGET)
QMAKE_EXTRA_TARGETS += debian-all debian-src debian-bin compiler_clean
}
isEmpty(RESOLUTION) {
RESOLUTION = "800x480"
}
isEqual(RESOLUTION, "800x480") {
DEFINES += DISPLAY_WIDTH=480 DISPLAY_HEIGHT=800
DEFINES += X_SCALE=1 Y_SCALE=1
} else:isEqual(RESOLUTION, "640x360") {
DEFINES += DISPLAY_WIDTH=360 DISPLAY_HEIGHT=640
DEFINES += X_SCALE=0.75 Y_SCALE=0.75
}
RESOURCES = resource/$$RESOLUTION/resources.qrc
|