blob: 85d5de37fe9dd05ac4be72d40fb2b3bd390dd6af (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
220
221
222
223
224
225
226
227
228
229
230
231
232
233
234
235
236
237
238
239
240
241
242
243
244
245
246
247
248
249
250
251
252
253
254
255
256
257
258
259
260
261
262
263
264
265
266
267
268
269
270
271
272
273
274
275
276
277
278
279
280
281
282
283
284
285
286
287
288
289
290
291
292
293
294
295
296
297
298
299
300
301
302
303
304
305
306
307
308
309
310
311
312
313
314
315
316
317
318
319
320
321
322
323
324
325
326
327
328
329
330
331
332
333
334
335
336
337
338
339
340
341
342
343
344
345
346
347
348
349
350
351
352
353
354
355
356
357
358
359
360
361
362
363
364
365
366
367
368
369
|
import QtQuick 2.5
import QtQuick.Controls 1.4
import QtQuick.Controls.Styles 1.4
import QtQuick.Layouts 1.2
import "assets"
ToolBar {
id: root
property alias addressBar: urlBar
property string color: settingsView.privateBrowsingEnabled ? "#26282a" : uiColor
property string separatorColor: settingsView.privateBrowsingEnabled ? "#68696a" : uiSeparatorColor
property string highlightColor: settingsView.privateBrowsingEnabled ? "#3c3e40" : buttonPressedColor
property Item webView: null
onWebViewChanged: {
}
visible: opacity != 0.0
opacity: tabView.viewState == "page" ? 1.0 : 0.0
function load(url) {
webView.url = url
homeScreen.state = "disabled"
}
function refresh() {
if (urlBar.text == "")
bookmarksButton.bookmarked = false
else
bookmarksButton.bookmarked = homeScreen.contains(urlBar.text) !== -1
}
state: "enabled"
style: ToolBarStyle {
background: Rectangle {
color: root.color
implicitHeight: toolBarSize + 3
}
padding {
left: 0
right: 0
top: 0
bottom: 0
}
}
Behavior on y {
NumberAnimation { duration: animationDuration }
}
states: [
State {
name: "enabled"
PropertyChanges {
target: root
y: 0
}
},
State {
name: "tracking"
PropertyChanges {
target: root
y: {
var diff = touchReference - touchY
if (velocityY > velocityThreshold) {
if (diff > 0)
return -root.height
else
return 0
}
if (!touchGesture || diff == 0) {
if (y < -root.height / 2)
return -root.height
else
return 0
}
if (diff > root.height)
return -root.height
if (diff > 0) {
if (y == -root.height)
return -root.height
return -diff
}
// diff < 0
if (y == 0)
return 0
diff = Math.abs(diff)
if (diff >= root.height)
return 0
return -root.height + diff
}
}
},
State {
name: "disabled"
PropertyChanges {
target: root
y: -root.height
}
}
]
RowLayout {
height: toolBarSize
anchors {
top: parent.top
right: parent.right
left: parent.left
}
spacing: 0
UIButton {
id: backButton
source: "qrc:///back"
color: root.color
highlightColor: root.highlightColor
onClicked: webView.goBack()
enabled: webView && webView.canGoBack
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
UIButton {
id: forwardButton
source: "qrc:///forward"
color: root.color
highlightColor: root.highlightColor
onClicked: webView.goForward()
enabled: webView && webView.canGoForward
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
Rectangle {
Layout.fillWidth: true
implicitWidth: 10
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.color
}
TextField {
id: urlBar
Layout.fillWidth: true
text: webView ? webView.url : ""
activeFocusOnPress: true
placeholderText: qsTr("Search or type a URL")
focus: false
onActiveFocusChanged: {
if (activeFocus)
root.state = "enabled"
else
root.state = "tracking"
}
UIButton {
id: reloadButton
source: webView && webView.loading ? "qrc:///stop" : "qrc:///refresh"
height: 54
width: height
color: "transparent"
highlightColor: "#eeeeee"
radius: width / 2
anchors {
rightMargin: 1
right: parent.right
verticalCenter: addressBar.verticalCenter;
}
onClicked: { webView.loading ? webView.stop() : webView.reload() }
}
style: TextFieldStyle {
textColor: "black"
font.family: defaultFontFamily
font.pixelSize: 28
selectionColor: uiHighlightColor
selectedTextColor: "black"
placeholderTextColor: placeholderColor
background: Rectangle {
implicitWidth: 514
implicitHeight: 56
border.color: settingsView.privateBrowsingEnabled ? "black" : textFieldStrokeColor
border.width: 1
}
padding {
left: 15
right: reloadButton.width
}
}
onAccepted: {
webView.url = engine.fromUserInput(text)
homeScreen.state = "disabled"
tabView.viewState = "page"
}
onTextChanged: refresh()
onEditingFinished: selectAll()
onFocusChanged: {
if (focus) {
forceActiveFocus()
selectAll()
} else {
urlBar.cursorPosition = 0
deselect()
}
}
}
Rectangle {
Layout.fillWidth: true
implicitWidth: 10
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.color
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
UIButton {
id: homeButton
source: "qrc:///home"
color: root.color
highlightColor: root.highlightColor
onClicked: {
if (homeScreen.state == "disabled" || homeScreen.state == "edit") {
homeScreen.messageBox.state = "disabled"
homeScreen.state = "enabled"
} else if (homeScreen.state != "disabled")
homeScreen.state = "disabled"
}
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
UIButton {
id: pageViewButton
source: "qrc:///tabs"
color: root.color
highlightColor: root.highlightColor
onClicked: {
if (tabView.viewState == "list") {
tabView.viewState = "page"
} else {
tabView.get(tabView.currentIndex).item.webView.takeSnapshot()
homeScreen.state = "disabled"
tabView.viewState = "list"
}
}
Text {
anchors {
centerIn: parent
verticalCenterOffset: 4
}
text: tabView.count
font.family: defaultFontFamily
font.pixelSize: 16
font.weight: Font.DemiBold
color: "white"
}
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
UIButton {
id: bookmarksButton
color: root.color
highlightColor: root.highlightColor
enabled: urlBar.text != "" && !settingsView.privateBrowsingEnabled
property bool bookmarked: false
source: bookmarked ? "qrc:///star_checked" : "qrc:///star"
onClicked: {
if (!webView)
return
var icon = webView.loading ? "" : webView.icon
var idx = homeScreen.contains(webView.url.toString())
if (idx !== -1) {
homeScreen.remove("", idx)
return
}
var count = homeScreen.count
homeScreen.add(webView.title, webView.url, icon, engine.fallbackColor())
if (count < homeScreen.count)
bookmarked = true
}
Component.onCompleted: refresh()
}
Rectangle {
width: 1
anchors {
top: parent.top
bottom: parent.bottom
}
color: root.separatorColor
}
UIButton {
id: settingsButton
source: "qrc:///settings"
color: root.color
highlightColor: root.highlightColor
onClicked: {
tabView.interactive = false
settingsView.state = "enabled"
}
}
}
ProgressBar {
id: progressBar
height: 3
anchors {
left: parent.left
bottom: parent.bottom
right: parent.right
leftMargin: -10
rightMargin: -10
}
style: ProgressBarStyle {
background: Rectangle {
height: 3
color: "#e4e4e4"
}
progress: Rectangle {
color: settingsView.privateBrowsingEnabled ? uiColor : "#317198"
}
}
minimumValue: 0
maximumValue: 100
value: (webView && webView.loadProgress < 100) ? webView.loadProgress : 0
}
}
|
