Move Qt profile setup into a dedicated library.

Otherwise all changes to the implementation will have to be duplicated
in IDEs.

Change-Id: I61e6d4fa1ee9b724eb5d9de9f233dc915a6c8bc3
Reviewed-by: Joerg Bornemann <joerg.bornemann@digia.com>

1 files changed, 38 insertions, 0 deletions

diff --git a/src/lib/corelib/use_installed_corelib.pri b/src/lib/corelib/use_installed_corelib.pri
new file mode 100644
index 000000000..bac8d6da7
--- /dev/null
+++ b/src/lib/corelib/use_installed_corelib.pri
@@ -0,0 +1,38 @@
+include(qbs_version.pri)
+
+QT += script xml
+
+QBSLIBDIR=$${PWD}/../../lib
+unix {
+    LIBS += -L$$QBSLIBDIR -lqbscore
+}
+
+!disable_rpath:unix:QMAKE_LFLAGS += -Wl,-rpath,$${QBSLIBDIR}
+
+!CONFIG(static, static|shared) {
+    QBSCORELIBSUFFIX = $$QBS_VERSION_MAJ
+}
+
+win32 {
+    CONFIG(debug, debug|release) {
+        QBSCORELIB = qbscored$$QBSCORELIBSUFFIX
+    }
+    CONFIG(release, debug|release) {
+        QBSCORELIB = qbscore$$QBSCORELIBSUFFIX
+    }
+    win32-msvc* {
+        LIBS += /LIBPATH:$$QBSLIBDIR
+        QBSCORELIB = $${QBSCORELIB}.lib
+        LIBS += Shell32.lib
+    } else {
+        LIBS += -L$${QBSLIBDIR}
+        QBSCORELIB = lib$${QBSCORELIB}
+    }
+    LIBS += $$QBSCORELIB
+}
+
+INCLUDEPATH += $${PWD} $${PWD}/..
+
+CONFIG(static, static|shared) {
+    DEFINES += QBS_STATIC_LIB
+}