blob: 0ac19123b220034deb33b7a06b9d3dcc9b73cc59 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
|
!CONFIG(pkg_pri_included) {
CONFIG+=pkg_pri_included
# Config for making example and demo apps packageable
# Note that the paths here all assumed the including .pro file
# is exactly 3 levels of directory tree below the root
# Include this file after qt3d_pkg_dep.pri or qt3dquick_pkg_dep.pri
qtc_harmattan {
CONFIG += maemo
CONFIG += package
# The Qt SDK / Qt Creator harmattan integration needs some special treatment
QT3D_INSTALL_BINS = /bin
QT3D_INSTALL_LIBS = /usr/lib
QT3D_INSTALL_PLUGINS = /usr/lib/qt4/plugins
QT3D_INSTALL_IMPORTS = /usr/lib/qt4/imports
QT3D_INSTALL_DATA = /usr/share/qt4
} else {
QT3D_INSTALL_BINS = $$[QT_INSTALL_BINS]
QT3D_INSTALL_LIBS = $$[QT_INSTALL_LIBS]
QT3D_INSTALL_PLUGINS = $$[QT_INSTALL_PLUGINS]
QT3D_INSTALL_IMPORTS = $$[QT_INSTALL_IMPORTS]
QT3D_INSTALL_DATA = $$[QT_INSTALL_DATA]
}
contains(TEMPLATE, app) {
package {
maemo {
applnk.files = $${TARGET}.desktop
applnk.path = /usr/share/applications
# icons.files is set by qt3dquick_pkg_dep.pri or qt3d_pkg_dep.pri
icons.path = /usr/share/themes/base/meegotouch/icons
INSTALLS += icons applnk
}
target.path += $$QT3D_INSTALL_BINS
INSTALLS += target
} else {
DESTDIR = ../../../bin
}
symbian {
vendorinfo = \
"%{\"NOKIA\"}" \
":\"NOKIA\""
my_deployment.pkg_prerules = vendorinfo
DEPLOYMENT += my_deployment
ICON = ../qt3d.svg
}
}
}
|