blob: a11a77ee58fdd7f87b9a9c360528420ee2440056 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
|
TEMPLATE = lib
CONFIG += staticlib
TARGET = $$qtLibraryTarget(examples-common)
QT += core-private 3dcore 3dcore-private 3drender 3dinput 3dlogic qml quick 3dextras
SOURCES += \
qfirstpersoncameracontroller.cpp \
qorbitcontrol.cpp \
qt3dwindow.cpp \
qt3dquickwindow.cpp
HEADERS += \
qfirstpersoncameracontroller.h \
qfirstpersoncameracontroller_p.h \
qorbitcontrol_p.h \
qorbitcontrol.h \
qt3dwindow.h \
qt3dquickwindow.h
QML_FILES = \
$$PWD/OrbitController.qml \
$$PWD/FirstPersonCameraController.qml
OTHER_FILES += \
$$QML_FILES
# Create a resource file for qml files that need to be registered by the plugin
GENERATED_RESOURCE_FILE = $$OUT_PWD/examples-common.qrc
INCLUDED_RESOURCE_FILES = $$QML_FILES
RESOURCE_CONTENT = \
"<RCC>" \
"<qresource prefix=\"/\">"
for(resourcefile, INCLUDED_RESOURCE_FILES) {
resourcefileabsolutepath = $$absolute_path($$resourcefile)
relativepath_in = $$relative_path($$resourcefileabsolutepath, $$_PRO_FILE_PWD_)
relativepath_out = $$relative_path($$resourcefileabsolutepath, $$OUT_PWD)
RESOURCE_CONTENT += "<file alias=\"$$relativepath_in\">$$relativepath_out</file>"
}
RESOURCE_CONTENT += \
"</qresource>" \
"</RCC>"
write_file($$GENERATED_RESOURCE_FILE, RESOURCE_CONTENT)|error("Aborting.")
RESOURCES += $$GENERATED_RESOURCE_FILE
|
