Added QPhongMaterial

QPhongMaterial is a default phong lightning implementation to be used in Qt3D
scenes created from C++.
Supports OpenGL 3.1, 2.0 and ES 2.0

Change-Id: I6f57ccf7ae2264cd0110de2081de841406a5efc4
Reviewed-by: Sean Harmer <sean.harmer@kdab.com>

4 files changed, 126 insertions, 0 deletions

diff --git a/src/render/shaders/es2/phong.frag b/src/render/shaders/es2/phong.frag
new file mode 100644
index 000000000..2bcfe570b
--- /dev/null
+++ b/src/render/shaders/es2/phong.frag
@@ -0,0 +1,43 @@
+#version 120
+
+// TODO: Replace with a uniform block
+uniform vec4 lightPosition = vec4(1.0, 1.0, 0.0, 1.0);
+uniform vec3 lightIntensity = vec3(1.0, 0.0, 1.0);
+
+// TODO: Replace with a struct
+uniform vec3 ka;            // Ambient reflectivity
+uniform vec3 kd;            // Diffuse reflectivity
+uniform vec3 ks;            // Specular reflectivity
+uniform float shininess;    // Specular shininess factor
+
+varying vec3 position;
+varying vec3 normal;
+
+vec3 adsModel( const vec3 pos, const vec3 n )
+{
+    // Calculate the vector from the light to the fragment
+    vec3 s = normalize( vec3( lightPosition ) - pos );
+
+    // Calculate the vector from the fragment to the eye position
+    // (origin since this is in "eye" or "camera" space)
+    vec3 v = normalize( -pos );
+
+    // Reflect the light beam using the normal at this fragment
+    vec3 r = reflect( -s, n );
+
+    // Calculate the diffuse component
+    float diffuse = max( dot( s, n ), 0.0 );
+
+    // Calculate the specular component
+    float specular = 0.0;
+    if ( dot( s, n ) > 0.0 )
+        specular = pow( max( dot( r, v ), 0.0 ), shininess );
+
+    // Combine the ambient, diffuse and specular contributions
+    return lightIntensity * ( ka + kd * diffuse + ks * specular );
+}
+
+void main()
+{
+    gl_FragColor = vec4( adsModel( position, normalize( normal ) ), 1.0 );
+}
diff --git a/src/render/shaders/es2/phong.vert b/src/render/shaders/es2/phong.vert
new file mode 100644
index 000000000..35813d19f
--- /dev/null
+++ b/src/render/shaders/es2/phong.vert
@@ -0,0 +1,19 @@
+#version 120
+
+attribute vec3 vertexPosition;
+attribute vec3 vertexNormal;
+
+varying vec3 position;
+varying vec3 normal;
+
+uniform mat4 modelView;
+uniform mat3 modelViewNormal;
+uniform mat4 mvp;
+
+void main()
+{
+    normal = normalize( modelViewNormal * vertexNormal );
+    position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
+
+    gl_Position = mvp * vec4( vertexPosition, 1.0 );
+}
diff --git a/src/render/shaders/gl3/phong.frag b/src/render/shaders/gl3/phong.frag
new file mode 100644
index 000000000..741f4da9f
--- /dev/null
+++ b/src/render/shaders/gl3/phong.frag
@@ -0,0 +1,45 @@
+#version 150 core
+
+// TODO: Replace with a uniform block
+uniform vec4 lightPosition = vec4(1.0, 1.0, 0.0, 1.0);
+uniform vec3 lightIntensity = vec3(1.0, 0.0, 1.0);
+
+// TODO: Replace with a struct
+uniform vec3 ka;            // Ambient reflectivity
+uniform vec3 kd;            // Diffuse reflectivity
+uniform vec3 ks;            // Specular reflectivity
+uniform float shininess;    // Specular shininess factor
+
+in vec3 position;
+in vec3 normal;
+
+out vec4 fragColor;
+
+vec3 adsModel( const in vec3 pos, const in vec3 n )
+{
+    // Calculate the vector from the light to the fragment
+    vec3 s = normalize( vec3( lightPosition ) - pos );
+
+    // Calculate the vector from the fragment to the eye position
+    // (origin since this is in "eye" or "camera" space)
+    vec3 v = normalize( -pos );
+
+    // Reflect the light beam using the normal at this fragment
+    vec3 r = reflect( -s, n );
+
+    // Calculate the diffuse component
+    float diffuse = max( dot( s, n ), 0.0 );
+
+    // Calculate the specular component
+    float specular = 0.0;
+    if ( dot( s, n ) > 0.0 )
+        specular = pow( max( dot( r, v ), 0.0 ), shininess );
+
+    // Combine the ambient, diffuse and specular contributions
+    return lightIntensity * ( ka + kd * diffuse + ks * specular );
+}
+
+void main()
+{
+    fragColor = vec4( adsModel( position, normalize( normal ) ), 1.0 );
+}
diff --git a/src/render/shaders/gl3/phong.vert b/src/render/shaders/gl3/phong.vert
new file mode 100644
index 000000000..c0f907f29
--- /dev/null
+++ b/src/render/shaders/gl3/phong.vert
@@ -0,0 +1,19 @@
+#version 150 core
+
+in vec3 vertexPosition;
+in vec3 vertexNormal;
+
+out vec3 position;
+out vec3 normal;
+
+uniform mat4 modelView;
+uniform mat3 modelViewNormal;
+uniform mat4 mvp;
+
+void main()
+{
+    normal = normalize( modelViewNormal * vertexNormal );
+    position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
+
+    gl_Position = mvp * vec4( vertexPosition, 1.0 );
+}