Modernize and clean up some of the shiboken build system files

Use target_* commands instead of subdirectory based commands
for adding link options, compile definitions, include directories,
etc.
Remove some non-used compile definitions.
Move around some of the find_package() and option() calls.
Simplify some of the package dependent logic.
Replace the qt include and linking variables with CMake targets.

Change-Id: I815595344e63a32dce3dc78652359beede3ff593
Reviewed-by: Qt CI Bot <qt_ci_bot@qt-project.org>
Reviewed-by: Christian Tismer <tismer@stackless.com>

15 files changed, 79 insertions, 155 deletions

diff --git a/sources/shiboken2/ApiExtractor/CMakeLists.txt b/sources/shiboken2/ApiExtractor/CMakeLists.txt
index bd5654303..147fda377 100644
--- a/sources/shiboken2/ApiExtractor/CMakeLists.txt
+++ b/sources/shiboken2/ApiExtractor/CMakeLists.txt
@@ -3,26 +3,7 @@ project(apiextractor)
 cmake_minimum_required(VERSION 3.1)
 cmake_policy(VERSION 3.1)
 
-set(USE_LIBXSLT 0)
-if (NOT DISABLE_DOCSTRINGS)
-    if (LIBXSLT_FOUND AND LIBXML2_FOUND)
-        add_definitions(-DHAVE_LIBXSLT)
-        set (USE_LIBXSLT 1)
-    else()
-        message(WARNING
-                "libxslt and/or libxml not found, falling back to QtXmlPatterns (QTBUG-66925)")
-    endif()
-endif()
-
-if(BUILD_TESTS)
-    set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/tests)
-endif ()
-
-set(QT_USE_QTCORE 1)
-set(QT_USE_QTXML 1)
-add_definitions(-DQT_PLUGIN)
-add_definitions(-DQT_SHARED)
-add_definitions(-DRXX_ALLOCATOR_INIT_0)
+set(CMAKE_AUTOMOC ON)
 
 set(apiextractor_SRC
 apiextractor.cpp
@@ -47,45 +28,37 @@ parser/codemodel.cpp
 parser/enumvalue.cpp
 )
 
-set(APIEXTRACTOR_EXTRA_INCLUDES ${CLANG_EXTRA_INCLUDES})
-set(APIEXTRACTOR_EXTRA_LIBRARIES ${CLANG_EXTRA_LIBRARIES})
+add_library(apiextractor STATIC ${apiextractor_SRC})
+target_include_directories(apiextractor PRIVATE ${CLANG_EXTRA_INCLUDES}
+                                                ${CMAKE_CURRENT_SOURCE_DIR}
+                                                ${CMAKE_CURRENT_BINARY_DIR}
+                                                ${CMAKE_CURRENT_SOURCE_DIR}/parser
+                                                ${CMAKE_CURRENT_SOURCE_DIR}/parser/rpp)
+target_link_libraries(apiextractor PUBLIC Qt5::Core)
+target_link_libraries(apiextractor PRIVATE ${CLANG_EXTRA_LIBRARIES})
 
 if (NOT DISABLE_DOCSTRINGS)
-    set(apiextractor_SRC
-        ${apiextractor_SRC}
-        docparser.cpp
-        doxygenparser.cpp
-        qtdocparser.cpp
-    )
-    set(APIEXTRACTOR_EXTRA_INCLUDES ${APIEXTRACTOR_EXTRA_INCLUDES})
-    set(APIEXTRACTOR_EXTRA_LIBRARIES ${APIEXTRACTOR_EXTRA_LIBRARIES})
-    if (USE_LIBXSLT)
-        list(APPEND APIEXTRACTOR_EXTRA_INCLUDES ${LIBXSLT_INCLUDE_DIR} ${LIBXML2_INCLUDE_DIR})
-        list(APPEND APIEXTRACTOR_EXTRA_LIBRARIES ${LIBXSLT_LIBRARIES} ${LIBXML2_LIBRARIES})
+    target_sources(apiextractor PRIVATE docparser.cpp
+                                        doxygenparser.cpp
+                                        qtdocparser.cpp)
+    target_link_libraries(apiextractor PUBLIC Qt5::Xml Qt5::XmlPatterns)
+
+    if (LIBXSLT_FOUND AND LIBXML2_FOUND)
+        target_compile_definitions(apiextractor PUBLIC HAVE_LIBXSLT)
+        target_include_directories(apiextractor
+                                   PRIVATE ${LIBXSLT_INCLUDE_DIR} ${LIBXML2_INCLUDE_DIR})
+        target_link_libraries(apiextractor
+                              PRIVATE ${LIBXSLT_LIBRARIES} ${LIBXML2_LIBRARIES})
+    else()
+        message(WARNING
+                "libxslt and/or libxml not found, falling back to QtXmlPatterns (QTBUG-66925)")
     endif()
 endif()
 
 set(LIB_INSTALL_DIR "${CMAKE_INSTALL_PREFIX}/lib${LIB_SUFFIX}" CACHE PATH "The subdirectory relative to the install prefix where libraries will be installed (default is /lib${LIB_SUFFIX})" FORCE)
 
