Refactor packaging.

Packaging was always not so good. With the arrival of yet another
packaging system to support, with QtSDK and Harmattan, it was overdue
time to refactor the build system.

Factored out all the places where Qt3D and QtQuick3D dependencies were
exactly 3 levels below the source .pro file. This catches all of the
examples and all of the demos, except for the ones in the tutorials
directories. It is fine if those don't appear in packages, since their
main value is in examining them in the IDE, rather than just having a
package run them for you. It also catches both of the import plugins.

Thus we save a huge amount of duplication of packaging information and
can place the Qt SDK Harmattan packaging into a couple of variables in a
new pkg.pri file. The two deps are now in a qt3d_pkg_dep.pri and
qt3dquick_pkg_dep.pri file which include the pkg.pri.

Change-Id: I28de17d7faa5ccf9157afad99471079c0b62ee87
Reviewed-on: http://codereview.qt.nokia.com/1191
Reviewed-by: Sarah Jane Smith

1 files changed, 54 insertions, 0 deletions

diff --git a/pkg.pri b/pkg.pri
new file mode 100644
index 000000000..0ac19123b
--- /dev/null
+++ b/pkg.pri
@@ -0,0 +1,54 @@
+!CONFIG(pkg_pri_included) {
+CONFIG+=pkg_pri_included
+
+# Config for making example and demo apps packageable
+
+# Note that the paths here all assumed the including .pro file
+# is exactly 3 levels of directory tree below the root
+
+# Include this file after qt3d_pkg_dep.pri or qt3dquick_pkg_dep.pri
+
+qtc_harmattan {
+    CONFIG += maemo
+    CONFIG += package
+    # The Qt SDK / Qt Creator harmattan integration needs some special treatment
+    QT3D_INSTALL_BINS = /bin
+    QT3D_INSTALL_LIBS = /usr/lib
+    QT3D_INSTALL_PLUGINS = /usr/lib/qt4/plugins
+    QT3D_INSTALL_IMPORTS = /usr/lib/qt4/imports
+    QT3D_INSTALL_DATA = /usr/share/qt4
+} else {
+    QT3D_INSTALL_BINS = $$[QT_INSTALL_BINS]
+    QT3D_INSTALL_LIBS = $$[QT_INSTALL_LIBS]
+    QT3D_INSTALL_PLUGINS = $$[QT_INSTALL_PLUGINS]
+    QT3D_INSTALL_IMPORTS = $$[QT_INSTALL_IMPORTS]
+    QT3D_INSTALL_DATA = $$[QT_INSTALL_DATA]
+}
+
+contains(TEMPLATE, app) {
+    package  {
+        maemo {
+            applnk.files = $${TARGET}.desktop
+            applnk.path = /usr/share/applications
+
+            # icons.files is set by qt3dquick_pkg_dep.pri or qt3d_pkg_dep.pri
+            icons.path = /usr/share/themes/base/meegotouch/icons
+            INSTALLS += icons applnk
+        }
+        target.path += $$QT3D_INSTALL_BINS
+        INSTALLS += target
+    } else {
+        DESTDIR = ../../../bin
+    }
+    symbian {
+        vendorinfo = \
+         "%{\"NOKIA\"}" \
+         ":\"NOKIA\""
+
+        my_deployment.pkg_prerules = vendorinfo
+        DEPLOYMENT += my_deployment
+
+        ICON = ../qt3d.svg
+    }
+}
+}