summaryrefslogtreecommitdiffstats
path: root/tradeshow/iot-sensortag/resources/base/TemperatureChart.qml
blob: 5a98029812e228e0d5af0b1dad929460a95fb707 (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
/****************************************************************************
**
** Copyright (C) 2017 The Qt Company Ltd.
** Contact: https://www.qt.io/licensing/
**
** This file is part of the examples of Qt for Device Creation.
**
** $QT_BEGIN_LICENSE:BSD$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see https://www.qt.io/terms-conditions. For further
** information use the contact form at https://www.qt.io/contact-us.
**
** BSD License Usage
** Alternatively, you may use this file under the terms of the BSD license
** as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of The Qt Company Ltd nor the names of its
**     contributors may be used to endorse or promote products derived
**     from this software without specific prior written permission.
**
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
** $QT_END_LICENSE$
**
****************************************************************************/
import QtQuick 2.7
import QtCharts 2.1
import SensorTag.DataProvider 1.0

BaseChart {
    id: tempHolderRect

    property int temperatureSeriesIndex: 0
    property int maxNumOfTempReadings: 240
    property real minimum: 10
    property real maximum: 40

    property real minValue: Number.MAX_VALUE
    property real maxValue: Number.MIN_VALUE
    readonly property real avgValue: (maxValue - minValue) / 2
    property real value

    readonly property color legendColor: "white"
    readonly property color chartColor: "#15bdff"

    onSensorChanged: if (sensor) {
        sensor.infraredCelsiusTemperatureChanged.connect(contentItem.updateTemperatureGraph)
    }

    title: qsTr("Ambient Temperature")

    content: Item {
        anchors.fill: parent

        function updateTemperatureGraph() {
            avgTempSeries.append(temperatureSeriesIndex, sensor.infraredAmbientTemperature);

            if (temperatureSeriesIndex >= maxNumOfTempReadings) {
                avgTempSeries.remove(avgTempSeries.at(temperatureSeriesIndex-maxNumOfTempReadings));
                valueAxisX.min++;
                valueAxisX.max++;
            }
            temperatureSeriesIndex++;

            var value = sensor.infraredAmbientTemperature;
            if (minValue > value)
                minValue = value;
            if (maxValue < value)
                maxValue = value;
        }

        Item {
            id: valueReading

            anchors.right: parent.right
            anchors.top: chartView.top
            anchors.topMargin: chartView.plotArea.y - 16
            width: childrenRect.width
            height: childrenRect.height

            Text {
                id: highValue

                text: "Highest\n" + (maxValue !== Number.MIN_VALUE ? maxValue : "--")
                lineHeight: 0.7
                width: 60
                horizontalAlignment: Text.Center
                anchors.horizontalCenter: reading.horizontalCenter
                color: "white"
            }

            Image {
                id: reading

                source: pathPrefix + "AmbientTemperature/ambTemp_display_amb.png"
                anchors.top: highValue.bottom
                anchors.topMargin: 10

                Text {
                    anchors.centerIn: parent
                    text: sensor ? sensor.infraredAmbientTemperature : ""
                    color: "white"
                }
            }

            Text {
                text: (minValue !== Number.MAX_VALUE ? minValue : "--") + "\nLowest"
                lineHeight: 0.8
                width: 60
                horizontalAlignment: Text.Center
                color: "white"
                anchors.top: reading.bottom
                anchors.topMargin: 6
                anchors.horizontalCenter: reading.horizontalCenter
            }

            Text {
                text: "Avg\n" + (sensor ? sensor.barometerTemperatureAverage.toFixed(1) : "")
                lineHeight: 0.8
                width: 60
                horizontalAlignment: Text.Center
                color: "white"
                anchors.left: reading.right
                anchors.verticalCenter: reading.verticalCenter
            }
        }

        ChartView {
            id: chartView

            anchors.top: parent.top
            anchors.bottom: parent.bottom
            anchors.bottomMargin: xLegend.height + 8
            anchors.left: parent.left
            anchors.leftMargin: -25
            anchors.right: valueReading.left
            anchors.rightMargin: -20
            antialiasing: true
            backgroundColor: "transparent"
            legend.visible: false
            margins.top: 0
            margins.bottom: 0
            margins.left: 0

            // Hide the value axis labels; labels are drawn separately.
            ValueAxis {
                id: valueAxisX

                labelsVisible: false
                min: 0
                max: maxNumOfTempReadings + 1
                tickCount: 6
                labelsColor: legendColor
                color: chartColor
                gridLineColor: chartColor
            }

            ValueAxis {
                id: valueAxisY

                labelsVisible: false
                min: minimum
                max: maximum
                tickCount: 7
                color: chartColor
                gridLineColor: chartColor
            }

            LineSeries {
                id: avgTempSeries

                axisX: valueAxisX
                axisY: valueAxisY
                color: chartColor
                width: 1
                useOpenGL: true
            }

            Column {
                id: col
                property int step: (valueAxisY.max - valueAxisY.min) / (valueAxisY.tickCount - 1)
                spacing: (valueAxisY.tickCount - 0.7) / 2
                y: chartView.plotArea.y - 10
                x: 24
                z: 5

                Repeater {
                    model: valueAxisY.tickCount

                    Text {
                        text: valueAxisY.max - index * col.step
                        horizontalAlignment: Text.AlignRight
                        width: 20
                        color: legendColor
                        font: fontMetrics.font
                    }
                }
            }

            Row {
                id: xLegend

                x: chartView.plotArea.x
                y: chartView.plotArea.y + chartView.plotArea.height + height + 6
                spacing: (chartView.plotArea.width) / (valueAxisX.tickCount - 0.7) + 1

                Repeater {
                    model: valueAxisX.tickCount

                    // Enclosing Text inside Item allows layouting Text correctly on the axis
                    Item {
                        width: 1
                        height: 1

                        Text {
                            id: legendText

                            text: index
                            color: legendColor
                            anchors.horizontalCenter: parent.horizontalCenter
                            font: fontMetrics.font
                        }
                    }
                }
            }

            Text {
                text: "°C"
                anchors.top: parent.top
                anchors.topMargin: chartView.plotArea.y - height - 4
                anchors.right: col.right
                color: legendColor
                font: fontMetrics.font
            }

            Text {
                text: "h"
                anchors.top: xLegend.top
                x: chartView.plotArea.x + chartView.plotArea.width + 16
                color: legendColor
                font: fontMetrics.font
            }
        }
    }

    // Create TextMetrics to allow easy use of the same font in the ChartView
    TextMetrics {
        id: fontMetrics

        font.family: "Titillium Web"
        font.pixelSize: 14
        text: "m"
    }
}