-set(CMAKE_AUTOMOC ON)
-
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_CURRENT_BINARY_DIR}
-                    ${CMAKE_CURRENT_SOURCE_DIR}/parser
-                    ${CMAKE_CURRENT_SOURCE_DIR}/parser/rpp
-                    ${APIEXTRACTOR_EXTRA_INCLUDES}
-                    ${Qt5Core_INCLUDE_DIRS}
-                    ${Qt5Xml_INCLUDE_DIRS}
-                    )
-
-add_library(apiextractor STATIC ${apiextractor_SRC} ${apiextractor_RCCS_SRC})
-target_link_libraries(apiextractor
-                      ${Qt5Xml_LIBRARIES}
-                      ${Qt5XmlPatterns_LIBRARIES}
-                      ${APIEXTRACTOR_EXTRA_LIBRARIES}
-                      )
-
 if (BUILD_TESTS)
+    set(LIBRARY_OUTPUT_PATH ${CMAKE_BINARY_DIR}/tests)
     enable_testing()
     add_subdirectory(tests)
 endif()
diff --git a/sources/shiboken2/ApiExtractor/tests/CMakeLists.txt b/sources/shiboken2/ApiExtractor/tests/CMakeLists.txt
index 1429a63b1..a36cc17de 100644
--- a/sources/shiboken2/ApiExtractor/tests/CMakeLists.txt
+++ b/sources/shiboken2/ApiExtractor/tests/CMakeLists.txt
@@ -1,7 +1,3 @@
-find_package(Qt5Core)
-find_package(Qt5Gui)
-find_package(Qt5Test)
-
 set(CMAKE_AUTORCC ON)
 
 macro(declare_test testname)
