blob: 45d12cd5c034748105cc56faab53d6aa40215c51 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
|
/****************************************************************************
**
** Copyright (C) 2017-2018 Pelagicore AG
** Contact: https://www.qt.io/licensing/
**
** This file is part of the Neptune 3 IVI UI.
**
** $QT_BEGIN_LICENSE:GPL-QTAS$
** Commercial License Usage
** Licensees holding valid commercial Qt Automotive Suite licenses may use
** this file in accordance with the commercial license agreement provided
** with the Software or, alternatively, in accordance with the terms
** contained in a written agreement between you and The Qt Company. For
** licensing terms and conditions see https://www.qt.io/terms-conditions.
** For further information use the contact form at https://www.qt.io/contact-us.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 3 or (at your option) any later version
** approved by the KDE Free Qt Foundation. The licenses are as published by
** the Free Software Foundation and appearing in the file LICENSE.GPL3
** included in the packaging of this file. Please review the following
** information to ensure the GNU General Public License requirements will
** be met: https://www.gnu.org/licenses/gpl-3.0.html.
**
** $QT_END_LICENSE$
**
** SPDX-License-Identifier: GPL-3.0
**
****************************************************************************/
import QtQuick 2.6
import QtQuick.Controls 2.2
import QtQuick.Layouts 1.3
import com.pelagicore.styles.neptune 3.0
import controls 1.0
import utils 1.0
import animations 1.0
// NB: We can't use Popup from QtQuick.Controls as it doesn't support a rotated scene
Control {
id: root
width: NeptuneStyle.dp(800)
focus: visible
// X and Y potition of the popup when open.
// By default you have it horizontally centered and vertically aligned to the bottom
property real popupX: (root.parent.width - root.width) / 2
property real popupY: root.parent.height - root.height - NeptuneStyle.dp(90)
property bool headerBackgroundVisible: false
property int headerBackgroundHeight: 0
property Item originItem
property real _openFromX
property real _openFromY
readonly property int minHeight: NeptuneStyle.dp(548)
ScalableBorderImage {
anchors.top: parent.top
width: parent.width
height: root.headerBackgroundHeight
visible: root.headerBackgroundVisible
source: Style.gfx("floating-panel-top-bg")
border {
left: 20
top: 30
right: 20
bottom: 0
}
}
background: ScalableBorderImage {
anchors.fill: root
source: Style.gfx("popup-background-9patch", NeptuneStyle.theme)
anchors.leftMargin: NeptuneStyle.dp(-40)
anchors.rightMargin: NeptuneStyle.dp(-40)
anchors.topMargin: NeptuneStyle.dp(-28)
anchors.bottomMargin: NeptuneStyle.dp(-52)
border.left: 70
border.right: 70
border.top: 50
border.bottom: 90
// click eater
MouseArea {
anchors.fill: parent
acceptedButtons: Qt.AllButtons
onWheel: wheel.accepted = true;
}
}
ToolButton {
anchors.verticalCenter: parent.top
anchors.horizontalCenter: parent.right
width: bg.width
height: bg.height
onClicked: close()
icon.name: "ic-close"
background: Image {
id: bg
width: NeptuneStyle.dp(sourceSize.width)
height: NeptuneStyle.dp(sourceSize.height)
anchors.verticalCenter: parent.verticalCenter
anchors.verticalCenterOffset: NeptuneStyle.dp(4)
source: Style.gfx("popup-close-button-bg", NeptuneStyle.theme)
fillMode: Image.PreserveAspectFit
}
}
Keys.onEscapePressed: close()
function updateOpenFromPosition() {
var originPos = originItem.mapToItem(root.parent, originItem.width/2, originItem.height/2)
_openFromX = originPos.x - (root.width / 2);
_openFromY = originPos.y - root.height;
}
function open() {
updateOpenFromPosition();
state = "open";
}
function close() {
updateOpenFromPosition();
state = "closed";
}
Connections {
target: parent ? parent : null
onOverlayClicked: close()
}
state: "closed"
states: [
State {
name: "open"
PropertyChanges {
target: root
visible: true
x: root.popupX
y: root.popupY
}
PropertyChanges {
target: root.parent
showModalOverlay: true
}
},
State {
name: "closed"
PropertyChanges {
target: root
x: root._openFromX
y: root._openFromY
visible: false
}
PropertyChanges {
target: root.parent
showModalOverlay: false
}
}
]
transitions: [
Transition {
to: "open"
SequentialAnimation {
PropertyAction { target: root; property: "visible"; value: true }
PropertyAction { target: root; property: "transformOrigin"; value: Popup.Bottom }
ParallelAnimation {
DefaultNumberAnimation { target: root; property: "opacity"; from: 0.25; to: 1.0}
DefaultNumberAnimation { target: root; property: "scale"; from: 0.25; to: 1}
DefaultNumberAnimation { target: root; properties: "x,y" }
}
PropertyAction { target: root; property: "transformOrigin"; value: Popup.Center }
}
},
Transition {
from: "open"; to: "closed"
SequentialAnimation {
PropertyAction { target: root; property: "visible"; value: true }
PropertyAction { target: root; property: "transformOrigin"; value: Popup.Bottom }
ParallelAnimation {
DefaultNumberAnimation { target: root; property: "opacity"; to: 0.25 }
DefaultNumberAnimation { target: root; property: "scale"; to: 0.25 }
DefaultNumberAnimation { target: root; properties: "x,y" }
}
PropertyAction { target: root; property: "transformOrigin"; value: Popup.Center }
}
}
]
}
|
