1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
|
/****************************************************************************
**
** Copyright (C) 2014 Digia Plc and/or its subsidiary(-ies).
** Copyright (C) 2014 Petroules Corporation.
** Contact: http://www.qt-project.org/legal
**
** This file is part of the Qt Build Suite.
**
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and Digia. For licensing terms and
** conditions see http://qt.digia.com/licensing. For further information
** use the contact form at http://qt.digia.com/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 2.1 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPL included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 2.1 requirements
** will be met: http://www.gnu.org/licenses/old-licenses/lgpl-2.1.html.
**
** In addition, as a special exception, Digia gives you certain additional
** rights. These rights are described in the Digia Qt LGPL Exception
** version 1.1, included in the file LGPL_EXCEPTION.txt in this package.
**
****************************************************************************/
#include "propertylist.h"
#include <tools/hostosinfo.h>
#include <QFile>
#include <QScriptEngine>
#include <QScriptValue>
#include <QTextStream>
#import <Foundation/Foundation.h>
namespace qbs {
namespace Internal {
static inline QString fromNSString(const NSString *string)
{
if (!string)
return QString();
QString qstring;
qstring.resize([string length]);
[string getCharacters:reinterpret_cast<unichar*>(qstring.data())
range:NSMakeRange(0, [string length])];
return qstring;
}
static inline NSString *toNSString(const QString &qstring)
{
return [NSString stringWithCharacters:reinterpret_cast<const UniChar*>(qstring.unicode())
length:qstring.length()];
}
class PropertyListPrivate
{
public:
PropertyListPrivate();
id propertyListObject;
void read(QScriptContext *context, NSData *data);
};
void initializeJsExtensionPropertyList(QScriptValue extensionObject)
{
QScriptEngine *engine = extensionObject.engine();
QScriptValue obj = engine->newQMetaObject(&PropertyList::staticMetaObject,
engine->newFunction(&PropertyList::ctor));
extensionObject.setProperty(QLatin1String("PropertyList"), obj);
}
QScriptValue PropertyList::ctor(QScriptContext *context, QScriptEngine *engine)
{
PropertyList *p = new PropertyList(context);
QScriptValue obj = engine->newQObject(p, QScriptEngine::ScriptOwnership);
return obj;
}
PropertyListPrivate::PropertyListPrivate()
: propertyListObject()
{
}
PropertyList::~PropertyList()
{
[d->propertyListObject release];
delete d;
}
PropertyList::PropertyList(QScriptContext *context)
: d(new PropertyListPrivate)
{
Q_UNUSED(context);
Q_ASSERT(thisObject().engine() == engine());
}
void PropertyList::read(const QString &input)
{
Q_ASSERT(thisObject().engine() == engine());
PropertyList *p = qscriptvalue_cast<PropertyList*>(thisObject());
NSString *inputString = toNSString(input);
NSData *data = [NSData dataWithBytes:[inputString UTF8String]
length:[inputString lengthOfBytesUsingEncoding:NSUTF8StringEncoding]];
p->d->read(p->context(), data);
}
void PropertyList::readFile(const QString &filePath)
{
Q_ASSERT(thisObject().engine() == engine());
PropertyList *p = qscriptvalue_cast<PropertyList*>(thisObject());
NSError *error;
NSData *data = [NSData dataWithContentsOfFile:toNSString(filePath) options:0 error:&error];
if (data) {
p->d->read(p->context(), data);
} else {
p->context()->throwError(fromNSString([error localizedDescription]));
}
}
void PropertyListPrivate::read(QScriptContext *context, NSData *data)
{
NSError *error = nil;
id plist = nil;
if ([NSPropertyListSerialization
respondsToSelector:@selector(propertyListWithData:options:format:error:)]) {
error = nil;
plist = [NSPropertyListSerialization propertyListWithData:data
options:0
format:NULL error:&error];
if (Q_UNLIKELY(!plist)) {
context->throwError(fromNSString([error localizedDescription]));
}
}
else
{
NSString *errorString = nil;
plist = [NSPropertyListSerialization propertyListFromData:data
mutabilityOption:NSPropertyListImmutable
format:NULL
errorDescription:&errorString];
if (Q_UNLIKELY(!plist)) {
context->throwError(fromNSString(errorString));
}
}
[propertyListObject release];
propertyListObject = [plist retain];
}
QString PropertyList::toXML() const
{
PropertyList *p = qscriptvalue_cast<PropertyList*>(thisObject());
if (!p->d->propertyListObject)
return QString();
NSData *data = nil;
if ([NSPropertyListSerialization
respondsToSelector:@selector(dataWithPropertyList:format:options:error:)]) {
NSError *error = nil;
data = [NSPropertyListSerialization dataWithPropertyList:p->d->propertyListObject
format:NSPropertyListXMLFormat_v1_0
options:0 error:&error];
if (!data) {
p->context()->throwError(fromNSString([error localizedDescription]));
}
} else {
NSString *errorString = nil;
data = [NSPropertyListSerialization dataFromPropertyList:p->d->propertyListObject
format:NSPropertyListXMLFormat_v1_0
errorDescription:&errorString];
if (!data) {
p->context()->throwError(fromNSString(errorString));
}
}
return fromNSString([[[NSString alloc] initWithData:data
encoding:NSUTF8StringEncoding] autorelease]);
}
QString PropertyList::toJSON() const
{
PropertyList *p = qscriptvalue_cast<PropertyList*>(thisObject());
if (!p->d->propertyListObject)
return QString();
#if __MAC_OS_X_VERSION_MAX_ALLOWED >= __MAC_10_7
if (NSClassFromString(@"NSJSONSerialization")) {
NSError *error = nil;
NSData *data = [NSJSONSerialization dataWithJSONObject:p->d->propertyListObject
options:0
error:&error];
if (!data) {
p->context()->throwError(fromNSString([error localizedDescription]));
}
return fromNSString([[[NSString alloc] initWithData:data
encoding:NSUTF8StringEncoding] autorelease]);
}
else
#endif
{
p->context()->throwError(QLatin1String("JSON serialization of property lists is not "
"supported on this version of OS X"));
return QString();
}
}
} // namespace Internal
} // namespace qbs
|
