blob: fda9de6a367bd4f704565d45a600f65b0f426329 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
TEMPLATE = subdirs
SUBDIRS += src
!gcov: SUBDIRS += util examples demos
SUBDIRS += tests
CONFIG += ordered
include(doc/doc.pri)
# We need opengl, minimum es2 or desktop
!contains(QT_CONFIG, opengl) {
error(QtQuick3D requires OpenGL!)
}
contains(QT_CONFIG, opengles1) {
error(QtQuick3D does not support OpenGL ES 1!)
}
# We need qt declarative
!contains(QT_CONFIG, declarative) {
error(QtQuick3D requires Qt Declarative!)
}
# Install qt3d.prf into the Qt mkspecs so that "CONFIG += qt3d"
# can be used in applications to build against Qt3D.
symbian|win32 {
Qt3DFile=$$PWD\\features\\Qt3D.prf
Qt3DFile=$$replace(Qt3DFile,/,\\)
featuresDir=$$[QT_INSTALL_DATA]\\mkspecs\\features
featuresDir=$$replace(featuresDir,/,\\)
system(copy "$$Qt3DFile $$featuresDir")
Qt3DQuickFile=$$PWD\\features\\Qt3Dquick.prf
Qt3DQuickFile=$$replace(Qt3DQuickFile,/,\\)
system(copy "$$Qt3DQuickFile $$featuresDir")
} else {
Qt3DFile=$$PWD/features/Qt3D.prf
featuresDir=$$[QT_INSTALL_DATA]/mkspecs/features
system(cp "$$Qt3DFile $$featuresDir")
Qt3DQuickFile=$$PWD/features/Qt3Dquick.prf
system(cp "$$Qt3DQuickFile $$featuresDir")
}
symbian {
# symbian needs to be at the end, because Qt3D.pro does an ordered build,
# and symbian depends on all the others.
SUBDIRS += symbianinstall
symbianinstall.subdir = devices/symbian
symbianinstall.target = sub-symbianinstall
symbianinstall.depends = $$SUBDIRS
symbianinstall.depends -= symbianinstall
}
|
