3 files changed, 260 insertions, 0 deletions
diff --git a/examples/qt3d/wireframe/shaders/robustwireframe.frag b/examples/qt3d/wireframe/shaders/robustwireframe.frag
new file mode 100644
index 000000000..217e0e761
--- /dev/null
+++ b/examples/qt3d/wireframe/shaders/robustwireframe.frag
@@ -0,0 +1,108 @@
+#version 330 core
+
+uniform struct LightInfo {
+    vec4 position;
+    vec3 intensity;
+} light;
+
+uniform struct LineInfo {
+    float width;
+    vec4 color;
+} line;
+
+uniform vec3 ka;            // Ambient reflectivity
+uniform vec3 kd;            // Diffuse reflectivity
+uniform vec3 ks;            // Specular reflectivity
+uniform float shininess;    // Specular shininess factor
+
+in WireframeVertex {
+    vec3 position;
+    vec3 normal;
+    noperspective vec4 edgeA;
+    noperspective vec4 edgeB;
+    flat int configuration;
+} fs_in;
+
+out vec4 fragColor;
+
+vec3 adsModel( const in vec3 pos, const in vec3 n )
+{
+    // Calculate the vector from the light to the fragment
+    vec3 s = normalize( vec3( light.position ) - pos );
+
+    // Calculate the vector from the fragment to the eye position (the
+    // origin since this is in "eye" or "camera" space
+    vec3 v = normalize( -pos );
+
+    // Refleft the light beam using the normal at this fragment
+    vec3 r = reflect( -s, n );
+
+    // Calculate the diffus component
+    vec3 diffuse = vec3( max( dot( s, n ), 0.0 ) );
+
+    // Calculate the specular component
+    vec3 specular = vec3( pow( max( dot( r, v ), 0.0 ), shininess ) );
+
+    // Combine the ambient, diffuse and specular contributions
+    return light.intensity * ( ka + kd * diffuse + ks * specular );
+}
+
+vec4 shadeLine( const in vec4 color )
+{
+    // Find the smallest distance between the fragment and a triangle edge
+    float d;
+    if ( fs_in.configuration == 0 )
+    {
+        // Common configuration
+        d = min( fs_in.edgeA.x, fs_in.edgeA.y );
+        d = min( d, fs_in.edgeA.z );
+    }
+    else
+    {
+        // Handle configuration where screen space projection breaks down
+        // Compute and compare the squared distances
+        vec2 AF = gl_FragCoord.xy - fs_in.edgeA.xy;
+        float sqAF = dot( AF, AF );
+        float AFcosA = dot( AF, fs_in.edgeA.zw );
+        d = abs( sqAF - AFcosA * AFcosA );
+
+        vec2 BF = gl_FragCoord.xy - fs_in.edgeB.xy;
+        float sqBF = dot( BF, BF );
+        float BFcosB = dot( BF, fs_in.edgeB.zw );
+        d = min( d, abs( sqBF - BFcosB * BFcosB ) );
+
+        // Only need to care about the 3rd edge for some configurations.
+        if ( fs_in.configuration == 1 || fs_in.configuration == 2 || fs_in.configuration == 4 )
+        {
+            float AFcosA0 = dot( AF, normalize( fs_in.edgeB.xy - fs_in.edgeA.xy ) );
+            d = min( d, abs( sqAF - AFcosA0 * AFcosA0 ) );
+        }
+
+        d = sqrt( d );
+    }
+
+    // Blend between line color and phong color
+    float mixVal;
+    if ( d < line.width - 1.0 )
+    {
+        mixVal = 1.0;
+    }
+    else if ( d > line.width + 1.0 )
+    {
+        mixVal = 0.0;
+    }
+    else
+    {
+        float x = d - ( line.width - 1.0 );
+        mixVal = exp2( -2.0 * ( x * x ) );
+    }
+
+    return mix( color, line.color, mixVal );
+}
+
+void main()
+{
+    // Calculate the color from the phong model
+    vec4 color = vec4( adsModel( fs_in.position, normalize( fs_in.normal ) ), 1.0 );
+    fragColor = shadeLine( color );
+}
diff --git a/examples/qt3d/wireframe/shaders/robustwireframe.geom b/examples/qt3d/wireframe/shaders/robustwireframe.geom
new file mode 100644
index 000000000..6eb0ecc76
--- /dev/null
+++ b/examples/qt3d/wireframe/shaders/robustwireframe.geom
@@ -0,0 +1,131 @@
+#version 330 core
+
+layout( triangles ) in;
+layout( triangle_strip, max_vertices = 3 ) out;
+
+in EyeSpaceVertex {
+    vec3 position;
+    vec3 normal;
+} gs_in[];
+
+out WireframeVertex {
+    vec3 position;
+    vec3 normal;
+    noperspective vec4 edgeA;
+    noperspective vec4 edgeB;
+    flat int configuration;
+} gs_out;
+
+uniform mat4 viewportMatrix;
+
+const int infoA[]  = int[]( 0, 0, 0, 0, 1, 1, 2 );
+const int infoB[]  = int[]( 1, 1, 2, 0, 2, 1, 2 );
+const int infoAd[] = int[]( 2, 2, 1, 1, 0, 0, 0 );
+const int infoBd[] = int[]( 2, 2, 1, 2, 0, 2, 1 );
+
+vec2 transformToViewport( const in vec4 p )
+{
+    return vec2( viewportMatrix * ( p / p.w ) );
+}
+
+void main()
+{
+    gs_out.configuration = int(gl_in[0].gl_Position.z < 0) * int(4)
+           + int(gl_in[1].gl_Position.z < 0) * int(2)
+           + int(gl_in[2].gl_Position.z < 0);
+
+    // If all vertices are behind us, cull the primitive
+    if (gs_out.configuration == 7)
+        return;
+
+    // Transform each vertex into viewport space
+    vec2 p[3];
+    p[0] = transformToViewport( gl_in[0].gl_Position );
+    p[1] = transformToViewport( gl_in[1].gl_Position );
+    p[2] = transformToViewport( gl_in[2].gl_Position );
+
+    if (gs_out.configuration == 0)
+    {
+        // Common configuration where all vertices are within the viewport
+        gs_out.edgeA = vec4(0.0);
+        gs_out.edgeB = vec4(0.0);
+
+        // Calculate lengths of 3 edges of triangle
+        float a = length( p[1] - p[2] );
+        float b = length( p[2] - p[0] );
+        float c = length( p[1] - p[0] );
+
+        // Calculate internal angles using the cosine rule
+        float alpha = acos( ( b * b + c * c - a * a ) / ( 2.0 * b * c ) );
+        float beta = acos( ( a * a + c * c - b * b ) / ( 2.0 * a * c ) );
+
+        // Calculate the perpendicular distance of each vertex from the opposing edge
+        float ha = abs( c * sin( beta ) );
+        float hb = abs( c * sin( alpha ) );
+        float hc = abs( b * sin( alpha ) );
+
+        // Now add this perpendicular distance as a per-vertex property in addition to
+        // the position and normal calculated in the vertex shader.
+
+        // Vertex 0 (a)
+        gs_out.edgeA = vec4( ha, 0.0, 0.0, 0.0 );
+        gs_out.normal = gs_in[0].normal;
+        gs_out.position = gs_in[0].position;
+        gl_Position = gl_in[0].gl_Position;
+        EmitVertex();
+
+        // Vertex 1 (b)
+        gs_out.edgeA = vec4( 0.0, hb, 0.0, 0.0 );
+        gs_out.normal = gs_in[1].normal;
+        gs_out.position = gs_in[1].position;
+        gl_Position = gl_in[1].gl_Position;
+        EmitVertex();
+
+        // Vertex 2 (c)
+        gs_out.edgeA = vec4( 0.0, 0.0, hc, 0.0 );
+        gs_out.normal = gs_in[2].normal;
+        gs_out.position = gs_in[2].position;
+        gl_Position = gl_in[2].gl_Position;
+        EmitVertex();
+
+        // Finish the primitive off
+        EndPrimitive();
+    }
+    else
+    {
+        // Viewport projection breaks down for one or two vertices.
+        // Caclulate what we can here and defer rest to fragment shader.
+        // Since this is coherent for the entire primitive the conditional
+        // in the fragment shader is still cheap as all concurrent
+        // fragment shader invocations will take the same code path.
+
+        // Copy across the viewport-space points for the (up to) two vertices
+        // in the viewport
+        gs_out.edgeA.xy = p[infoA[gs_out.configuration]];
+        gs_out.edgeB.xy = p[infoB[gs_out.configuration]];
+
+        // Copy across the viewport-space edge vectors for the (up to) two vertices
+        // in the viewport
+        gs_out.edgeA.zw = normalize( gs_out.edgeA.xy - p[ infoAd[gs_out.configuration] ] );
+        gs_out.edgeB.zw = normalize( gs_out.edgeB.xy - p[ infoBd[gs_out.configuration] ] );
+
+        // Pass through the other vertex attributes
+        gs_out.normal = gs_in[0].normal;
+        gs_out.position = gs_in[0].position;
+        gl_Position = gl_in[0].gl_Position;
+        EmitVertex();
+
+        gs_out.normal = gs_in[1].normal;
+        gs_out.position = gs_in[1].position;
+        gl_Position = gl_in[1].gl_Position;
+        EmitVertex();
+
+        gs_out.normal = gs_in[2].normal;
+        gs_out.position = gs_in[2].position;
+        gl_Position = gl_in[2].gl_Position;
+        EmitVertex();
+
+        // Finish the primitive off
+        EndPrimitive();
+    }
+}
diff --git a/examples/qt3d/wireframe/shaders/robustwireframe.vert b/examples/qt3d/wireframe/shaders/robustwireframe.vert
new file mode 100644
index 000000000..e53a2b594
--- /dev/null
+++ b/examples/qt3d/wireframe/shaders/robustwireframe.vert
@@ -0,0 +1,21 @@
+#version 330 core
+
+in vec3 vertexPosition;
+in vec3 vertexNormal;
+
+out EyeSpaceVertex {
+    vec3 position;
+    vec3 normal;
+} vs_out;
+
+uniform mat4 modelView;
+uniform mat3 modelViewNormal;
+uniform mat4 mvp;
+
+void main()
+{
+    vs_out.normal = normalize( modelViewNormal * vertexNormal );
+    vs_out.position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
+
+    gl_Position = mvp * vec4( vertexPosition, 1.0 );
+}