TEMPLATE=lib
CONFIG+=plugin
SOURCES+=style.cpp
HEADERS+=style.h
TARGET=qtuiteststyle
TARGET=$$qtLibraryTarget($$TARGET)
QT+=network
INCLUDEPATH+=$$SRCROOT/libqtslave
INCLUDEPATH+=$$SRCROOT/libqtuitest
INCLUDEPATH+=$$SRCROOT
DEPENDPATH+=$$SRCROOT

unix:!symbian {
    MOC_DIR=$$OUT_PWD/.moc
    OBJECTS_DIR=$$OUT_PWD/.obj
    target.path=$$[QT_INSTALL_PLUGINS]/styles
    INSTALLS+=target
    !mac {
        LIBS+=-L$$BUILDROOT/lib -lqtslave -lqtuitest
    }
}

symbian {
    TARGET.EPOCALLOWDLLDATA=1
    TARGET.CAPABILITY += AllFiles ReadDeviceData ReadUserData SwEvent WriteUserData NetworkServices
    MOC_DIR=$$OUT_PWD/moc
    OBJECTS_DIR=$$OUT_PWD/obj
    LIBS+=-lqtuitest.lib -lqtslave.lib -lws32 -leuser -lcone
}

mac {
    CONFIG(debug,debug|release): LIBS += -L$$BUILDROOT/lib -lqtslave_debug -lqtuitest_debug
    CONFIG(release,debug|release): LIBS += -L$$BUILDROOT/lib -lqtslave -lqtuitest
    target.path=$$[QT_INSTALL_PLUGINS]/styles
    INSTALLS+=target
}

win32 {
    CONFIG(debug,debug|release):  LIBS+=-L$$BUILDROOT/libqtuitest -L$$BUILDROOT/libqtslave/debug -lqtuitestd -lqtslaved
    CONFIG(release,debug|release):LIBS+=-L$$BUILDROOT/libqtuitest -L$$BUILDROOT/libqtslave/release -lqtuitest -lqtslave
    target.path=$$[QT_INSTALL_PLUGINS]/styles
    INSTALLS+=target
}