@@ -13,19 +9,13 @@ macro(declare_test testname)
     if (EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/${testname}.qrc")
         list(APPEND SOURCES "${testname}.qrc")
     endif ()
+
     add_executable(${testname} ${SOURCES})
-    include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                        ${CMAKE_CURRENT_BINARY_DIR}
-                        ${apiextractor_SOURCE_DIR}
-                        ${Qt5Test_INCLUDE_DIRS}
-                        )
-    link_directories(${APIEXTRACTOR_EXTRA_LINK_DIRECTORIES})
-    target_link_libraries(${testname}
-                          ${Qt5XmlPatterns_LIBRARIES}
-                          ${Qt5Test_LIBRARIES}
-                          ${Qt5Core_LIBRARIES}
-                          ${Qt5Gui_LIBRARIES}
-                          apiextractor)
+    target_include_directories(${testname} PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}
+                                                   ${CMAKE_CURRENT_BINARY_DIR}
+                                                   ${apiextractor_SOURCE_DIR}
+                                                   )
+    target_link_libraries(${testname} PRIVATE apiextractor Qt5::Test)
     add_test(${testname} ${testname})
     if (INSTALL_TESTS)
         install(PROGRAMS ${CMAKE_CURRENT_BINARY_DIR}/${testname}
diff --git a/sources/shiboken2/CMakeLists.txt b/sources/shiboken2/CMakeLists.txt
index 0f39bff61..12429c657 100644
--- a/sources/shiboken2/CMakeLists.txt
+++ b/sources/shiboken2/CMakeLists.txt
@@ -11,22 +11,25 @@ list(APPEND CMAKE_MODULE_PATH "${CMAKE_CURRENT_SOURCE_DIR}/data/")
 include(helpers)
 include(shiboken_helpers)
 
+option(BUILD_TESTS "Build tests." TRUE)
+option(USE_PYTHON_VERSION "Use specific python version to build shiboken2." "")
+option(DISABLE_DOCSTRINGS "Disable documentation extraction." FALSE)
+
 find_package(Qt5 5.12 REQUIRED COMPONENTS Core)
 find_package(Qt5Xml 5.12)
 find_package(Qt5XmlPatterns 5.12)
 find_package(LibXml2 2.6.32)
 find_package(LibXslt 1.1.19)
+if(BUILD_TESTS)
+    find_package(Qt5Test 5.12 REQUIRED)
+endif()
 
-option(DISABLE_DOCSTRINGS "Disable documentation extraction." FALSE)
 if(NOT Qt5XmlPatterns_FOUND OR NOT Qt5Xml_FOUND)
     set(DISABLE_DOCSTRINGS TRUE)
     message(WARNING
             "Documentation will not be built due to missing dependency (no Qt5XmlPatterns found).")
 endif()
 
-option(BUILD_TESTS "Build tests." TRUE)
-option(USE_PYTHON_VERSION "Use specific python version to build shiboken2." "")
-
 # Don't display "up-to-date / install" messages when installing, to reduce visual clutter.
 if (QUIET_BUILD)
     set(CMAKE_INSTALL_MESSAGE NEVER)
diff --git a/sources/shiboken2/generator/CMakeLists.txt b/sources/shiboken2/generator/CMakeLists.txt
index 890790522..745c366f5 100644
--- a/sources/shiboken2/generator/CMakeLists.txt
+++ b/sources/shiboken2/generator/CMakeLists.txt
@@ -9,29 +9,23 @@ shiboken2/shibokengenerator.cpp
 main.cpp
 )
 
-if (NOT DISABLE_DOCSTRINGS)
-    set(shiboken2_SRC ${shiboken2_SRC} qtdoc/qtdocgenerator.cpp)
-    add_definitions(-DDOCSTRINGS_ENABLED)
-endif()
-
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}/shiboken2
+add_executable(shiboken2 ${shiboken2_SRC})
+add_executable(Shiboken2::shiboken2 ALIAS shiboken2)
+add_dependencies(shiboken2 apiextractor)
+set_target_properties(shiboken2 PROPERTIES OUTPUT_NAME shiboken2${shiboken2_SUFFIX})
+target_include_directories(shiboken2 PRIVATE
+                    ${CMAKE_CURRENT_SOURCE_DIR}/shiboken2
                     ${CMAKE_CURRENT_SOURCE_DIR}/qtdoc
                     ${CMAKE_CURRENT_SOURCE_DIR}
                     ${CMAKE_CURRENT_BINARY_DIR}
                     ${apiextractor_SOURCE_DIR}
-                    ${Qt5Core_INCLUDE_DIRS}
-                    ${Qt5XmlPatterns_INCLUDE_DIRS}
                     )
-
-add_executable(shiboken2 ${shiboken2_SRC})
-add_executable(Shiboken2::shiboken2 ALIAS shiboken2)
-add_dependencies(shiboken2 apiextractor)
-set_target_properties(shiboken2 PROPERTIES OUTPUT_NAME shiboken2${shiboken2_SUFFIX})
-target_link_libraries(shiboken2
-                      apiextractor
-                      ${Qt5Core_LIBRARIES}
-                      ${Qt5XmlPatterns_LIBRARIES}
-                      )
+target_link_libraries(shiboken2 apiextractor Qt5::Core)
+if (NOT DISABLE_DOCSTRINGS)
+    target_sources(shiboken2 PRIVATE qtdoc/qtdocgenerator.cpp)
+    target_compile_definitions(shiboken2 PUBLIC DOCSTRINGS_ENABLED)
+    target_link_libraries(shiboken2 Qt5::XmlPatterns)
+endif()
 
 configure_file(shibokenconfig.h.in "${CMAKE_CURRENT_BINARY_DIR}/shibokenconfig.h" @ONLY)
 
