blob: 1cba270e8a802435e6db3f4e06f1e431d814cc76 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
include(../../../qbs_version.pri)
include(../../library_dirname.pri)
isEmpty(QBSLIBDIR) {
QBSLIBDIR = $${OUT_PWD}/../../../$${QBS_LIBRARY_DIRNAME}
}
LIBNAME=qbsqtprofilesetup
unix {
LIBS += -L$${QBSLIBDIR} -l$${LIBNAME}
}
!disable_rpath {
linux-*:QMAKE_LFLAGS += -Wl,-z,origin \'-Wl,-rpath,\$\$ORIGIN/../$${QBS_LIBRARY_DIRNAME}\'
macx:QMAKE_LFLAGS += -Wl,-rpath,@loader_path/../$${QBS_LIBRARY_DIRNAME}
}
!CONFIG(static, static|shared) {
QBSQTPROFILELIBSUFFIX = $${QBS_VERSION_MAJ}
}
win32 {
CONFIG(debug, debug|release) {
QBSQTPROFILELIB = $${LIBNAME}d$${QBSQTPROFILELIBSUFFIX}
}
CONFIG(release, debug|release) {
QBSQTPROFILELIB = $${LIBNAME}$${QBSQTPROFILELIBSUFFIX}
}
win32-msvc* {
LIBS += /LIBPATH:$$QBSLIBDIR
QBSQTPROFILELIB = $${QBSQTPROFILELIB}.lib
LIBS += Shell32.lib
} else {
LIBS += -L$${QBSLIBDIR}
QBSQTPROFILELIB = lib$${QBSQTPROFILELIB}
}
LIBS += $${QBSQTPROFILELIB}
}
INCLUDEPATH += \
$$PWD
CONFIG += depend_includepath
CONFIG(static, static|shared) {
DEFINES += QBS_STATIC_LIB
}
|