fixed up the demo suite

Change-Id: I42dfba551b26f66b8de41dad3df2a5e120c82fb8
Reviewed-by: Eirik Aavitsland <eirik.aavitsland@digia.com>

1 files changed, 154 insertions, 0 deletions

diff --git a/basicsuite/Controls Touch/main.qml b/basicsuite/Controls Touch/main.qml
new file mode 100644
index 0000000..18b26e9
--- /dev/null
+++ b/basicsuite/Controls Touch/main.qml
@@ -0,0 +1,154 @@
+/****************************************************************************
+**
+** Copyright (C) 2013 Digia Plc and/or its subsidiary(-ies).
+** Contact: http://www.qt-project.org/legal
+**
+** This file is part of the Qt Quick Controls module of the Qt Toolkit.
+**
+** $QT_BEGIN_LICENSE:BSD$
+** You may use this file under the terms of the BSD license as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
+**     of its contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+****************************************************************************/
+
+
+
+
+
+import QtQuick 2.1
+import QtQuick.Controls 1.0
+import "content"
+
+Item {
+    width: 800
+    height: 1280
+
+    Rectangle {
+        color: "#212126"
+        anchors.fill: parent
+    }
+
+    // Implements back key navigation
+    Keys.onReleased: {
+        if (event.key === Qt.Key_Back) {
+            if (pageStack.depth > 1) {
+                pageStack.pop();
+                event.accepted = true;
+            } else { Qt.quit(); }
+        }
+    }
+
+    BorderImage {
+        id: toolbar
+        border.bottom: 8
+        source: "images/toolbar.png"
+        width: parent.width
+        height: 100
+
+        Rectangle {
+            id: backButton
+            width: opacity ? 60 : 0
+            anchors.left: parent.left
+            anchors.leftMargin: 20
+            opacity: pageStack.depth > 1 ? 1 : 0
+            anchors.verticalCenter: parent.verticalCenter
+            antialiasing: true
+            height: 60
+            radius: 4
+            color: backmouse.pressed ? "#222" : "transparent"
+            Behavior on opacity { NumberAnimation{} }
+            Image {
+                anchors.verticalCenter: parent.verticalCenter
+                source: "images/navigation_previous_item.png"
+            }
+            MouseArea {
+                id: backmouse
+                anchors.fill: parent
+                anchors.margins: -10
+                onClicked: pageStack.pop()
+            }
+        }
+
+        Text {
+            font.pixelSize: 42
+            Behavior on x { NumberAnimation{ easing.type: Easing.OutCubic} }
+            x: backButton.x + backButton.width + 20
+            anchors.verticalCenter: parent.verticalCenter
+            color: "white"
+            text: "Widget Gallery"
+        }
+    }
+
+    ListModel {
+        id: pageModel
+        ListElement {
+            title: "Buttons"
+            page: "content/ButtonPage.qml"
+        }
+        ListElement {
+            title: "Sliders"
+            page: "content/SliderPage.qml"
+        }
+        ListElement {
+            title: "ProgressBar"
+            page: "content/ProgressBarPage.qml"
+        }
+        ListElement {
+            title: "Tabs"
+            page: "content/TabBarPage.qml"
+        }
+        ListElement {
+            title: "TextInput"
+            page: "content/TextInputPage.qml"
+        }
+    }
+
+    StackView {
+        id: pageStack
+        anchors.left: parent.left
+        anchors.right: parent.right
+        anchors.bottom: parent.bottom
+        anchors.top: toolbar.bottom
+
+        initialItem: Item {
+            width: parent.width
+            height: parent.height
+            ListView {
+                model: pageModel
+                anchors.fill: parent
+                delegate: AndroidDelegate {
+                    text: title
+                    onClicked: pageStack.push(Qt.resolvedUrl(page))
+                }
+            }
+        }
+    }
+
+}