3 files changed, 65 insertions, 0 deletions
diff --git a/qmake-features/app.prf b/qmake-features/app.prf
new file mode 100644
index 0000000..0329256
--- /dev/null
+++ b/qmake-features/app.prf
@@ -0,0 +1,10 @@
+TEMPLATE = aux
+
+APPMAN_APP = TRUE
+
+app.files = $$FILES
+app.path = $$OUT_PWD/../install/
+
+isEmpty(NAME): NAME = $$basename(_PRO_FILE_PWD_)
+
+INSTALLS += app
diff --git a/qmake-features/package.prf b/qmake-features/package.prf
new file mode 100644
index 0000000..23d9d3a
--- /dev/null
+++ b/qmake-features/package.prf
@@ -0,0 +1,32 @@
+# generate code coverage information using gcov/lcov/genhtml
+message("PACKAGE")
+CONFIG(debug,debug|release) {
+    equals(TEMPLATE, "subdirs") {
+        package.target = package
+        package.CONFIG = recursive
+        QMAKE_EXTRA_TARGETS += package
+    } equals(APPMAN_APP, "TRUE") {
+
+        !isEmpty(EXTRA_METADATA): OPTIONS += --extra-metadata $$EXTRA_METADATA
+        !isEmpty(EXTRA_METADATA_FILE): OPTIONS += --extra-metadata-file $$EXTRA_METADATA_FILE
+        !isEmpty(EXTRA_SIGNED_METADATA): OPTIONS += --extra-signed-metadata $$EXTRA_SIGNED_METADATA
+        !isEmpty(EXTRA_SIGNED_METADATA_FILE): OPTIONS += --extra-signed-metadata-file $$EXTRA_SIGNED_METADATA_FILE
+
+        # The actual packaging step
+        package.CONFIG += recursive
+        package.commands += @echo && echo "PACKAGING $$NAME" && echo &&
+        package.commands += $$[QT_HOST_BINS]/appman-packager create-package $${OPTIONS} $${BUILD_DIR}/$${NAME}.pkg $$OUT_PWD/../install
+        build_pass|!debug_and_release:package.depends = install
+
+        QMAKE_EXTRA_TARGETS *= package
+
+        QMAKE_CLEAN += $${BUILD_DIR}/$${NAME}.pkg
+    } else {
+        # Create a dummy target for all other project files
+        package.CONFIG += recursive
+        build_pass|!debug_and_release:package.depends = install
+
+        QMAKE_EXTRA_TARGETS *= package
+    }
+}
+
diff --git a/qmake-features/qmlplugin.prf b/qmake-features/qmlplugin.prf
new file mode 100644
index 0000000..59b3895
--- /dev/null
+++ b/qmake-features/qmlplugin.prf
@@ -0,0 +1,23 @@
+# Add a long padded rpath, so the installer can replace it with a relative rpath
+QMAKE_RPATHDIR += "$$INSTALL_PREFIX/long_padding/long_padding/long_padding/long_padding/long_padding\
+                   long_padding/long_padding/long_padding/long_padding/long_padding/long_padding/"
+
+CONFIG += skip_target_version_ext
+TARGET = $$qtLibraryTarget($$TARGET)
+DESTDIR = $$OUT_PWD/imports/$$replace(uri, \\., /)
+
+OTHER_FILES = qmldir
+
+!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
+    copy_qmldir.target = $$replace(DESTDIR, /, $$QMAKE_DIR_SEP)$${QMAKE_DIR_SEP}qmldir
+    copy_qmldir.depends = $$replace(_PRO_FILE_PWD_, /, $$QMAKE_DIR_SEP)$${QMAKE_DIR_SEP}qmldir
+    copy_qmldir.commands = $(COPY_FILE) \"$$copy_qmldir.depends\" \"$$copy_qmldir.target\"
+    QMAKE_EXTRA_TARGETS += copy_qmldir
+    PRE_TARGETDEPS += $$copy_qmldir.target
+}
+
+qmldir.files = qmldir
+installPath = $$OUT_PWD/../install/imports/$$replace(uri, \\., /)
+qmldir.path = $$installPath
+target.path = $$installPath
+INSTALLS += target qmldir