blob: 2d9c2d3bda1b41a272eed36bab956fae5dbdd0bf (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
|
TARGET = Qt3DRenderer
QT += core-private gui-private 3dcore 3dcore-private openglextensions
DEFINES += QT3DRENDERER_LIBRARY
MODULE = 3drenderer
MODULE_PLUGIN_TYPES = \
sceneparsers
load(qt_module)
QMAKE_DOCS = $$PWD/doc/qt3drender.qdocconf
include (backend/render-backend.pri)
include (frontend/render-frontend.pri)
include (io/render-io.pri)
include (defaults/defaults.pri)
RESOURCES += $$PWD/render.qrc
OTHER_FILES += \
$$PWD/shaders/* \
$$PWD/shaders/gl3/* \
$$PWD/shaders/es2/*
gcov {
CONFIG += static
QMAKE_CXXFLAGS += -fprofile-arcs -ftest-coverage
QMAKE_LFLAGS += -fprofile-arcs -ftest-coverage
}
HEADERS += \
qt3drenderer_global.h \
qt3drenderer_global_p.h \
renderlogging_p.h
!contains(QT_CONFIG, egl):DEFINES += QT_NO_EGL
# otherwise mingw headers do not declare common functions like ::strcasecmp
win32-g++*:QMAKE_CXXFLAGS_CXX11 = -std=gnu++0x
SOURCES += \
renderlogging.cpp
|
