TEMPLATE=subdirs
SUBDIRS=lib qtslave qtwidgets qgraphicsviewwidgets hbwidgets qtbindings libqsystemtest interpreter 
CONFIG+=ordered

system(echo DEFINES+=QTUITEST_IMAGE_PATH=$$OUT_PWD > $$OUT_PWD/.qmake.cache)
system(echo QMAKEFEATURES+=$$PWD/features:$HB_INSTALL_DIR:$HB_SOURCE_DIR >> $$OUT_PWD/.qmake.cache)

unix:!mac:!symbian {
    SUBDIRS+=style tests examples
    system(if ! [ -e $$OUT_PWD/features ]; then ln -sf $$PWD/features $$OUT_PWD/features; fi)
    system(echo SRCROOT=$(readlink -f $$PWD) >> $$OUT_PWD/.qmake.cache)
    system(echo BUILDROOT=$(readlink -f $$OUT_PWD) >> $$OUT_PWD/.qmake.cache)
}

mac {
    SUBDIRS+=style tests
    system(if ! [ -e $$OUT_PWD/features ]; then ln -sf $$PWD/features $$OUT_PWD/features; fi)
    system(echo SRCROOT='$$PWD' >> $$OUT_PWD/.qmake.cache)
    system(echo BUILDROOT='$$OUT_PWD' >> $$OUT_PWD/.qmake.cache)
}

symbian {
    SUBDIRS-=qgraphicsviewwidgets qtbindings libqsystemtest interpreter
    SUBDIRS+=style
    system(echo SRCROOT=$$PWD >> $$OUT_PWD/.qmake.cache)
    system(echo BUILDROOT=$$OUT_PWD >> $$OUT_PWD/.qmake.cache)
}

win32 {
    SUBDIRS+=style tests
    WIN_PWD=$$replace(PWD,/,\)
    WIN_OUT_PWD=$$replace(OUT_PWD,/,\)
    system(xcopy $$WIN_PWD\features $$WIN_OUT_PWD\features /E /I /D /Y)
    system(echo SRCROOT=$$PWD >> $$OUT_PWD/.qmake.cache)
    system(echo BUILDROOT=$$OUT_PWD >> $$OUT_PWD/.qmake.cache)
    system(echo INSTALLROOT=$$OUT_PWD/bin >> $$OUT_PWD/.qmake.cache)
}