blob: 44930f7a071d6256c9d196c9ab89cd97b6f82470 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
TEMPLATE = app
DEPENDPATH += . ..
INCLUDEPATH += . ..
TARGET = installerbase
include(../../installerfw.pri)
LIBS += -linstaller
QT += network script
CONFIG -= app_bundle
DESTDIR = $$IFW_APP_PATH
QM_FILES = qt_de.qm de_de.qm en_us.qm
defineTest(testQmFiles) {
for(file, QM_FILES) {
!exists($$PWD/translations/$$file) {
message("File $$PWD/translations/$$file not found!")
return(false)
}
}
return(true)
}
if (testQmFiles()) {
RESOURCES += installerbase.qrc
}
FORMS += settingsdialog.ui
HEADERS += installerbase_p.h \
tabcontroller.h \
installerbasecommons.h \
settingsdialog.h
SOURCES = installerbase.cpp \
installerbase_p.cpp \
tabcontroller.cpp \
installerbasecommons.cpp \
settingsdialog.cpp
win32:RC_FILE = installerbase.rc
win32-msvc2005 {
CONFIG += embed_manifest_exe #msvc2008 is doing this automaticaly
}
embed_manifest_exe:win32-msvc2005 {
# The default configuration embed_manifest_exe overrides the manifest file
# already embedded via RC_FILE. Vs2008 already have the necessary manifest entry
QMAKE_POST_LINK += $$quote(mt.exe -updateresource:$$IFW_APP_PATH/$${TARGET}.exe -manifest \"$${IFW_SOURCE_TREE}\\src\\sdk\\$${TARGET}.exe.manifest\")
}
|
