blob: 414bc60339a88ddc8994802d896ade956069e28f (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
defineTest(minQtVersion) {
maj = $$1
min = $$2
patch = $$3
isEqual(QT_MAJOR_VERSION, $$maj) {
isEqual(QT_MINOR_VERSION, $$min) {
isEqual(QT_PATCH_VERSION, $$patch) {
return(true)
}
greaterThan(QT_PATCH_VERSION, $$patch) {
return(true)
}
}
greaterThan(QT_MINOR_VERSION, $$min) {
return(true)
}
}
greaterThan(QT_MAJOR_VERSION, $$maj) {
return(true)
}
return(false)
}
!minQtVersion(4, 8, 0) {
message("Cannot build qbs with Qt version $${QT_VERSION}.")
error("Use at least Qt 4.8.0.")
}
TEMPLATE = subdirs
CONFIG += ordered
corelib.file = src/lib/corelib/corelib.pro
setupqtprofilelib.subdir = src/lib/qtprofilesetup
setupqtprofilelib.depends = corelib
src_app.subdir = src/app
src_app.depends = setupqtprofilelib
SUBDIRS += \
corelib\
setupqtprofilelib\
src_app\
src/plugins\
static.pro\
tests
OTHER_FILES += \
doc/*.qdoc \
doc/reference/*.qdoc \
doc/reference/items/*.qdoc \
doc/reference/jsextensions/*.qdoc \
doc/reference/modules/*.qdoc \
doc/qbs.qdocconf \
doc/config/qbs-project.qdocconf
include(qbs_version.pri)
include(doc/doc.pri)
|
