1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
73
74
75
|
/*************************************************************************
*
* Copyright (c) 2016, Klaralvdalens Datakonsult AB (KDAB)
* All rights reserved.
*
* See the LICENSE.txt file shipped along with this file for the license.
*
*************************************************************************/
import Qt3D.Core 2.0
import Qt3D.Render 2.0
import Qt3D.Input 2.0
import Qt3D.Animation 2.9
import Qt3D.Extras 2.0
DefaultSceneEntity {
id: scene
Entity {
id: cube
components: [
Transform {
id: cubeTransform
translation: Qt.vector3d(5, 0, 0)
onTranslationChanged: console.log("t = " + translation)
},
CuboidMesh {
},
PhongMaterial {
id: cubeMaterial
ambient: Qt.rgba(0.02, 0.02, 0.02, 1.0)
diffuse: "red"
shininess: 50
},
ObjectPicker {
onClicked: blendedAnimator.running = true
},
BlendedClipAnimator {
id: blendedAnimator
loops: 2
onRunningChanged: console.log("running = " + running)
blendTree: LerpClipBlend {
blendFactor: 0.2
startClip: ClipBlendValue {
clip: AnimationClip { source: "sliding-cube.json" }
}
endClip: ClipBlendValue {
clip: AnimationClip { source: "sliding-pulsing-cube.json" }
}
}
channelMapper: ChannelMapper {
mappings: [
ChannelMapping { channelName: "Location"; target: cubeTransform; property: "translation" },
ChannelMapping { channelName: "Scale"; target: cubeTransform; property: "scale3D" }
]
}
}
]
}
camera: Camera {
position: Qt.vector3d(10, 3, 15)
viewCenter: Qt.vector3d(2.5, 1, 0)
}
OrbitCameraController {
camera: scene.camera
linearSpeed: 8
lookSpeed: 180
}
}
|