1 files changed, 47 insertions, 0 deletions
diff --git a/src/lib/corelib/use_corelib.pri b/src/lib/corelib/use_corelib.pri
new file mode 100644
index 000000000..875c51f51
--- /dev/null
+++ b/src/lib/corelib/use_corelib.pri
@@ -0,0 +1,47 @@
+include(../../../qbs_version.pri)
+
+isEmpty(QBSLIBDIR) {
+    QBSLIBDIR = $$OUT_PWD/../../../lib
+}
+
+QT += script xml
+
+unix {
+    LIBS += -L$$QBSLIBDIR -lqbscore
+}
+
+!disable_rpath {
+    linux-*:QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,\$\$ORIGIN/../lib\'
+    macx:QMAKE_LFLAGS += -Wl,-rpath,@loader_path/../lib
+}
+
+!CONFIG(static, static|shared) {
+    QBSCORELIBSUFFIX = $$QBS_VERSION_MAJ
+}
+
+win32 {
+    CONFIG(debug, debug|release) {
+        QBSCORELIB = qbscored$$QBSCORELIBSUFFIX
+    }
+    CONFIG(release, debug|release) {
+        QBSCORELIB = qbscore$$QBSCORELIBSUFFIX
+    }
+    win32-msvc* {
+        LIBS += /LIBPATH:$$QBSLIBDIR
+        QBSCORELIB = $${QBSCORELIB}.lib
+        LIBS += Shell32.lib
+    } else {
+        LIBS += -L$${QBSLIBDIR}
+        QBSCORELIB = lib$${QBSCORELIB}
+    }
+    LIBS += $$QBSCORELIB
+}
+
+INCLUDEPATH += \
+    $$PWD
+
+CONFIG += depend_includepath
+
+CONFIG(static, static|shared) {
+    DEFINES += QBS_STATIC_LIB
+}