SRCDIR=$$replace(OUT_PWD, $$BUILDROOT, $$SRCROOT)
BUILDDIR=$$OUT_PWD

TEMPLATE=subdirs

unix:!mac:!symbian {
    symlink.commands =                                           \
        if  [ ! -h $$BUILDDIR/$$SOURCES -a $$BUILDDIR/$$SOURCES != $$SRCDIR/$$SOURCES ]; then                   \
            ln -sf $$SRCDIR/$$SOURCES $$BUILDDIR/$$SOURCES;      \
        fi
    QMAKE_EXTRA_TARGETS+=symlink

#    testapp_symlink.commands =                                   \
#        for app in $$TESTAPPS; do                                \
#            APPPATH=$$BUILDROOT/tests/qtuitest/testapps/\$\$app; \
#            [ -d \$\$APPPATH ] || continue;                      \
#            ln -sf \$\$APPPATH/\$\$app $$BUILDDIR/\$\$app;       \
#        done
#    QMAKE_EXTRA_TARGETS+=testapp_symlink

    test.commands = PATH=$$BUILDDIR:$$BUILDROOT/bin:\$\$PATH QTUITEST_INCLUDE_PATH=$$SRCROOT/tests/shared:\$\$QTUITEST_INCLUDE_PATH $$[QT_INSTALL_BINS]/qtuitestrunner $$BUILDDIR/$$SOURCES $(ARGS)
#    test.depends = symlink testapp_symlink
    test.depends = symlink
    QMAKE_EXTRA_TARGETS+=test

    storetest.commands = PATH=$$[QT_INSTALL_BINS]:$$BUILDDIR/bin:\$\$PATH BUILDDIR=$$BUILDDIR perl $$SRCROOT/scripts/storetest.pl $$BUILDDIR/$$SOURCES $(ARGS)
    storetest.depends = symlink
    QMAKE_EXTRA_TARGETS+=storetest
}

mac {
    symlink.commands = ln -sf $$SRCDIR/$$SOURCES $$BUILDDIR/$$SOURCES
    QMAKE_EXTRA_TARGETS+=symlink

    testapp_symlink.commands =                                   \
        for app in $$TESTAPPS; do                                \
            APPPATH=$$BUILDROOT/tests/qtuitest/testapps/\$\$app; \
            [ -d \$\$APPPATH ] || continue;                      \
            ln -sf \$\$APPPATH/\$\$app $$BUILDDIR/\$\$app;       \
        done
    QMAKE_EXTRA_TARGETS+=testapp_symlink

    test.commands = PATH=$$BUILDDIR:\$\$PATH QTUITEST_INCLUDE_PATH=$$SRCROOT/tests/shared:\$\$QTUITEST_INCLUDE_PATH DYLD_LIBRARY_PATH=$$BUILDROOT/lib:\$\$DYLD_LIBRARY_PATH $$BUILDROOT/bin/qtuitestrunner $$BUILDDIR/$$SOURCES $(ARGS)
    test.depends = symlink testapp_symlink
    QMAKE_EXTRA_TARGETS+=test
}

win32 {
    WIN_SRCDIR=$$replace(SRCDIR,/,\)
    WIN_INSTALLROOT=$$replace(INSTALLROOT,/,\)
    WIN_BUILDDIR=$$replace(BUILDDIR,/,\)
    WIN_SRCROOT=$$replace(SRCROOT,/,\)

    test.commands=cmd /c set PATH=$${WIN_INSTALLROOT};%PATH% && $${WIN_INSTALLROOT}\\qtuitestrunner $${WIN_SRCDIR}\\$${SOURCES}
    QMAKE_EXTRA_TARGETS+=test

    storetest.commands=cmd /s/c \"PATH $${WIN_INSTALLROOT};%PATH%&& set BUILDDIR=$$BUILDDIR&& perl $$WIN_SRCROOT\\scripts\\storetest.pl $${WIN_SRCDIR}\\$${SOURCES}\"
    QMAKE_EXTRA_TARGETS+=storetest
}