blob: 65fd7231fa077ccd686e9cf118a7cc463b6178ff (
plain)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
|
#version 150 core
in vec3 vertexPosition;
in vec3 vertexNormal;
in vec2 vertexTexCoord;
in vec4 vertexTangent;
out vec3 lightDir;
out vec3 viewDir;
out vec2 texCoord;
uniform mat4 modelView;
uniform mat3 modelViewNormal;
uniform mat4 projectionMatrix;
uniform mat4 mvp;
uniform float texCoordScale;
// TODO: Replace with a uniform block
uniform vec4 lightPosition;
uniform vec3 lightIntensity;
void main()
{
// Pass through texture coordinates
texCoord = vertexTexCoord * texCoordScale;
// Transform position, normal, and tangent to eye coords
vec3 normal = normalize( modelViewNormal * vertexNormal );
vec3 tangent = normalize( modelViewNormal * vertexTangent.xyz );
vec3 position = vec3( modelView * vec4( vertexPosition, 1.0 ) );
// Calculate binormal vector
vec3 binormal = normalize( cross( normal, tangent ) );
// Construct matrix to transform from eye coords to tangent space
mat3 tangentMatrix = mat3 (
tangent.x, binormal.x, normal.x,
tangent.y, binormal.y, normal.y,
tangent.z, binormal.z, normal.z );
// Transform light direction and view direction to tangent space
vec3 s = vec3( lightPosition ) - position;
lightDir = normalize( tangentMatrix * s );
vec3 v = -position;
viewDir = normalize( tangentMatrix * v );
// Calculate vertex position in clip coordinates
gl_Position = mvp * vec4( vertexPosition, 1.0 );
}
|