blob: d04bcb85420e6e0664d7f38e87cb27b80accb59a (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
|
VERSION = 5.15.0
TEMPLATE = app
TARGET = neptune3-ui
include(../../config.pri)
macos: {
CONFIG -= app_bundle
CONFIG *= separate_debug_info
}
CONFIG *= no_private_qt_headers_warning link_pkgconfig
QT *= appman_main-private testlib gui-private
load(gitUtils.prf)
DEFINES *= NEPTUNE_INFO=\""\\\"$$currentGitRevision()\\\""\"
DEFINES *= "NEPTUNE_VERSION=$$VERSION"
SOURCES = main.cpp
DESTDIR = $$OUT_PWD/../../
android: target.path = $$INSTALL_PREFIX
else: target.path = $$INSTALL_PREFIX/neptune3
INSTALLS += target
win32 {
wrapper.files = neptune3-ui_wrapper.bat
wrapper.path = $$INSTALL_PREFIX/neptune3
INSTALLS += wrapper
}
android: {
SOURCES += \
urlinterceptor.cpp
HEADERS += \
urlinterceptor.h
QML_ROOT_PATH = $$PWD/../../
# Only add the C++ plugins here as these need to be deployed with androiddeployqt
# Don't add QML only plugins here as they are imported using appmans import paths
QML_IMPORT_PATH += $$OUT_PWD/../../imports_shared_cpp \
ANDROID_EXTRA_PLUGINS += \
$$OUT_PWD/../../plugins \
$$[QT_INSTALL_PLUGINS]/ \
ANDROID_EXTRA_LIBS += \
$$[QT_INSTALL_LIBS]/libQt5Sql.so \
}
qtHaveModule(qtsaferenderer):load(qtsaferenderer-tools):qtsaferenderer-tools-available {
#include Qt Safe Renderer part, generate file
CONFIG += qtsaferenderer
SAFE_QML = $$PWD/../../apps/com.theqtcompany.cluster/panels/SafeTelltalesPanel.qml
SAFE_LAYOUT_FONTS = $$PWD/../../imports_shared/assets/fonts/
SAFE_LAYOUT_PATH = $$DESTDIR/qsr-safelayout
DEFINES += USE_QT_SAFE_RENDERER
qsr-safelayout.files = $$DESTDIR/qsr-safelayout
qsr-safelayout.path = $$INSTALL_PREFIX/neptune3
INSTALLS += qsr-safelayout
}
|