summaryrefslogtreecommitdiffstats
path: root/examples/qt3d/picking-qml/main.qml
blob: 8b7111b4d83a781c2712a1f7737fcfb0bfac4c9d (plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
76
77
78
79
80
81
82
83
84
85
86
87
88
89
90
91
92
93
94
95
96
97
98
99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
147
148
149
150
151
152
153
154
155
156
157
158
159
160
161
162
163
164
165
166
167
168
169
170
171
172
173
174
175
176
177
178
179
180
181
182
183
184
185
186
187
188
189
190
191
192
193
194
195
196
197
198
199
200
201
202
203
204
205
206
207
208
209
210
211
212
213
214
215
216
217
218
219
/****************************************************************************
**
** Copyright (C) 2015 Klaralvdalens Datakonsult AB (KDAB).
** Contact: http://www.qt-project.org/legal
**
** This file is part of the Qt3D module of the Qt Toolkit.
**
** $QT_BEGIN_LICENSE:LGPL3$
** Commercial License Usage
** Licensees holding valid commercial Qt licenses may use this file in
** accordance with the commercial license agreement provided with the
** Software or, alternatively, in accordance with the terms contained in
** a written agreement between you and The Qt Company. For licensing terms
** and conditions see http://www.qt.io/terms-conditions. For further
** information use the contact form at http://www.qt.io/contact-us.
**
** GNU Lesser General Public License Usage
** Alternatively, this file may be used under the terms of the GNU Lesser
** General Public License version 3 as published by the Free Software
** Foundation and appearing in the file LICENSE.LGPLv3 included in the
** packaging of this file. Please review the following information to
** ensure the GNU Lesser General Public License version 3 requirements
** will be met: https://www.gnu.org/licenses/lgpl.html.
**
** GNU General Public License Usage
** Alternatively, this file may be used under the terms of the GNU
** General Public License version 2.0 or later as published by the Free
** Software Foundation and appearing in the file LICENSE.GPL included in
** the packaging of this file. Please review the following information to
** ensure the GNU General Public License version 2.0 requirements will be
** met: http://www.gnu.org/licenses/gpl-2.0.html.
**
** $QT_END_LICENSE$
**
****************************************************************************/

import Qt3D.Core 2.0
import Qt3D.Render 2.0
import Qt3D.Input 2.0

import QtQuick 2.0 as QQ2
import QtQuick.Window 2.2 as W
import QtQuick.Scene3D 2.0

W.Window
{
    id: _view
    visible: true
    width: 1024
    height: 768

    Scene3D {
//        anchors.fill: parent
        id: sceneItem
        x: parent.width / 2 - width / 2
        y: parent.height / 2 - height / 2
        width: parent.width / 2
        height: parent.height / 2
        focus: true
        aspects: "input"

        Entity {
            id: sceneRoot

            Camera {
                id: camera
                projectionType: CameraLens.PerspectiveProjection
                fieldOfView: 45
                aspectRatio: _view.width * 0.5 / _view.height
                nearPlane : 0.1
                farPlane : 1000.0
                position: Qt.vector3d( 0.0, 0.0, -40.0 )
                upVector: Qt.vector3d( 0.0, 1.0, 0.0 )
                viewCenter: Qt.vector3d( 0.0, 0.0, 0.0 )
            }

            Camera {
                id: camera2
                projectionType: CameraLens.PerspectiveProjection
                fieldOfView: 45
                aspectRatio: _view.width * 0.5 / _view.height
                nearPlane : 0.1
                farPlane : 1000.0
                position: Qt.vector3d( 40.0, 5.0, -20.0 )
                upVector: Qt.vector3d( 0.0, 1.0, 0.0 )
                viewCenter: Qt.vector3d( 0.0, 0.0, 0.0 )
            }

            FirstPersonCameraController {
                camera: camera
            }

            // Draw 2 viewports
            // one with the content, the other with content + debug volumes
            components: FrameGraph {
                Viewport {
                    ClearBuffer {
                        buffers : ClearBuffer.ColorDepthBuffer
                        NoDraw {}
                    }
                    Viewport {
                        rect: Qt.rect(0.0, 0.0, 0.5, 1.0)
                        CameraSelector {
                            camera: camera
                            LayerFilter { layers: "content"}
                        }
                    }
                    Viewport {
                        rect: Qt.rect(0.5, 0.0, 0.5, 1.0)
                        CameraSelector {
                            camera: camera2
                            LayerFilter {
                                // To show Debug volumes
                                layers: ["content", "debug"]
                            }
                        }
                    }
                }
            }

            CuboidMesh { id: cubeMesh }

            PickableEntity {
                id: cube1
                property real scaleFactor: isPressed ? 3.0 : 1.0
                QQ2.Behavior on scaleFactor { QQ2.NumberAnimation { duration: 150; easing.type: QQ2.Easing.InQuad } }

                mesh: cubeMesh
                scale: cube1.scaleFactor
                x: -8

                ambientColor: "green"
                diffuseColor: "green"

                hoverEnabled: true
                onPressed: cube1.diffuseColor = "orange"
                onReleased:  cube1.diffuseColor = "green"
                onEntered: cube1.ambientColor = "blue"
                onExited: cube1.ambientColor = "green"
                onClicked: console.log("Clicked cube 1")
            }

            PickableEntity {
                id: cube2
                mesh: cubeMesh

                ambientColor: cube2.containsMouse ? "blue" : "red"
                scale: 1.5
                hoverEnabled: true

                onPressed: cube2.diffuseColor = "white"
                onReleased: cube2.diffuseColor = "red"

                property bool toggled: false
                onClicked: {
                    console.log("Clicked cube 2")
                    toggled = !toggled
                    sceneItem.width = _view.width * (toggled ? .7 : .5)
                    sceneItem.height = _view.height * (toggled ? .7 : .5)
                    console.log(sceneItem.width, sceneItem.height)
                }
            }
            PickableEntity {
                id: cube3
                mesh: cubeMesh

                diffuseColor: "yellow"

                property bool toggled: false
                property real scaleFactor: toggled ? 5.0 : 0.5
                QQ2.Behavior on scaleFactor { QQ2.NumberAnimation { duration: 200; easing.type: QQ2.Easing.InQuad } }

                scale: cube3.scaleFactor
                x: 8

                onPressed: cube3.toggled = !cube3.toggled
                onEntered: cube3.ambientColor = "black"
                onExited: cube3.ambientColor = "white"
                onClicked: console.log("Clicked cube 3")
            }

            Entity {
                readonly property ObjectPicker objectPicker: ObjectPicker {
                    hoverEnabled: true
                    onPressed: cube4.toggled = !cube4.toggled
                    onClicked: console.log("Clicked cube 4's parent Entity")
                    onEntered: cube4.material.diffuse = "white"
                    onExited: cube4.material.diffuse = "blue"
                }

                readonly property BoundingVolumeDebug debugVolume: BoundingVolumeDebug {
                    recursive: true
                }

                components: [objectPicker, debugVolume]

                Entity {
                    id: cube4
                    property bool toggled: false
                    property real scaleFactor: toggled ? 2.0 : 1.0
                    QQ2.Behavior on scaleFactor { QQ2.NumberAnimation { duration: 200; easing.type: QQ2.Easing.InQuad } }

                    readonly property Transform transform: Transform {
                        scale: cube4.scaleFactor
                        translation: Qt.vector3d(3, 4, 0)
                    }
                    readonly property Layer layer: Layer { names: "content" }
                    readonly property BoundingVolumeDebug debugVolume: BoundingVolumeDebug {}
                    readonly property PhongMaterial material: PhongMaterial { diffuse: "red" }

                    components: [cubeMesh, transform, material, debugVolume, layer]
                }
            }
        }

        QQ2.Behavior on width { QQ2.NumberAnimation { duration: 200 } }
        QQ2.Behavior on height { QQ2.NumberAnimation { duration: 200 } }
    }
}