From 5ec853169633d958c653c2a9431225e37843af98 Mon Sep 17 00:00:00 2001
From: Oswald Buddenhagen <oswald.buddenhagen@qt.io>
Date: Thu, 8 Feb 2018 19:41:40 +0100
Subject: move ts targets to a separate project file

that makes it possible to update the templates even if the ifw itself
cannot be built (e.g., due to using a -no-widgets qt build).

Change-Id: Ie170e6524dbed40f6c8b837e35af6b45a1c2d2dd
Reviewed-by: Katja Marttila <katja.marttila@qt.io>
---
 src/sdk/translations/translations.pro | 40 +++++++++++++++++++++++++++++++++++
 1 file changed, 40 insertions(+)
 create mode 100644 src/sdk/translations/translations.pro

(limited to 'src/sdk/translations/translations.pro')

diff --git a/src/sdk/translations/translations.pro b/src/sdk/translations/translations.pro
new file mode 100644
index 000000000..8a77a0b44
--- /dev/null
+++ b/src/sdk/translations/translations.pro
@@ -0,0 +1,40 @@
+TEMPLATE = aux
+
+include(../../../installerfw.pri)
+
+!exists($$LUPDATE): return()
+
+IB_TRANSLATIONS = $$files($$PWD/*_??.ts)
+IB_TRANSLATIONS -= $$PWD/ifw_en.ts
+
+wd = $$toNativeSeparators($$IFW_SOURCE_TREE)
+sources = src
+lupdate_opts = -locations relative -no-ui-lines -no-sort
+
+IB_ALL_TRANSLATIONS = $$IB_TRANSLATIONS $$PWD/ifw_untranslated.ts
+for(file, IB_ALL_TRANSLATIONS) {
+    lang = $$replace(file, .*_([^/]*)\\.ts, \\1)
+    v = ts-$${lang}.commands
+    $$v = cd $$wd && $$LUPDATE $$lupdate_opts $$sources -ts $$file
+    QMAKE_EXTRA_TARGETS += ts-$$lang
+}
+ts-all.commands = cd $$wd && $$LUPDATE $$lupdate_opts $$sources -ts $$IB_ALL_TRANSLATIONS
+QMAKE_EXTRA_TARGETS += ts-all
+
+isEqual(QMAKE_DIR_SEP, /) {
+    commit-ts.commands = \
+        cd $$wd; \
+        git add -N src/sdk/translations/*_??.ts && \
+        for f in `git diff-files --name-only src/sdk/translations/*_??.ts`; do \
+            $$LCONVERT -locations none -i \$\$f -o \$\$f; \
+        done; \
+        git add src/sdk/translations/*_??.ts && git commit
+} else {
+    commit-ts.commands = \
+        cd $$wd && \
+        git add -N src/sdk/translations/*_??.ts && \
+        for /f usebackq %%f in (`git diff-files --name-only src/sdk/translations/*_??.ts`) do \
+            $$LCONVERT -locations none -i %%f -o %%f $$escape_expand(\\n\\t) \
+        cd $$wd && git add src/sdk/translations/*_??.ts && git commit
+}
+QMAKE_EXTRA_TARGETS += commit-ts
-- 
cgit v1.2.3