/****************************************************************************
**
** Copyright (C) 2014 Digia Plc and/or its subsidiary(-ies).
** Contact: For any questions to Digia, please use the contact form at
** http://qt.digia.com/
**
** This file is part of the examples of the Qt Enterprise Embedded.
**
** $QT_BEGIN_LICENSE:BSD$
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Digia Plc and its Subsidiary(-ies) nor the names
**     of its contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.0
import QtSensors 5.0

Item {
    function calc() {
        if (xAnimation.running || yAnimation.running)
            return

        var newX = (bubble.x + calcRoll(accel.reading.x, accel.reading.y, accel.reading.z) * .8)
        var newY = (bubble.y - calcPitch(accel.reading.x, accel.reading.y, accel.reading.z) * .8)

        if (newX < 0)
            newX = 0
        if (newY < 0)
            newY = 0

        var right = field.width - bubble.width
        var bottom = field.height - bubble.height

        if (newX > right)
            newX = right
        if (newY > bottom)
            newY = bottom

        bubble.x = newX
        bubble.y = newY

        yBehavior.enabled = true
        xBehavior.enabled = true
    }

    Rectangle {
        id: field
        color: "lightblue"
        border.width: 1
        border.color: "darkblue"
        width: parent.width
        height: parent.height
        Accelerometer {
            id: accel
            active:true
        }

        Timer {
            interval: 100
            running: true
            repeat: true
            onTriggered: calc()
        }

        Image {
            id: bubble
            source: "bluebubble.png"
            property real centerX: parent.width / 2
            property real centerY: parent.height / 2;
            property real bubbleCenter: bubble.width / 2
            x: centerX - bubbleCenter
            y: centerY - bubbleCenter
            smooth: true

            Behavior on y {
                id: yBehavior
                enabled: false
                SmoothedAnimation {
                    id: yAnimation
                    easing.type: Easing.Linear
                    duration: 40
                    onRunningChanged: calc()
                }
            }
            Behavior on x {
                id: xBehavior
                enabled: false
                SmoothedAnimation {
                    id: xAnimation
                    easing.type: Easing.Linear
                    duration: 40
                    onRunningChanged: calc()
                }
            }
        }
    }

    function calcPitch(x,y,z) {
        return Math.atan(y / Math.sqrt(x*x + z*z)) * 57.2957795;
    }
    function calcRoll(x,y,z) {
         return Math.atan(x / Math.sqrt(y*y + z*z)) * 57.2957795;
    }
}