From 7ada3952860398bdeef580e2260901a5f33b689e Mon Sep 17 00:00:00 2001
From: Dominik Holland <dominik.holland@pelagicore.com>
Date: Fri, 31 Aug 2018 16:12:31 +0200
Subject: Introduce a build system for the repository

This enables us to build the needed files and create a package out of it.

Change-Id: Ic0ee97401785e1e61d3b4b71bd4d63a54c1efb98
Reviewed-by: Bramastyo Harimukti Santoso <bramastyo.harimukti.santoso@pelagicore.com>
---
 qmake-features/qmlplugin.prf | 23 +++++++++++++++++++++++
 1 file changed, 23 insertions(+)
 create mode 100644 qmake-features/qmlplugin.prf

(limited to 'qmake-features/qmlplugin.prf')

diff --git a/qmake-features/qmlplugin.prf b/qmake-features/qmlplugin.prf
new file mode 100644
index 0000000..59b3895
--- /dev/null
+++ b/qmake-features/qmlplugin.prf
@@ -0,0 +1,23 @@
+# Add a long padded rpath, so the installer can replace it with a relative rpath
+QMAKE_RPATHDIR += "$$INSTALL_PREFIX/long_padding/long_padding/long_padding/long_padding/long_padding\
+                   long_padding/long_padding/long_padding/long_padding/long_padding/long_padding/"
+
+CONFIG += skip_target_version_ext
+TARGET = $$qtLibraryTarget($$TARGET)
+DESTDIR = $$OUT_PWD/imports/$$replace(uri, \\., /)
+
+OTHER_FILES = qmldir
+
+!equals(_PRO_FILE_PWD_, $$OUT_PWD) {
+    copy_qmldir.target = $$replace(DESTDIR, /, $$QMAKE_DIR_SEP)$${QMAKE_DIR_SEP}qmldir
+    copy_qmldir.depends = $$replace(_PRO_FILE_PWD_, /, $$QMAKE_DIR_SEP)$${QMAKE_DIR_SEP}qmldir
+    copy_qmldir.commands = $(COPY_FILE) \"$$copy_qmldir.depends\" \"$$copy_qmldir.target\"
+    QMAKE_EXTRA_TARGETS += copy_qmldir
+    PRE_TARGETDEPS += $$copy_qmldir.target
+}
+
+qmldir.files = qmldir
+installPath = $$OUT_PWD/../install/imports/$$replace(uri, \\., /)
+qmldir.path = $$installPath
+target.path = $$installPath
+INSTALLS += target qmldir
-- 
cgit v1.2.3