blob: 01c75142ac7aebee762a1c340cae90ac6596cf43 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
|
requires(linux:!android|win32:!winrt|macos)
TEMPLATE = subdirs
include(config.pri)
SUBDIRS += plugins
SUBDIRS += doc
SUBDIRS += tests
# mainly a hint for Qt Creator
QML_IMPORT_PATH += imports/shared imports/system sysui
copydata.file = copydata.pro
copydata.depends = plugins
requires(qtHaveModule(appman_main-private))
SUBDIRS += src
copydata.depends += src
copydata.depends += plugins
SUBDIRS += copydata
# Install all required files
qml.files = apps dev/apps imports sysui styles am-config.yaml Main.qml
qml.path = $$INSTALL_PREFIX/neptune3
INSTALLS += qml
win32: server.files = win32/server.conf
else: server.files = server.conf
server.path = $$INSTALL_PREFIX/neptune3
INSTALLS += server
OTHER_FILES += $$files($$PWD/*.qml, true)
OTHER_FILES += $$files($$PWD/*.qmldir, true)
OTHER_FILES += $$PWD/plugins.yaml.in
OTHER_FILES += .qmake.conf
PLUGINS_DIR = $$OUT_PWD/qml
QMAKE_SUBSTITUTES += $$PWD/plugins.yaml.in
tests.depends = copydata plugins src
|