diff --git a/sources/shiboken2/shibokenmodule/CMakeLists.txt b/sources/shiboken2/shibokenmodule/CMakeLists.txt
index 61c38c5d7..09731240f 100644
--- a/sources/shiboken2/shibokenmodule/CMakeLists.txt
+++ b/sources/shiboken2/shibokenmodule/CMakeLists.txt
@@ -3,14 +3,9 @@ project(shibokenmodule)
 configure_file("${CMAKE_CURRENT_SOURCE_DIR}/shibokenmodule.txt.in"
                "${CMAKE_CURRENT_BINARY_DIR}/shibokenmodule.txt" @ONLY)
 
+set(sample_SRC ${CMAKE_CURRENT_BINARY_DIR}/shiboken2/shiboken2_module_wrapper.cpp)
 
-set(sample_SRC
-${CMAKE_CURRENT_BINARY_DIR}/shiboken2/shiboken2_module_wrapper.cpp
-)
-
-set(shibokenmodule_TYPESYSTEM
-${CMAKE_CURRENT_SOURCE_DIR}/typesystem_shiboken.xml
-)
+set(shibokenmodule_TYPESYSTEM ${CMAKE_CURRENT_SOURCE_DIR}/typesystem_shiboken.xml)
 
 add_custom_command(
 OUTPUT "${CMAKE_CURRENT_BINARY_DIR}/mjb_rejected_classes.log"
@@ -24,19 +19,16 @@ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 COMMENT "Running generator for 'shiboken2'..."
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_SOURCE_DIR}
-                    ${libshiboken_SOURCE_DIR}
-                    ${libshiboken_BINARY_DIR})
 add_library(shibokenmodule MODULE ${sample_SRC})
+target_include_directories(shibokenmodule PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}
+                                                  ${CMAKE_SOURCE_DIR})
 set_property(TARGET shibokenmodule PROPERTY PREFIX "")
 set_property(TARGET shibokenmodule PROPERTY OUTPUT_NAME "shiboken2${PYTHON_EXTENSION_SUFFIX}")
 
 if(WIN32)
     set_property(TARGET shibokenmodule PROPERTY SUFFIX ".pyd")
 endif()
-target_link_libraries(shibokenmodule
-                      libshiboken)
+target_link_libraries(shibokenmodule PUBLIC libshiboken)
 
 add_dependencies(shibokenmodule shiboken2)
 create_generator_target(shibokenmodule)
diff --git a/sources/shiboken2/tests/CMakeLists.txt b/sources/shiboken2/tests/CMakeLists.txt
index c06c56f6d..085a4344c 100644
--- a/sources/shiboken2/tests/CMakeLists.txt
+++ b/sources/shiboken2/tests/CMakeLists.txt
@@ -1,6 +1,3 @@
-find_package(Qt5 REQUIRED COMPONENTS Core)
-include_directories(${Qt5Core_INCLUDE_DIRS})
-
 add_subdirectory(libminimal)
 if(NOT DEFINED MINIMAL_TESTS)
     add_subdirectory(libsample)
diff --git a/sources/shiboken2/tests/dumpcodemodel/CMakeLists.txt b/sources/shiboken2/tests/dumpcodemodel/CMakeLists.txt
index af18cb3c8..7c6d60fe2 100644
--- a/sources/shiboken2/tests/dumpcodemodel/CMakeLists.txt
+++ b/sources/shiboken2/tests/dumpcodemodel/CMakeLists.txt
@@ -1,5 +1,6 @@
 add_executable(dumpcodemodel main.cpp)
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR} ${apiextractor_SOURCE_DIR} ${Qt5Core_INCLUDE_DIRS})
+target_include_directories(dumpcodemodel
+                           PRIVATE ${CMAKE_CURRENT_SOURCE_DIR} ${apiextractor_SOURCE_DIR})
 
-target_link_libraries(dumpcodemodel apiextractor ${Qt5Core_LIBRARIES})
+target_link_libraries(dumpcodemodel PUBLIC apiextractor Qt5::Core)
diff --git a/sources/shiboken2/tests/libminimal/CMakeLists.txt b/sources/shiboken2/tests/libminimal/CMakeLists.txt
index a25892571..f906bdb84 100644
--- a/sources/shiboken2/tests/libminimal/CMakeLists.txt
+++ b/sources/shiboken2/tests/libminimal/CMakeLists.txt
@@ -6,8 +6,8 @@ listuser.cpp
 typedef.cpp
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-add_definitions("-DLIBMINIMAL_BUILD")
 add_library(libminimal SHARED ${libminimal_SRC})
