summaryrefslogtreecommitdiffstats
path: root/basicsuite/ebike-ui/SpeedView.qml
blob: d62e7104435154caaaccbf41806d6cbef86a79f3 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
370
371
372
373
374
375
376
377
378
379
380
381
382
383
384
385
386
387
388
389
390
391
392
393
394
395
396
397
398
399
400
401
402
403
404
405
406
407
408
409
410
411
412
413
414
415
416
417
418
419
420
421
422
423
424
425
426
427
428
429
430
431
432
433
434
435
436
437
438
439
440
441
442
443
444
445
446
447
448
449
450
451
452
453
454
455
456
457
458
459
460
461
462
463
464
465
466
467
468
469
470
471
472
473
474
475
476
477
478
479
480
481
482
483
484
485
486
487
488
489
490
491
492
493
494
495
496
497
498
499
500
501
502
503
504
505
506
507
508
509
510
511
512
513
514
515
516
517
518
519
520
521
522
523
524
525
526
/****************************************************************************
**
** Copyright (C) 2017 The Qt Company Ltd.
** Contact: http://www.qt.io/licensing/
**
** This file is part of the E-Bike demo project.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/

import QtQuick 2.9
import DataStore 1.0
import "./BikeStyle"

Rectangle {
    width: UILayout.speedViewRadius * 2 + 2
    height: UILayout.speedViewRadius * 2 + 2
    color: "transparent"
    radius: width * 0.5
    z: 1
    anchors {
        horizontalCenter: parent.horizontalCenter
        top: parent.top
        topMargin: UILayout.speedViewTop
    }
    property int dotcount: UILayout.speedViewDots
    property int curvewidth: UILayout.speedViewInnerWidth
    property int speedTextSize: UILayout.speedTextSize
    property int speedBaselineOffset: UILayout.speedBaselineOffset + 1
    property int innerRadius: UILayout.speedViewInnerRadius
    property int speedUnitsSize: UILayout.speedUnitsSize
    property int speedUnitBaselineOffset: UILayout.speedTextUnitMargin
    property int speedIconsOffset: UILayout.speedIconsCenterOffset
    property int speedInfoTextsOffset: 0
    property int speedInfoTextsSize: UILayout.speedInfoTextsSize
    property int speedInfoUnitsOffset: UILayout.speedInfoUnitsOffset
    property int assistPowerIconOffset: UILayout.assistPowerIconOffset
    property bool enlarged: false
    property alias cornerRectangle: cornerRectangle
    property bool showZero: false

    signal showMain()

    // Speed info
    Text {
        id: speedText
        anchors {
            horizontalCenter: speedView.horizontalCenter
            baseline: speedView.bottom
            baselineOffset: -speedBaselineOffset
        }

        color: Colors.speedText
        font {
            family: "Teko, Light"
            weight: Font.Light
            pixelSize: speedTextSize
        }
        text: showZero ? "0" : datastore.speed.toFixed(0)
    }

    Text {
        id: speedUnit
        anchors {
            horizontalCenter: speedText.horizontalCenter
            baseline: speedText.baseline
            baselineOffset: speedUnitBaselineOffset
        }

        color: Colors.speedUnit
        font {
            family: "Montserrat, Light"
            weight: Font.Light
            pixelSize: speedUnitsSize
        }
        text: datastore.unit === DataStore.Kmh ? qsTr("km/h") : qsTr("mph")
    }

    // Average speed info
    Text {
        id: averageSpeedText
        anchors {
            baseline: speedText.baseline
            baselineOffset: speedInfoTextsOffset
            horizontalCenter: speedText.horizontalCenter
            horizontalCenterOffset: -speedIconsOffset
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.averageSpeedText
        font {
            family: "Teko, Light"
            weight: Font.Light
            pixelSize: speedInfoTextsSize
        }
        text: datastore.averagespeed.toFixed(0)
    }

    Text {
        id: averageSpeedUnit
        anchors {
            horizontalCenter: averageSpeedText.horizontalCenter
            baseline: averageSpeedText.baseline
            baselineOffset: speedInfoUnitsOffset
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.averageSpeedUnit
        font {
            family: "Montserrat, Light"
            weight: Font.Light
            pixelSize: speedUnitsSize
        }
        horizontalAlignment: Text.AlignHCenter
        text: datastore.unit === DataStore.Kmh ? qsTr("AVG\nkm/h") : qsTr("AVG\nmph")
    }

    Image {
        id: averageSpeedIcon
        width: UILayout.averageSpeedIconWidth
        height: UILayout.averageSpeedIconHeight
        source: "images/speed.png"
        anchors {
            horizontalCenter: averageSpeedText.horizontalCenter
            bottom: averageSpeedText.top
            bottomMargin: UILayout.averageSpeedIconMargin
        }
        visible: speedView.state !== "CORNERED"
    }

    // Assist info
    Text {
        id: assistDistanceText
        anchors {
            baseline: speedText.baseline
            baselineOffset: speedInfoTextsOffset
            horizontalCenter: speedText.horizontalCenter
            horizontalCenterOffset: speedIconsOffset
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.assistDistanceText
        font {
            family: "Teko, Light"
            weight: Font.Light
            pixelSize: speedInfoTextsSize
        }
        text: datastore.assistdistance.toFixed(0)
    }

    Text {
        id: assistDistanceUnit
        anchors {
            horizontalCenter: assistDistanceText.horizontalCenter
            baseline: assistDistanceText.baseline
            baselineOffset: speedInfoUnitsOffset
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.assistDistanceUnit
        font {
            family: "Montserrat, Light"
            weight: Font.Light
            pixelSize: speedUnitsSize
        }
        horizontalAlignment: Text.AlignHCenter
        text: datastore.unit === DataStore.Kmh ? qsTr("km\nassist\nleft") : qsTr("mi.\nassist\nleft")
    }

    Image {
        id: assistDistanceIcon
        width: UILayout.assistDistanceIconWidth
        height: UILayout.assistDistanceIconHeight
        source: "images/battery.png"
        anchors {
            horizontalCenter: assistDistanceText.horizontalCenter
            bottom: assistDistanceText.top
            bottomMargin: UILayout.assistDistanceIconMargin
        }
        visible: speedView.state !== "CORNERED"
    }

    // Assist power icon
    Image {
        id: assistPowerIcon
        width: UILayout.assistPowerTconWidth
        height: UILayout.assistPowerTconHeight
        source: "images/assist.png"
        anchors {
            horizontalCenter: speedView.horizontalCenter
            top: parent.verticalCenter
            topMargin: assistPowerIconOffset
        }
        visible: speedView.state !== "CORNERED"
    }

    Gradient {
        id: assistPowerGradient
        GradientStop { position: 0.0; color: Colors.assistPowerGradientStart }
        GradientStop { position: 1.0; color: Colors.assistPowerGradientEnd }
    }

    // Assist power circles
    Rectangle {
        id: assistPowerIcon1
        width: UILayout.assistPowerCircleRadius * 2
        height: width
        radius: UILayout.assistPowerCircleRadius
        anchors {
            right: assistPowerIcon2.left
            rightMargin: UILayout.assistPowerCircleOffset
            bottom: assistPowerIcon2.bottom
            bottomMargin: UILayout.assistPowerCircleVerticalOffset
        }
        color: Colors.assistPowerEmpty
        gradient: datastore.assistpower > 2.0 ? assistPowerGradient : null
        visible: speedView.state !== "CORNERED"
    }

    Rectangle {
        id: assistPowerIcon2
        width: UILayout.assistPowerCircleRadius * 2
        height: width
        radius: UILayout.assistPowerCircleRadius
        anchors {
            right: parent.horizontalCenter
            rightMargin: UILayout.assistPowerCircleOffset / 2
            top: assistPowerIcon.bottom
            topMargin: UILayout.assistPowerCircleTopMargin
        }
        color: Colors.assistPowerEmpty
        gradient: datastore.assistpower > 25.0 ? assistPowerGradient : null
        visible: speedView.state !== "CORNERED"
    }

    Rectangle {
        id: assistPowerIcon3
        width: UILayout.assistPowerCircleRadius * 2
        height: width
        radius: UILayout.assistPowerCircleRadius
        anchors {
            left: parent.horizontalCenter
            leftMargin: UILayout.assistPowerCircleOffset / 2
            top: assistPowerIcon.bottom
            topMargin: UILayout.assistPowerCircleTopMargin
        }
        color: Colors.assistPowerEmpty
        gradient: datastore.assistpower > 50.0 ? assistPowerGradient : null
        visible: speedView.state !== "CORNERED"
    }

    Rectangle {
        id: assistPowerIcon4
        width: UILayout.assistPowerCircleRadius * 2
        height: width
        radius: UILayout.assistPowerCircleRadius
        anchors {
            left: assistPowerIcon3.right
            leftMargin: UILayout.assistPowerCircleOffset
            bottom: assistPowerIcon3.bottom
            bottomMargin: UILayout.assistPowerCircleVerticalOffset
        }
        color: Colors.assistPowerEmpty
        gradient: datastore.assistpower > 75.0 ? assistPowerGradient : null
        visible: speedView.state !== "CORNERED"
    }

    // Numbers for speed and battery level
    Text {
        anchors {
            baseline: parent.bottom
            baselineOffset: 20
            right: parent.horizontalCenter
            rightMargin: 10
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "0"
    }

    Text {
        anchors {
            baseline: parent.bottom
            baselineOffset: 20
            left: parent.horizontalCenter
            leftMargin: 10
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "0 %"
    }

    Text {
        anchors {
            baseline: parent.verticalCenter
            baselineOffset: -10
            right: parent.left
            rightMargin: 9
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "30"
    }

    Text {
        anchors {
            baseline: parent.verticalCenter
            baselineOffset: -10
            left: parent.right
            leftMargin: 9
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "50 %"
    }

    Text {
        anchors {
            baseline: parent.top
            baselineOffset: -10
            right: parent.horizontalCenter
            rightMargin: 10
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "60"
    }

    Text {
        anchors {
            baseline: parent.top
            baselineOffset: -10
            left: parent.horizontalCenter
            leftMargin: 10
        }
        visible: speedView.state !== "CORNERED"

        color: Colors.dottedRing
        font {
            family: "Montserrat, Regular"
            weight: Font.Normal
            pixelSize: UILayout.ringValueText
        }
        text: "100 %"
    }

    Rectangle {
        id: cornerRectangle
        width: UILayout.speedViewRadiusMinified
        height: width
        // By default this is centered, and invisible
        anchors.horizontalCenter: speedView.horizontalCenter
        anchors.verticalCenter: speedView.verticalCenter
        color: "transparent"
        radius: 10
        z: -1

        Image {
            source: "images/small_speedometer_arrow.png"
            width: UILayout.speedometerCornerArrowWidth
            height: UILayout.speedometerCornerArrowHeight
            anchors.left: parent.left
            anchors.bottom: parent.bottom
            visible: swipeView.currentIndex != 1
        }
    }

    Image {
        source: "images/small_speedometer_shadow.png"
        anchors {
            horizontalCenter: parent.horizontalCenter
            verticalCenter: parent.verticalCenter
            horizontalCenterOffset: 1
            verticalCenterOffset: 1
        }
        z: -1

        visible: speedView.state == "CORNERED"
    }

    Canvas {
        id: speedArc
        anchors.fill: parent

        Component.onCompleted: {
            datastore.onSpeedChanged.connect(speedArc.requestPaint)
            datastore.onBatterylevelChanged.connect(speedArc.requestPaint)
        }

        onPaint: {
            var ctx = getContext("2d");
            ctx.reset();

            var currentRadius = (speedView.width - 2) / 2;
            var centerX = speedView.width / 2;
            var centerY = speedView.height / 2;

            // Draw the dotted circle (if not in corner mode)
            if (speedView.state !== "CORNERED") {
                ctx.fillStyle = Colors.dottedRing;
                var angleStep = Math.PI * 2.0 / dotcount;
                for (var angle = 0; angle <= Math.PI * 2; angle += angleStep) {
                    var x = currentRadius * Math.cos(angle);
                    var y = currentRadius * Math.sin(angle);
                    ctx.fillRect(centerX + x, centerY + y, 2, 2);
                }
            }

            // Draw speed and battery view bases
            ctx.lineCap = "round";
            ctx.strokeStyle = Colors.dottedRing;
            ctx.lineWidth = curvewidth;
            ctx.beginPath();
            ctx.arc(centerX, centerY, innerRadius,
                    UILayout.speedViewSpeedStart, UILayout.speedViewSpeedEnd);
            ctx.stroke();
            ctx.beginPath();
            ctx.arc(centerX, centerY, innerRadius,
                    UILayout.speedViewBatteryStart, UILayout.speedViewBatteryEnd, true);
            ctx.stroke();

            // Draw speed gradient
            if (!showZero) {
                var speedArcLength = UILayout.speedViewSpeedEnd - UILayout.speedViewSpeedStart;
                var speedAngle = Math.min(UILayout.speedViewSpeedEnd,
                                          UILayout.speedViewSpeedStart + speedArcLength * (datastore.speed / 60));
                var speedAngleX = Math.cos(speedAngle) * innerRadius;
                var speedAngleY = Math.sin(speedAngle) * innerRadius;
                var speedGradient = ctx.createLinearGradient(centerX, centerY + innerRadius,
                                                             centerX + speedAngleX, centerY + speedAngleY);
                speedGradient.addColorStop(0.0, Colors.speedGradientStart);
                speedGradient.addColorStop(1.0, Colors.speedGradientEnd);
                ctx.strokeStyle = speedGradient;
                ctx.beginPath();
                ctx.arc(centerX, centerY, innerRadius,
                        UILayout.speedViewSpeedStart, speedAngle);
                ctx.stroke();
            }

            // Draw battery gradient
            var batteryArcLength = UILayout.speedViewBatteryEnd - UILayout.speedViewBatteryStart;
            var batteryAngle = Math.max(UILayout.speedViewBatteryEnd,
                                       UILayout.speedViewBatteryStart + batteryArcLength * (datastore.batterylevel / 100));
            var batteryAngleX = Math.cos(batteryAngle) * innerRadius;
            var batteryAngleY = Math.sin(batteryAngle) * innerRadius;
            var batteryGradient = ctx.createLinearGradient(centerX, centerY + innerRadius,
                                                           centerX + batteryAngleX, centerY + batteryAngleY);
                                                           //centerX, centerY - innerRadius);
            batteryGradient.addColorStop(0.0, Colors.batteryGradientStart);
            batteryGradient.addColorStop(1.0, Colors.batteryGradientEnd);
            ctx.strokeStyle = batteryGradient;
            ctx.beginPath();
            ctx.arc(centerX, centerY, innerRadius,
                    UILayout.speedViewBatteryStart, batteryAngle, true);
            ctx.stroke();
        }
    }

    MouseArea {
        anchors.fill: parent
        onClicked: {
            if (enlarged)
                enlarged = false
            else if (swipeView.currentIndex === 1)
                enlarged = true
            else
                speedView.showMain()
        }
    }
}