summaryrefslogtreecommitdiffstats
path: root/basicsuite/mediaplayer/FileBrowser.qml
blob: 5ffe1306c1a5bcb25b46ffedf9f9d16a68af2521 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
/****************************************************************************
**
** Copyright (C) 2016 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the examples of Qt for Device Creation.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of The Qt Company Ltd nor the names of its
**     contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.0
import Qt.labs.folderlistmodel 2.0
import QtQuick.Controls 1.4

Item {
    id: fileBrowser

    property string folder: "file:///data/videos"

    signal fileSelected(string file)

    function selectFile(file) {
        loader.sourceComponent = undefined
        fileBrowser.fileSelected("file://" + file)
    }

    Loader {
        id: loader
        anchors.fill: parent
    }

    function show() {
        loader.sourceComponent = fileBrowserComponent
    }

    Component {
        id: fileBrowserComponent

        Rectangle {
            id: root
            color: "white"
            property alias folder: folders.folder

            FolderListModel {
                id: folders
                folder: fileBrowser.folder
                nameFilters: [ "*.3g2", "*.3gp", "*.asf", "*.avi", "*.drc", "*.flv", "*.f4v", "*.f4p",
                    "*.f4a", "*.f4b", "*.gif", "*.gifv", "*.m4v", "*.mkv", "*.mng", "*.mov", "*.qt",
                    "*.mp4", "*.m4p", "*.m4v", "*.mpg", "*.mp2", "*.mpeg", "*.mpe", "*.mpv", "*.m2v",
                    "*.mxf", "*.nsv", "*.ogv", "*.ogg", "*.rm", "*.rmvb", "*.roq", "*.svi", "*.vob",
                    "*.webm", "*.wmv", "*.yuv", "*.aa", "*.aac", "*.aax", "*.act", "*.aiff", "*.amr",
                    "*.ape", "*.au", "*.awb", "*.dct", "*.dss", "*.flac", "*.gsm", "*.m4a", "*.m4b",
                    "*.m4p", "*.mp3", "*.mpc", "*.ogg", "*.oga", "*.vox", "*.wav", "*.wma"
                ]
            }

            Component {
                id: folderDelegate

                Item {
                    width: root.width / 5
                    height: width

                    Text {
                        id: nameText
                        anchors { top: parent.bottom; left: parent.left; right: parent.right; bottom: parent.bottom }
                        anchors.topMargin:  -parent.height * .2
                        anchors.leftMargin:  parent.width * .1
                        anchors.rightMargin: parent.width * .1
                        anchors.bottomMargin:  -parent.height * .1
                        wrapMode: Text.WrapAtWordBoundaryOrAnywhere
                        text: fileName
                        font.pixelSize: parent.height * .1
                        color: view.currentIndex === index ? "#80c342" : "#46484a"
                        elide: Text.ElideRight
                    }

                    Item {
                        id: wrapper

                        function launch() {
                            if (folders.isFolder(index))
                                down(filePath);
                            else
                                fileBrowser.selectFile(filePath)
                        }

                        anchors.fill: parent
                        anchors.margins: parent.width * .1

                        Image {
                            anchors.top: parent.top
                            anchors.topMargin: -view.cellHeight * .2
                            anchors.right: parent.right
                            anchors.left: parent.left
                            anchors.bottom: parent.bottom
                            fillMode: Image.PreserveAspectFit

                            source:  folders.isFolder(index) ? "images/icon_folder.png" : "images/icon_video.png"
                        }

                        MouseArea {
                            id: mouseRegion
                            anchors.fill: parent
                            onClicked: { wrapper.launch() }
                        }
                    }
                }
            }

            GridView {
                id: view
                anchors.top: titleBar.bottom
                anchors.bottom: parent.bottom
                x: 0
                width: parent.width
                model: folders
                delegate: folderDelegate
                cellWidth: root.width / 5
                cellHeight: cellWidth
                focus: true

                Component.onCompleted: forceActiveFocus();

                Keys.onPressed: {
                    if (event.key === Qt.Key_Escape) {
                        fileBrowser.selectFile("")
                    } else if (event.key === Qt.Key_Return) {
                        if (folders.isFolder(view.currentIndex)) {


                            down(folders.get(view.currentIndex, "filePath"))
                        } else {
                            fileBrowser.selectFile(folders.get(view.currentIndex, "filePath"))
                        }

                    } else if (event.key === Qt.Key_Backspace) {
                        up()
                    }
                }
            }

            Rectangle {
                width: parent.width;
                height: 70
                color: "#f6f6f6"
                id: titleBar

                Button {
                    id: backButton
                    text: qsTr("Back")
                    anchors.left: parent.left
                    anchors.leftMargin: parent.width * .05
                    anchors.verticalCenter: parent.verticalCenter
                    onClicked: up()
                }

                Text {
                    anchors.left: backButton.right;
                    anchors.leftMargin: parent.width * .05
                    anchors.right: cancelButton.left
                    anchors.rightMargin: parent.width * .05
                    anchors.top: parent.top
                    anchors.bottom: parent.bottom

                    text: String(folders.folder).replace("file://", "")
                    color: "#46484a"
                    elide: Text.ElideLeft
                    verticalAlignment: Text.AlignVCenter
                    font.pixelSize: backButton.height * .8
                }

                Button {
                    id: cancelButton
                    text: qsTr("Cancel")
                    checkable: true
                    checked: true
                    anchors.right: parent.right
                    anchors.rightMargin: parent.width * .05
                    anchors.verticalCenter: parent.verticalCenter
                    onClicked: fileBrowser.selectFile("")
                }

                Rectangle {
                    width: parent.width
                    anchors.bottom: parent.bottom
                    height: 2
                    color: "#e4e4e4"
                }
            }

            function down(path) {
                if (folderChangeAnimation.running)
                    return;

                folderChangeAnimation.targetFolder = "file://" + path;
                folderChangeAnimation.direction = "down"
                folderChangeAnimation.restart()
            }

            function up() {
                var path = folders.parentFolder;

                if (path.toString() === "")
                    return;

                if (folderChangeAnimation.running)
                    return;

                folderChangeAnimation.targetFolder = path
                folderChangeAnimation.direction = "up"
                folderChangeAnimation.restart()
            }

            SequentialAnimation {
                id: folderChangeAnimation
                property string targetFolder: ""
                property string direction: "up"

                alwaysRunToEnd: true

                NumberAnimation {
                    target: view
                    property: "x"
                    from: 0
                    to: folderChangeAnimation.direction === "up" ? root.width : -root.width
                    duration: 250
                }

                ScriptAction {
                    script: root.folder = folderChangeAnimation.targetFolder
                }

                NumberAnimation {
                    target: view
                    property: "x"
                    from: folderChangeAnimation.direction === "up" ? -root.width : root.width
                    to: 0
                    duration: 250
                }
            }
        }
    }
}