+target_include_directories(libminimal PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_compile_definitions(libminimal PRIVATE LIBMINIMAL_BUILD)
 set_property(TARGET libminimal PROPERTY PREFIX "")
 
diff --git a/sources/shiboken2/tests/libother/CMakeLists.txt b/sources/shiboken2/tests/libother/CMakeLists.txt
index 9b3cf5552..6aba91e13 100644
--- a/sources/shiboken2/tests/libother/CMakeLists.txt
+++ b/sources/shiboken2/tests/libother/CMakeLists.txt
@@ -7,12 +7,10 @@ otherobjecttype.cpp
 othermultiplederived.cpp
 )
 
-add_definitions("-DLIBOTHER_BUILD")
 add_library(libother SHARED ${libother_SRC})
+target_include_directories(libother PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_compile_definitions(libother PRIVATE LIBOTHER_BUILD)
+target_link_libraries(libother PUBLIC libsample)
 set_property(TARGET libother PROPERTY PREFIX "")
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${libsample_SOURCE_DIR}
-                    ${libsample_SOURCE_DIR}/..)
-target_link_libraries(libother libsample)
 
diff --git a/sources/shiboken2/tests/libsample/CMakeLists.txt b/sources/shiboken2/tests/libsample/CMakeLists.txt
index ae3d40312..170829fbc 100644
--- a/sources/shiboken2/tests/libsample/CMakeLists.txt
+++ b/sources/shiboken2/tests/libsample/CMakeLists.txt
@@ -51,8 +51,8 @@ expression.cpp
 filter.cpp
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-add_definitions("-DLIBSAMPLE_BUILD")
 add_library(libsample SHARED ${libsample_SRC})
+target_include_directories(libsample PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_compile_definitions(libsample PRIVATE LIBSAMPLE_BUILD)
 set_property(TARGET libsample PROPERTY PREFIX "")
 
diff --git a/sources/shiboken2/tests/libsmart/CMakeLists.txt b/sources/shiboken2/tests/libsmart/CMakeLists.txt
index 66c27cdae..152c57f25 100644
--- a/sources/shiboken2/tests/libsmart/CMakeLists.txt
+++ b/sources/shiboken2/tests/libsmart/CMakeLists.txt
@@ -4,8 +4,8 @@ set(libsmart_SRC
 smart.cpp
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR})
-add_definitions("-DLIBSMART_BUILD")
 add_library(libsmart SHARED ${libsmart_SRC})
+target_include_directories(libsmart PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_compile_definitions(libsmart PRIVATE LIBSMART_BUILD)
 set_property(TARGET libsmart PROPERTY PREFIX "")
 
diff --git a/sources/shiboken2/tests/minimalbinding/CMakeLists.txt b/sources/shiboken2/tests/minimalbinding/CMakeLists.txt
index 7301e1882..ffeb086a0 100644
--- a/sources/shiboken2/tests/minimalbinding/CMakeLists.txt
+++ b/sources/shiboken2/tests/minimalbinding/CMakeLists.txt
@@ -24,18 +24,13 @@ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 COMMENT "Running generator for 'minimal' test binding..."
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_SOURCE_DIR}
-                    ${libminimal_SOURCE_DIR}
-                    ${libshiboken_SOURCE_DIR}
-                    ${libshiboken_BINARY_DIR})
 add_library(minimal MODULE ${minimal_SRC})
+target_include_directories(minimal PRIVATE ${CMAKE_CURRENT_SOURCE_DIR})
+target_link_libraries(minimal PUBLIC libminimal libshiboken)
 set_property(TARGET minimal PROPERTY PREFIX "")
 set_property(TARGET minimal PROPERTY OUTPUT_NAME "minimal${PYTHON_EXTENSION_SUFFIX}")
 if(WIN32)
     set_property(TARGET minimal PROPERTY SUFFIX ".pyd")
 endif()
-target_link_libraries(minimal
-                      libminimal
-                      libshiboken)
+
 create_generator_target(minimal)
