1 files changed, 64 insertions, 0 deletions
diff --git a/doc/doc.pri b/doc/doc.pri
new file mode 100644
index 000000000..b37049592
--- /dev/null
+++ b/doc/doc.pri
@@ -0,0 +1,64 @@
+# Adapted from doc/doc.pri in Qt Creator.
+
+QDOC_BIN = $$[QT_INSTALL_BINS]/qdoc3
+win32:QDOC_BIN = $$replace(QDOC_BIN, "/", "\\")
+
+unix {
+    QDOC = SRCDIR=$$PWD OUTDIR=$$OUT_PWD/doc/html QT_MOBILITY_SOURCE_PATH=$$QT_MOBILITY_SOURCE_PATH $$QDOC_BIN
+    HELPGENERATOR = $$[QT_INSTALL_BINS]/qhelpgenerator
+} else {
+    QDOC = set SRCDIR=$$PWD&& set OUTDIR=$$OUT_PWD/doc/html&& set QT_MOBILITY_SOURCE_PATH=$$QT_MOBILITY_SOURCE_PATH&& $$QDOC_BIN
+    # Always run qhelpgenerator inside its own cmd; this is a workaround for
+    # an unusual bug which causes qhelpgenerator.exe to do nothing
+    HELPGENERATOR = cmd /C $$replace($$list($$[QT_INSTALL_BINS]/qhelpgenerator.exe), "/", "\\")
+}
+
+QHP_FILE = $$OUT_PWD/doc/html/installerfw.qhp
+QCH_FILE = $$OUT_PWD/doc/installerfw.qch
+
+HELP_DEP_FILES = $$PWD/installerfw.qdoc \
+                 $$PWD/scripting.qdoc \
+                 $$PWD/installerfw.qdocconf
+
+unix {
+html_docs.commands = $$QDOC $$PWD/installerfw.qdocconf
+} else {
+html_docs.commands = \"$$QDOC $$PWD/installerfw.qdocconf\"
+}
+html_docs.depends += $$HELP_DEP_FILES
+html_docs.files = $$QHP_FILE
+
+unix {
+html_docs_online.commands = $$QDOC $$PWD/installerfw.qdocconf
+} else {
+html_docs_online.commands = \"$$QDOC $$PWD/installerfw.qdocconf\"
+}
+html_docs_online.depends += $$HELP_DEP_FILES
+html_docs_online.files = $$QHP_FILE
+
+qch_docs.commands = $$HELPGENERATOR -o $$QCH_FILE $$QHP_FILE
+qch_docs.depends += html_docs
+qch_docs.files = $$QCH_FILE
+
+unix:!macx {
+    qch_docs.path = $$PREFIX/doc
+    qch_docs.CONFIG += no_check_exist
+    INSTALLS += qch_docs
+}
+
+docs_online.depends = html_docs_online
+QMAKE_EXTRA_TARGETS += html_docs_online docs_online
+
+macx {
+    DOC_DIR = "$${OUT_PWD}/bin/Simulator.app/Contents/Resources/doc"
+    cp_docs.commands = mkdir -p \"$${DOC_DIR}\" ; $${QMAKE_COPY} \"$${QCH_FILE}\" \"$${DOC_DIR}\"
+    cp_docs.depends += qch_docs
+    docs.depends = cp_docs
+    QMAKE_EXTRA_TARGETS += html_docs qch_docs cp_docs docs ht
+}
+!macx {
+    docs.depends = qch_docs
+    QMAKE_EXTRA_TARGETS += html_docs qch_docs docs
+}
+
+OTHER_FILES = $$HELP_DEP_FILES