blob: 6a42bb6034ed534506713df21bd63b440d036ad3 (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
|
TEMPLATE = lib
TARGET = qthreedqmlplugin
CONFIG += qt plugin
include(../../../qt3d_pkg_dep.pri)
include(../../../qt3dquick_pkg_dep.pri)
# See the README in the root dir re this code
package {
target.path += $$QT3D_INSTALL_IMPORTS/Qt3D
INSTALLS += target
} else {
CONFIG += qt3dquick qt3d
DESTDIR = $$QT3D_INSTALL_IMPORTS/Qt3D
}
win32 {
CONFIG(debug, debug|release) {
TARGET = $$member(TARGET, 0)d
}
}
symbian {
CONFIG += epocallowdlldata
MMP_RULES += EXPORTUNFROZEN
LIBS += -lQt3D -lQt3DQuick
TARGET.CAPABILITY = All -Tcb
TARGET.UID3 = 0x20031E9B
}
SOURCES += \
threed.cpp \
qt3dnamespace.cpp \
scale3d.cpp \
viewport.cpp \
qgraphicslookattransform.cpp \
shaderprogram.cpp
HEADERS += \
qt3dnamespace.h \
scale3d.h \
viewport.h \
qgraphicslookattransform.h \
shaderprogram.h \
shaderprogram_p.h
# See the file README.library_xml for more on this
qdeclarativesources.files += \
qmldir \
library.xml \
plugins.qmltypes
!package {
qdeclarative_in_place.input = qdeclarativesources.files
qdeclarative_in_place.output = $$QT3D_INSTALL_IMPORTS/Qt3D/${QMAKE_FILE_IN_BASE}${QMAKE_FILE_EXT}
qdeclarative_in_place.commands = $$QMAKE_COPY ${QMAKE_FILE_IN} ${QMAKE_FILE_OUT}
qdeclarative_in_place.CONFIG += no_link_no_clean
qdeclarative_in_place.variable_out = PRE_TARGETDEPS
QMAKE_EXTRA_COMPILERS += qdeclarative_in_place
} else {
qdeclarativesources.path += $$QT3D_INSTALL_IMPORTS/Qt3D
INSTALLS += qdeclarativesources
}
OTHER_FILES += \
README.plugins_types \
README.library_xml
|