diff --git a/sources/shiboken2/tests/otherbinding/CMakeLists.txt b/sources/shiboken2/tests/otherbinding/CMakeLists.txt
index 44855e297..bc5c4bdad 100644
--- a/sources/shiboken2/tests/otherbinding/CMakeLists.txt
+++ b/sources/shiboken2/tests/otherbinding/CMakeLists.txt
@@ -26,26 +26,17 @@ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 COMMENT "Running generator for 'other' test binding..."
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_SOURCE_DIR}
-                    ${libother_SOURCE_DIR}
-                    ${libsample_SOURCE_DIR}
-                    ${libsample_SOURCE_DIR}/..
-                    ${sample_BINARY_DIR}
-                    ${sample_BINARY_DIR}/sample
-                    ${libshiboken_SOURCE_DIR}
-                    ${libshiboken_BINARY_DIR})
 add_library(other MODULE ${other_SRC})
+target_include_directories(other PRIVATE ${CMAKE_CURRENT_SOURCE_DIR}
+                                         ${sample_BINARY_DIR}/sample)
+target_link_libraries(other PUBLIC libother libsample libshiboken)
 set_property(TARGET other PROPERTY PREFIX "")
 set_property(TARGET other PROPERTY OUTPUT_NAME "other${PYTHON_EXTENSION_SUFFIX}")
 
 if(WIN32)
     set_property(TARGET other PROPERTY SUFFIX ".pyd")
 endif()
-target_link_libraries(other
-                      libother
-                      libsample
-                      libshiboken)
+
 
 add_dependencies(other sample)
 create_generator_target(other)
diff --git a/sources/shiboken2/tests/samplebinding/CMakeLists.txt b/sources/shiboken2/tests/samplebinding/CMakeLists.txt
index 9ecbd98e6..61090d30e 100644
--- a/sources/shiboken2/tests/samplebinding/CMakeLists.txt
+++ b/sources/shiboken2/tests/samplebinding/CMakeLists.txt
@@ -137,19 +137,14 @@ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 COMMENT "Running generator for 'sample' test binding..."
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_SOURCE_DIR}
-                    ${libsample_SOURCE_DIR}
-                    ${libshiboken_SOURCE_DIR}
-                    ${libshiboken_BINARY_DIR})
 add_library(sample MODULE ${sample_SRC})
+target_include_directories(sample PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_link_libraries(sample PUBLIC libsample libshiboken)
 set_property(TARGET sample PROPERTY PREFIX "")
 set_property(TARGET sample PROPERTY OUTPUT_NAME "sample${PYTHON_EXTENSION_SUFFIX}")
 
 if(WIN32)
     set_property(TARGET sample PROPERTY SUFFIX ".pyd")
 endif()
-target_link_libraries(sample
-                      libsample
-                      libshiboken)
+
 create_generator_target(sample)
diff --git a/sources/shiboken2/tests/smartbinding/CMakeLists.txt b/sources/shiboken2/tests/smartbinding/CMakeLists.txt
index ed6bcef0a..88a7bc059 100644
--- a/sources/shiboken2/tests/smartbinding/CMakeLists.txt
+++ b/sources/shiboken2/tests/smartbinding/CMakeLists.txt
@@ -27,19 +27,14 @@ WORKING_DIRECTORY ${CMAKE_CURRENT_SOURCE_DIR}
 COMMENT "Running generator for 'smart' test binding..."
 )
 
-include_directories(${CMAKE_CURRENT_SOURCE_DIR}
-                    ${CMAKE_SOURCE_DIR}
-                    ${libsmart_SOURCE_DIR}
-                    ${libshiboken_SOURCE_DIR}
-                    ${libshiboken_BINARY_DIR})
 add_library(smart MODULE ${smart_SRC})
+target_include_directories(smart PUBLIC ${CMAKE_CURRENT_SOURCE_DIR})
+target_link_libraries(smart PUBLIC libsmart libshiboken)
 set_property(TARGET smart PROPERTY PREFIX "")
 set_property(TARGET smart PROPERTY OUTPUT_NAME "smart${PYTHON_EXTENSION_SUFFIX}")
 
 if(WIN32)
     set_property(TARGET smart PROPERTY SUFFIX ".pyd")
 endif()
-target_link_libraries(smart
-                      libsmart
-                      libshiboken)
+
 create_generator_target(smart)