1 files changed, 58 insertions, 0 deletions
diff --git a/tools/qml/qml.pro b/tools/qml/qml.pro
new file mode 100644
index 0000000000..9c9c398eb6
--- /dev/null
+++ b/tools/qml/qml.pro
@@ -0,0 +1,58 @@
+TEMPLATE = app
+CONFIG += qt \
+    uic
+DESTDIR = ../../bin
+QT += declarative \
+    script \
+    network \
+    sql
+
+contains(QT_CONFIG, opengl) {
+    QT += opengl
+    DEFINES += GL_SUPPORTED
+}
+
+# Input
+HEADERS += qmlruntime.h \
+           proxysettings.h \
+           qfxtester.h \
+           deviceorientation.h \
+           qdeclarativefolderlistmodel.h
+SOURCES += main.cpp \
+           qmlruntime.cpp \
+           proxysettings.cpp \
+           qfxtester.cpp \
+           qdeclarativefolderlistmodel.cpp
+RESOURCES = qmlruntime.qrc
+maemo5 {
+    SOURCES += deviceorientation_maemo.cpp
+} else {
+    SOURCES += deviceorientation.cpp
+}
+FORMS = recopts.ui \
+    proxysettings.ui
+INCLUDEPATH += ../../include/QtDeclarative
+INCLUDEPATH += ../../src/declarative/util
+INCLUDEPATH += ../../src/declarative/graphicsitems
+include(../shared/deviceskin/deviceskin.pri)
+target.path = $$[QT_INSTALL_BINS]
+INSTALLS += target
+
+wince* {
+QT += scripttools \
+    xml \
+    xmlpatterns \
+    phonon
+
+    contains(QT_CONFIG, webkit) {
+        QT += webkit 
+    }
+}
+symbian {
+#    TARGET.UID3 =
+    include($$QT_SOURCE_TREE/examples/symbianpkgrules.pri)
+    TARGET.EPOCHEAPSIZE = 0x20000 0x2000000
+    HEADERS += $$QT_SOURCE_TREE/examples/network/qftp/sym_iap_util.h
+    LIBS += -lesock  -lconnmon -linsock
+    TARGET.CAPABILITY = "All -TCB"
+}