From be3b47d0d504a3409ce66bd77bb8c0acff87c4f5 Mon Sep 17 00:00:00 2001
From: kh1 <karsten.heimrich@nokia.com>
Date: Thu, 15 Mar 2012 14:53:47 +0100
Subject: Reorganize the tree, have better ifw.pri. Shadow build support.

Change-Id: I01fb12537f863ed0744979973c7e4153889cc5cb
Reviewed-by: Tim Jenssen <tim.jenssen@nokia.com>
---
 src/sdk/sdk.pro | 51 +++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 51 insertions(+)
 create mode 100644 src/sdk/sdk.pro

(limited to 'src/sdk/sdk.pro')

diff --git a/src/sdk/sdk.pro b/src/sdk/sdk.pro
new file mode 100644
index 000000000..44930f7a0
--- /dev/null
+++ b/src/sdk/sdk.pro
@@ -0,0 +1,51 @@
+TEMPLATE = app
+DEPENDPATH += . ..
+INCLUDEPATH += . .. 
+TARGET = installerbase
+
+include(../../installerfw.pri)
+
+LIBS += -linstaller
+QT += network script
+
+CONFIG -= app_bundle
+DESTDIR = $$IFW_APP_PATH
+
+QM_FILES = qt_de.qm de_de.qm en_us.qm
+defineTest(testQmFiles) {
+    for(file, QM_FILES) {
+        !exists($$PWD/translations/$$file) {
+            message("File $$PWD/translations/$$file not found!")
+            return(false)
+        }
+    }
+    return(true)
+}
+
+if (testQmFiles()) {
+    RESOURCES += installerbase.qrc
+}
+
+FORMS += settingsdialog.ui
+
+HEADERS += installerbase_p.h \
+           tabcontroller.h \
+           installerbasecommons.h \
+           settingsdialog.h
+
+SOURCES = installerbase.cpp \
+          installerbase_p.cpp \
+          tabcontroller.cpp \
+          installerbasecommons.cpp \
+          settingsdialog.cpp
+
+win32:RC_FILE = installerbase.rc
+win32-msvc2005 {
+  CONFIG += embed_manifest_exe #msvc2008 is doing this automaticaly
+}
+
+embed_manifest_exe:win32-msvc2005 {
+    # The default configuration embed_manifest_exe overrides the manifest file
+    # already embedded via RC_FILE. Vs2008 already have the necessary manifest entry
+    QMAKE_POST_LINK += $$quote(mt.exe -updateresource:$$IFW_APP_PATH/$${TARGET}.exe -manifest \"$${IFW_SOURCE_TREE}\\src\\sdk\\$${TARGET}.exe.manifest\")
+}
-- 
cgit v1.2.3