blob: 3a71d9114caf29dfcd94ff257dcc7ba7976ca712 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
|
TEMPLATE = lib
TARGET = qshapesqmlplugin
CONFIG += qt plugin
include(../../../qt3d_pkg_dep.pri)
include(../../../qt3dquick_pkg_dep.pri)
# See the README in the root dir re this code
package {
target.path += $$QT3D_INSTALL_IMPORTS/Qt3D/Shapes
INSTALLS += target
QT += declarative
} else {
CONFIG += qt3dquick qt3d
DESTDIR = $$QT3D_INSTALL_IMPORTS/Qt3D/Shapes
}
win32 {
CONFIG(debug, debug|release) {
TARGET = $$member(TARGET, 0)d
}
}
SOURCES += \
sphere.cpp \
shapes.cpp \
cylinder.cpp \
capsule.cpp \
line.cpp \
point.cpp
HEADERS += \
sphere.h \
cylinder.h \
capsule.h \
line.h \
point.h
qdeclarativesources.files += \
qmldir \
library.xml \
plugins.qmltypes \
Cube.qml \
cube.obj \
Quad.qml \
quad.obj \
Teapot.qml \
teapot.bez
# see the file README.library_xml for more on library.xml
!package {
qdeclarative_in_place.input = qdeclarativesources.files
qdeclarative_in_place.output = $$QT3D_INSTALL_IMPORTS/Qt3D/Shapes/${QMAKE_FILE_IN_BASE}${QMAKE_FILE_EXT}
qdeclarative_in_place.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
qdeclarative_in_place.CONFIG += no_link_no_clean
qdeclarative_in_place.variable_out = PRE_TARGETDEPS
QMAKE_EXTRA_COMPILERS += qdeclarative_in_place
} else {
qdeclarativesources.path += $$QT3D_INSTALL_IMPORTS/Qt3D/Shapes
INSTALLS += qdeclarativesources
}
OTHER_FILES += \
README.plugins_types \
README.library_xml
|