From e5fcad302d86d316390c6b0f62759a067313e8a9 Mon Sep 17 00:00:00 2001
From: Lars Knoll <lars.knoll@nokia.com>
Date: Mon, 23 Mar 2009 10:18:55 +0100
Subject: Long live Qt 4.5!

---
 tools/tools.pro | 30 ++++++++++++++++++++++++++++++
 1 file changed, 30 insertions(+)
 create mode 100644 tools/tools.pro

(limited to 'tools/tools.pro')

diff --git a/tools/tools.pro b/tools/tools.pro
new file mode 100644
index 0000000000..ffc5d63217
--- /dev/null
+++ b/tools/tools.pro
@@ -0,0 +1,30 @@
+TEMPLATE        = subdirs
+
+no-png {
+    message("Some graphics-related tools are unavailable without PNG support")
+} else {
+     SUBDIRS += assistant \
+		pixeltool \
+		porting \
+                qtestlib
+     contains(QT_EDITION, Console) {
+         SUBDIRS += designer/src/uitools     # Linguist depends on this
+     } else {
+         SUBDIRS += designer
+     }
+     SUBDIRS     += linguist
+     wince*: SUBDIRS = qtestlib designer
+     unix:!mac:!embedded:contains(QT_CONFIG, qt3support):SUBDIRS += qtconfig
+     win32:!wince*:!contains(QT_EDITION, OpenSource|Console):SUBDIRS += activeqt
+}
+
+mac {
+    SUBDIRS += macdeployqt
+}
+
+contains(QT_CONFIG, dbus):SUBDIRS += qdbus
+!wince*:contains(QT_CONFIG, xmlpatterns): SUBDIRS += xmlpatterns
+embedded: SUBDIRS += makeqpf
+
+CONFIG+=ordered
+QTDIR_build:REQUIRES = "contains(QT_CONFIG, full-config)"
-- 
cgit v1.2.3