blob: ef251c5c995fb4a0e5933d29b93b46b3b64fb63b (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
|
TEMPLATE = subdirs
CONFIG += ordered
include(WebKit.pri)
SUBDIRS += \
JavaScriptCore \
WebCore
# If the source exists, built it
exists($$PWD/WebKitTools/QtTestBrowser): SUBDIRS += WebKitTools/QtTestBrowser
contains(QT_CONFIG, declarative) {
exists($$PWD/WebKit/qt/declarative): SUBDIRS += WebKit/qt/declarative
}
exists($$PWD/JavaScriptCore/jsc.pro): SUBDIRS += JavaScriptCore/jsc.pro
exists($$PWD/WebKit/qt/tests): SUBDIRS += WebKit/qt/tests
exists($$PWD/WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/DumpRenderTree.pro
!win32:!symbian {
exists($$PWD/WebKitTools/DumpRenderTree/qt/ImageDiff.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/ImageDiff.pro
exists($$PWD/WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro): SUBDIRS += WebKitTools/DumpRenderTree/qt/TestNetscapePlugin/TestNetscapePlugin.pro
}
build-qtscript {
SUBDIRS += \
JavaScriptCore/qt/api/QtScript.pro \
JavaScriptCore/qt/tests
}
symbian {
# Forward the install target to WebCore. A workaround since INSTALLS is not implemented for symbian
install.commands = $(MAKE) -C WebCore install
QMAKE_EXTRA_TARGETS += install
}
include(WebKit/qt/docs/docs.pri)
!isEmpty(QT_BUILD_TREE) {
QMAKE_SUBSTITUTES += qt_webkit_version
qt_webkit_version.input = WebKit/qt/qt_webkit_version.pri
qt_webkit_version.output = $$QT_BUILD_TREE/mkspecs/modules/qt_webkit_version.pri
}
|
