summaryrefslogtreecommitdiffstats
path: root/basicsuite/ebike-ui/GeneralTab.qml
blob: 697a451db8d99b6cf2fc718173593bb7877fc5ce (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
/****************************************************************************
**
** Copyright (C) 2017 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the E-Bike demo project.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.9
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import DataStore 1.0

import "./BikeStyle"

Item {
    Column {
        anchors.left: parent.left
        anchors.right: parent.right

        Text {
            height: UILayout.configurationItemHeight
            width: parent.width
            text: qsTr("GENERAL")
            font {
                family: "Montserrat, Medium"
                weight: Font.Medium
                pixelSize: UILayout.configurationTitleSize
            }
            color: Colors.tabTitleColor
            verticalAlignment: Text.AlignVCenter
        }

        ColumnSpacer {
            color: Colors.tabItemBorder
        }

        ConfigurationItem {
            description: qsTr("Language")

            Text {
                anchors {
                    top: parent.top
                    bottom: parent.bottom
                    right: parent.right
                }
                text: qsTr("English")
                font {
                    family: "Montserrat, Medium"
                    weight: Font.Medium
                    pixelSize: UILayout.languageTextSize
                }
                color: Colors.languageTextColor
                verticalAlignment: Text.AlignVCenter
            }
        }

        ColumnSpacer {
            color: Colors.tabItemBorder
        }

        ConfigurationItem {
            description: qsTr("Brightness")

            Text {
                anchors {
                    right: autoBrightness.left
                    rightMargin: UILayout.checkboxTextOffset
                    verticalCenter: autoBrightness.verticalCenter
                }
                text: qsTr("Auto")
                font {
                    family: "Montserrat, Medium"
                    weight: Font.Medium
                    pixelSize: UILayout.checkboxLabelSize
                }
                color: Colors.checkboxCheckedText
            }

            CheckBox {
                id: autoBrightness
                width: UILayout.checkboxWidth
                anchors {
                    right: brightnessSlider.left
                    rightMargin: UILayout.checkboxSliderOffset
                    verticalCenter: brightnessSlider.verticalCenter
                }
                checked: brightness.automatic

                indicator: Rectangle {
                    implicitWidth: UILayout.checkboxWidth
                    implicitHeight: UILayout.checkboxHeight
                    y: parent.height / 2 - height / 2
                    radius: UILayout.checkboxRadius
                    color: Colors.checkboxUncheckedBackground
                    border.color: autoBrightness.checked ? Colors.checkboxBorderColorChecked : Colors.checkboxBorderColor
                    border.width: autoBrightness.checked ? 2 : 1

                    Image {
                        source: "images/checkmark.png"
                        anchors.centerIn: parent
                        visible: autoBrightness.checked
                    }
                }

                contentItem: Item {}

                onToggled: brightness.automatic = checked
            }

            Slider {
                id: brightnessSlider
                value: 4
                anchors {
                    top: parent.top
                    bottom: parent.bottom
                    right: parent.right
                }
                from: 6
                to: 1
                stepSize: -1
                snapMode: Slider.SnapAlways
                onMoved: brightness.brightness = value

                background: Rectangle {
                    x: brightnessSlider.leftPadding
                    y: brightnessSlider.topPadding + brightnessSlider.availableHeight / 2 - height / 2
                    implicitWidth: UILayout.sliderWidth
                    implicitHeight: UILayout.sliderHeight
                    width: brightnessSlider.availableWidth
                    height: implicitHeight
                    radius: UILayout.sliderHeight / 2
                    color: Colors.sliderBackground

                    Rectangle {
                        // Since gradient is only available vertically, we must draw and rotate
                        width: parent.height
                        height: brightnessSlider.visualPosition * parent.width
                        radius: UILayout.sliderHeight / 2
                        gradient: Gradient {
                            GradientStop { position: 0; color: Colors.sliderMinimumValue }
                            GradientStop { position: 1; color: Colors.sliderMaximumValue }
                        }

                        transform: Rotation { origin.x: 0; origin.y: UILayout.sliderHeight; angle: -90}
                    }
                }

                handle: Rectangle {
                    x: brightnessSlider.leftPadding + brightnessSlider.visualPosition * (brightnessSlider.availableWidth - width)
                    y: brightnessSlider.topPadding + brightnessSlider.availableHeight / 2 - height / 2
                    implicitWidth: 2 * UILayout.sliderHandleRadius
                    implicitHeight: 2 * UILayout.sliderHandleRadius
                    radius: UILayout.sliderHandleRadius
                    color: Colors.sliderMaximumValue

                    Rectangle {
                        anchors.centerIn: parent
                        implicitWidth: 2 * UILayout.sliderHandleRadiusInner
                        implicitHeight: 2 * UILayout.sliderHandleRadiusInner
                        radius: UILayout.sliderHandleRadiusInner
                        color: Colors.sliderInnerBackground
                    }
                }
            }
        }

        ColumnSpacer {
            color: Colors.tabItemBorder
        }

        ConfigurationItem {
            description: qsTr("Units")

            RoundButton {
                id: kmhButton
                width: UILayout.unitButtonWidthMargin * 2 + kmhText.implicitWidth
                height: UILayout.unitButtonHeight
                radius: height / 2
                anchors {
                    verticalCenter: parent.verticalCenter
                    right: parent.right
                }

                background: Rectangle {
                    width: parent.width
                    height: parent.height
                    radius: parent.radius
                    color: datastore.unit === DataStore.Kmh ? Colors.activeButtonBackground : Colors.inactiveButtonBackground
                    border.color: Colors.inactiveButtonBorder
                    border.width: datastore.unit === DataStore.Kmh ? 0 : 1
                }

                contentItem: Text {
                    id: kmhText
                    font {
                        family: "Montserrat, Medium"
                        weight: Font.Medium
                        pixelSize: UILayout.unitFontSize
                    }
                    text: "km/h"
                    color: datastore.unit === DataStore.Kmh ? Colors.activeButtonText : Colors.inactiveButtonText
                    horizontalAlignment: Text.AlignHCenter
                    verticalAlignment: Text.AlignVCenter
                }

                onClicked: datastore.unit = DataStore.Kmh
            }

            RoundButton {
                id: mphButton
                width: UILayout.unitButtonWidthMargin * 2 + mphText.implicitWidth
                height: UILayout.unitButtonHeight
                radius: height / 2
                anchors {
                    verticalCenter: parent.verticalCenter
                    right: kmhButton.left
                    rightMargin: UILayout.unitButtonSpacing
                }

                background: Rectangle {
                    width: parent.width
                    height: parent.height
                    radius: parent.radius
                    color: datastore.unit === DataStore.Mph ? Colors.activeButtonBackground : Colors.inactiveButtonBackground
                    border.color: Colors.inactiveButtonBorder
                    border.width: datastore.unit === DataStore.Mph ? 0 : 1
                }

                contentItem: Text {
                    id: mphText
                    text: "mph"
                    font {
                        family: "Montserrat, Medium"
                        weight: Font.Medium
                        pixelSize: UILayout.unitFontSize
                    }
                    color: datastore.unit === DataStore.Mph ? Colors.activeButtonText : Colors.inactiveButtonText
                    horizontalAlignment: Text.AlignHCenter
                    verticalAlignment: Text.AlignVCenter
                }

                onClicked: datastore.unit = DataStore.Mph
            }
        }

        ColumnSpacer {
            color: Colors.tabItemBorder
        }
    }
}