summaryrefslogtreecommitdiffstats
path: root/gnuwin32/bin/data/xslt
diff options
context:
space:
mode:
Diffstat (limited to 'gnuwin32/bin/data/xslt')
-rw-r--r--gnuwin32/bin/data/xslt/bison.xsl105
-rw-r--r--gnuwin32/bin/data/xslt/xml2dot.xsl397
-rw-r--r--gnuwin32/bin/data/xslt/xml2text.xsl569
-rw-r--r--gnuwin32/bin/data/xslt/xml2xhtml.xsl745
4 files changed, 1816 insertions, 0 deletions
diff --git a/gnuwin32/bin/data/xslt/bison.xsl b/gnuwin32/bin/data/xslt/bison.xsl
new file mode 100644
index 00000000..10e3305b
--- /dev/null
+++ b/gnuwin32/bin/data/xslt/bison.xsl
@@ -0,0 +1,105 @@
+<?xml version="1.0" encoding="UTF-8"?>
+
+<!--
+ bison.xsl - common templates for Bison XSLT.
+
+ Copyright (C) 2007-2013 Free Software Foundation, Inc.
+
+ This file is part of Bison, the GNU Compiler Compiler.
+
+ This program is free software: you can redistribute it and/or modify
+ it under the terms of the GNU General Public License as published by
+ the Free Software Foundation, either version 3 of the License, or
+ (at your option) any later version.
+
+ This program is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ GNU General Public License for more details.
+
+ You should have received a copy of the GNU General Public License
+ along with this program. If not, see <http://www.gnu.org/licenses/>.
+ -->
+
+<xsl:stylesheet version="1.0"
+ xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:bison="http://www.gnu.org/software/bison/">
+
+<xsl:key
+ name="bison:symbolByName"
+ match="/bison-xml-report/grammar/nonterminals/nonterminal"
+ use="@name"
+/>
+<xsl:key
+ name="bison:symbolByName"
+ match="/bison-xml-report/grammar/terminals/terminal"
+ use="@name"
+/>
+<xsl:key
+ name="bison:ruleByNumber"
+ match="/bison-xml-report/grammar/rules/rule"
+ use="@number"
+/>
+<xsl:key
+ name="bison:ruleByLhs"
+ match="/bison-xml-report/grammar/rules/rule[
+ @usefulness != 'useless-in-grammar']"
+ use="lhs"
+/>
+<xsl:key
+ name="bison:ruleByRhs"
+ match="/bison-xml-report/grammar/rules/rule[
+ @usefulness != 'useless-in-grammar']"
+ use="rhs/symbol"
+/>
+
+<!-- For the specified state, output: #sr-conflicts,#rr-conflicts -->
+<xsl:template match="state" mode="bison:count-conflicts">
+ <xsl:variable name="transitions" select="actions/transitions"/>
+ <xsl:variable name="reductions" select="actions/reductions"/>
+ <xsl:variable
+ name="terminals"
+ select="
+ $transitions/transition[@type='shift']/@symbol
+ | $reductions/reduction/@symbol
+ "
+ />
+ <xsl:variable name="conflict-data">
+ <xsl:for-each select="$terminals">
+ <xsl:variable name="name" select="."/>
+ <xsl:if test="generate-id($terminals[. = $name][1]) = generate-id(.)">
+ <xsl:variable
+ name="shift-count"
+ select="count($transitions/transition[@symbol=$name])"
+ />
+ <xsl:variable
+ name="reduce-count"
+ select="count($reductions/reduction[@symbol=$name])"
+ />
+ <xsl:if test="$shift-count > 0 and $reduce-count > 0">
+ <xsl:text>s</xsl:text>
+ </xsl:if>
+ <xsl:if test="$reduce-count > 1">
+ <xsl:text>r</xsl:text>
+ </xsl:if>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:variable>
+ <xsl:value-of select="string-length(translate($conflict-data, 'r', ''))"/>
+ <xsl:text>,</xsl:text>
+ <xsl:value-of select="string-length(translate($conflict-data, 's', ''))"/>
+</xsl:template>
+
+<xsl:template name="space">
+ <xsl:param name="repeat">0</xsl:param>
+ <xsl:param name="fill" select="' '"/>
+ <xsl:if test="number($repeat) &gt;= 1">
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$repeat - 1"/>
+ <xsl:with-param name="fill" select="$fill"/>
+ </xsl:call-template>
+ <xsl:value-of select="$fill"/>
+ </xsl:if>
+</xsl:template>
+
+</xsl:stylesheet>
diff --git a/gnuwin32/bin/data/xslt/xml2dot.xsl b/gnuwin32/bin/data/xslt/xml2dot.xsl
new file mode 100644
index 00000000..93bec599
--- /dev/null
+++ b/gnuwin32/bin/data/xslt/xml2dot.xsl
@@ -0,0 +1,397 @@
+<?xml version="1.0" encoding="UTF-8"?>
+
+<!--
+ xml2dot.xsl - transform Bison XML Report into DOT.
+
+ Copyright (C) 2007-2013 Free Software Foundation, Inc.
+
+ This file is part of Bison, the GNU Compiler Compiler.
+
+ This program is free software: you can redistribute it and/or modify
+ it under the terms of the GNU General Public License as published by
+ the Free Software Foundation, either version 3 of the License, or
+ (at your option) any later version.
+
+ This program is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ GNU General Public License for more details.
+
+ You should have received a copy of the GNU General Public License
+ along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+ Written by Wojciech Polak <polak@gnu.org>.
+ -->
+
+<xsl:stylesheet version="1.0"
+ xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:bison="http://www.gnu.org/software/bison/">
+
+<xsl:import href="bison.xsl"/>
+<xsl:output method="text" encoding="UTF-8" indent="no"/>
+
+<xsl:template match="/">
+ <xsl:apply-templates select="bison-xml-report"/>
+</xsl:template>
+
+<xsl:template match="bison-xml-report">
+ <xsl:text>// Generated by GNU Bison </xsl:text>
+ <xsl:value-of select="@version"/>
+ <xsl:text>.&#10;</xsl:text>
+ <xsl:text>// Report bugs to &lt;</xsl:text>
+ <xsl:value-of select="@bug-report"/>
+ <xsl:text>&gt;.&#10;</xsl:text>
+ <xsl:text>// Home page: &lt;</xsl:text>
+ <xsl:value-of select="@url"/>
+ <xsl:text>&gt;.&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="automaton">
+ <xsl:with-param name="filename" select="filename"/>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="automaton">
+ <xsl:param name="filename"/>
+ <xsl:text>digraph "</xsl:text>
+ <xsl:call-template name="escape">
+ <xsl:with-param name="subject" select="$filename"/>
+ </xsl:call-template>
+ <xsl:text>"&#10;{
+ node [fontname = courier, shape = box, colorscheme = paired6]
+ edge [fontname = courier]
+
+</xsl:text>
+ <xsl:apply-templates select="state"/>
+ <xsl:text>}&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="automaton/state">
+ <xsl:call-template name="output-node">
+ <xsl:with-param name="number" select="@number"/>
+ <xsl:with-param name="label">
+ <xsl:apply-templates select="itemset/item"/>
+ </xsl:with-param>
+ </xsl:call-template>
+ <xsl:apply-templates select="actions/transitions"/>
+ <xsl:apply-templates select="actions/reductions">
+ <xsl:with-param name="staten">
+ <xsl:value-of select="@number"/>
+ </xsl:with-param>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="actions/reductions">
+ <xsl:param name="staten"/>
+ <xsl:for-each select='reduction'>
+ <!-- These variables are needed because the current context can't be
+ refered to directly in XPath expressions. -->
+ <xsl:variable name="rul">
+ <xsl:value-of select="@rule"/>
+ </xsl:variable>
+ <xsl:variable name="ena">
+ <xsl:value-of select="@enabled"/>
+ </xsl:variable>
+ <!-- The foreach's body is protected by this, so that we are actually
+ going to iterate once per reduction rule, and not per lookahead. -->
+ <xsl:if test='not(preceding-sibling::*[@rule=$rul and @enabled=$ena])'>
+ <xsl:variable name="rule">
+ <xsl:choose>
+ <!-- The acceptation state is refered to as 'accept' in the XML, but
+ just as '0' in the DOT. -->
+ <xsl:when test="@rule='accept'">
+ <xsl:text>0</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="@rule"/>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:variable>
+
+ <!-- The edge's beginning -->
+ <xsl:call-template name="reduction-edge-start">
+ <xsl:with-param name="state" select="$staten"/>
+ <xsl:with-param name="rule" select="$rule"/>
+ <xsl:with-param name="enabled" select="@enabled"/>
+ </xsl:call-template>
+
+ <!-- The edge's tokens -->
+ <!-- Don't show labels for the default action. In other cases, there will
+ always be at least one token, so 'label="[]"' will not occur. -->
+ <xsl:if test='$rule!=0 and not(../reduction[@enabled=$ena and @rule=$rule and @symbol="$default"])'>
+ <xsl:text>label="[</xsl:text>
+ <xsl:for-each select='../reduction[@enabled=$ena and @rule=$rule]'>
+ <xsl:call-template name="escape">
+ <xsl:with-param name="subject" select="@symbol"/>
+ </xsl:call-template>
+ <xsl:if test="position() != last ()">
+ <xsl:text>, </xsl:text>
+ </xsl:if>
+ </xsl:for-each>
+ <xsl:text>]", </xsl:text>
+ </xsl:if>
+
+ <!-- The edge's end -->
+ <xsl:text>style=solid]&#10;</xsl:text>
+
+ <!-- The diamond representing the reduction -->
+ <xsl:call-template name="reduction-node">
+ <xsl:with-param name="state" select="$staten"/>
+ <xsl:with-param name="rule" select="$rule"/>
+ <xsl:with-param name="color">
+ <xsl:choose>
+ <xsl:when test='@enabled="true"'>
+ <xsl:text>3</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>5</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:with-param>
+ </xsl:call-template>
+ </xsl:if>
+ </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="actions/transitions">
+ <xsl:apply-templates select="transition"/>
+</xsl:template>
+
+<xsl:template match="item">
+ <xsl:param name="prev-rule-number"
+ select="preceding-sibling::item[1]/@rule-number"/>
+ <xsl:apply-templates select="key('bison:ruleByNumber', @rule-number)">
+ <xsl:with-param name="point" select="@point"/>
+ <xsl:with-param name="num" select="@rule-number"/>
+ <xsl:with-param name="prev-lhs"
+ select="key('bison:ruleByNumber', $prev-rule-number)/lhs[text()]"
+ />
+ </xsl:apply-templates>
+ <xsl:apply-templates select="lookaheads"/>
+</xsl:template>
+
+<xsl:template match="rule">
+ <xsl:param name="point"/>
+ <xsl:param name="num"/>
+ <xsl:param name="prev-lhs"/>
+ <xsl:text>&#10;</xsl:text>
+ <xsl:choose>
+ <xsl:when test="$num &lt; 10">
+ <xsl:text> </xsl:text>
+ </xsl:when>
+ <xsl:when test="$num &lt; 100">
+ <xsl:text> </xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text></xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:value-of select="$num"/>
+ <xsl:text> </xsl:text>
+ <xsl:choose>
+ <xsl:when test="$prev-lhs = lhs[text()]">
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="'|'"/>
+ <xsl:with-param name="pad" select="number(string-length(lhs[text()])) + 1"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="lhs"/>
+ <xsl:text>:</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:if test="$point = 0">
+ <xsl:text> .</xsl:text>
+ </xsl:if>
+ <xsl:for-each select="rhs/symbol|rhs/empty">
+ <xsl:apply-templates select="."/>
+ <xsl:if test="$point = position()">
+ <xsl:text> .</xsl:text>
+ </xsl:if>
+ </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="symbol">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="."/>
+</xsl:template>
+
+<xsl:template match="empty"/>
+
+<xsl:template match="lookaheads">
+ <xsl:text> [</xsl:text>
+ <xsl:apply-templates select="symbol"/>
+ <xsl:text>]</xsl:text>
+</xsl:template>
+
+<xsl:template match="lookaheads/symbol">
+ <xsl:value-of select="."/>
+ <xsl:if test="position() != last()">
+ <xsl:text>, </xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template name="reduction-edge-start">
+ <xsl:param name="state"/>
+ <xsl:param name="rule"/>
+ <xsl:param name="enabled"/>
+
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="$state"/>
+ <xsl:text> -> "</xsl:text>
+ <xsl:value-of select="$state"/>
+ <xsl:text>R</xsl:text>
+ <xsl:value-of select="$rule"/>
+ <xsl:if test='$enabled = "false"'>
+ <xsl:text>d</xsl:text>
+ </xsl:if>
+ <xsl:text>" [</xsl:text>
+</xsl:template>
+
+<xsl:template name="reduction-node">
+ <xsl:param name="state"/>
+ <xsl:param name="rule"/>
+ <xsl:param name="color"/>
+
+ <xsl:text> "</xsl:text>
+ <xsl:value-of select="$state"/>
+ <xsl:text>R</xsl:text>
+ <xsl:value-of select="$rule"/>
+ <xsl:if test="$color = 5">
+ <xsl:text>d</xsl:text>
+ </xsl:if>
+ <xsl:text>" [label="</xsl:text>
+ <xsl:choose>
+ <xsl:when test="$rule = 0">
+ <xsl:text>Acc", fillcolor=1</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>R</xsl:text>
+ <xsl:value-of select="$rule"/>
+ <xsl:text>", fillcolor=</xsl:text>
+ <xsl:value-of select="$color"/>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:text>, shape=diamond, style=filled]&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="transition">
+ <xsl:call-template name="output-edge">
+ <xsl:with-param name="src" select="../../../@number"/>
+ <xsl:with-param name="dst" select="@state"/>
+ <xsl:with-param name="style">
+ <xsl:choose>
+ <xsl:when test="@symbol = 'error'">
+ <xsl:text>dotted</xsl:text>
+ </xsl:when>
+ <xsl:when test="@type = 'shift'">
+ <xsl:text>solid</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>dashed</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:with-param>
+ <xsl:with-param name="label">
+ <xsl:if test="not(@symbol = 'error')">
+ <xsl:value-of select="@symbol"/>
+ </xsl:if>
+ </xsl:with-param>
+ </xsl:call-template>
+</xsl:template>
+
+<xsl:template name="output-node">
+ <xsl:param name="number"/>
+ <xsl:param name="label"/>
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="$number"/>
+ <xsl:text> [label="</xsl:text>
+ <xsl:text>State </xsl:text>
+ <xsl:value-of select="$number"/>
+ <xsl:text>\n</xsl:text>
+ <xsl:call-template name="escape">
+ <xsl:with-param name="subject" select="$label"/>
+ </xsl:call-template>
+ <xsl:text>\l"]&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template name="output-edge">
+ <xsl:param name="src"/>
+ <xsl:param name="dst"/>
+ <xsl:param name="style"/>
+ <xsl:param name="label"/>
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="$src"/>
+ <xsl:text> -> </xsl:text>
+ <xsl:value-of select="$dst"/>
+ <xsl:text> [style=</xsl:text>
+ <xsl:value-of select="$style"/>
+ <xsl:if test="$label and $label != ''">
+ <xsl:text> label="</xsl:text>
+ <xsl:call-template name="escape">
+ <xsl:with-param name="subject" select="$label"/>
+ </xsl:call-template>
+ <xsl:text>"</xsl:text>
+ </xsl:if>
+ <xsl:text>]&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template name="escape">
+ <xsl:param name="subject"/> <!-- required -->
+ <xsl:call-template name="string-replace">
+ <xsl:with-param name="subject">
+ <xsl:call-template name="string-replace">
+ <xsl:with-param name="subject">
+ <xsl:call-template name="string-replace">
+ <xsl:with-param name="subject" select="$subject"/>
+ <xsl:with-param name="search" select="'\'"/>
+ <xsl:with-param name="replace" select="'\\'"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ <xsl:with-param name="search" select="'&quot;'"/>
+ <xsl:with-param name="replace" select="'\&quot;'"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ <xsl:with-param name="search" select="'&#10;'"/>
+ <xsl:with-param name="replace" select="'\l'"/>
+ </xsl:call-template>
+</xsl:template>
+
+<xsl:template name="string-replace">
+ <xsl:param name="subject"/>
+ <xsl:param name="search"/>
+ <xsl:param name="replace"/>
+ <xsl:choose>
+ <xsl:when test="contains($subject, $search)">
+ <xsl:variable name="before" select="substring-before($subject, $search)"/>
+ <xsl:variable name="after" select="substring-after($subject, $search)"/>
+ <xsl:value-of select="$before"/>
+ <xsl:value-of select="$replace"/>
+ <xsl:call-template name="string-replace">
+ <xsl:with-param name="subject" select="$after"/>
+ <xsl:with-param name="search" select="$search"/>
+ <xsl:with-param name="replace" select="$replace"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="$subject"/>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="lpad">
+ <xsl:param name="str" select="''"/>
+ <xsl:param name="pad" select="0"/>
+ <xsl:variable name="diff" select="$pad - string-length($str)" />
+ <xsl:choose>
+ <xsl:when test="$diff &lt; 0">
+ <xsl:value-of select="$str"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$diff"/>
+ </xsl:call-template>
+ <xsl:value-of select="$str"/>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+</xsl:stylesheet>
diff --git a/gnuwin32/bin/data/xslt/xml2text.xsl b/gnuwin32/bin/data/xslt/xml2text.xsl
new file mode 100644
index 00000000..2626f566
--- /dev/null
+++ b/gnuwin32/bin/data/xslt/xml2text.xsl
@@ -0,0 +1,569 @@
+<?xml version="1.0" encoding="UTF-8"?>
+
+<!--
+ xml2text.xsl - transform Bison XML Report into plain text.
+
+ Copyright (C) 2007-2013 Free Software Foundation, Inc.
+
+ This file is part of Bison, the GNU Compiler Compiler.
+
+ This program is free software: you can redistribute it and/or modify
+ it under the terms of the GNU General Public License as published by
+ the Free Software Foundation, either version 3 of the License, or
+ (at your option) any later version.
+
+ This program is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ GNU General Public License for more details.
+
+ You should have received a copy of the GNU General Public License
+ along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+ Written by Wojciech Polak <polak@gnu.org>.
+ -->
+
+<xsl:stylesheet version="1.0"
+ xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns:bison="http://www.gnu.org/software/bison/">
+
+<xsl:import href="bison.xsl"/>
+<xsl:output method="text" encoding="UTF-8" indent="no"/>
+
+<xsl:template match="/">
+ <xsl:apply-templates select="bison-xml-report"/>
+</xsl:template>
+
+<xsl:template match="bison-xml-report">
+ <xsl:apply-templates select="grammar" mode="reductions"/>
+ <xsl:apply-templates select="grammar" mode="useless-in-parser"/>
+ <xsl:apply-templates select="automaton" mode="conflicts"/>
+ <xsl:apply-templates select="grammar"/>
+ <xsl:apply-templates select="automaton"/>
+</xsl:template>
+
+<xsl:template match="grammar" mode="reductions">
+ <xsl:apply-templates select="nonterminals" mode="useless-in-grammar"/>
+ <xsl:apply-templates select="terminals" mode="unused-in-grammar"/>
+ <xsl:apply-templates select="rules" mode="useless-in-grammar"/>
+</xsl:template>
+
+<xsl:template match="nonterminals" mode="useless-in-grammar">
+ <xsl:if test="nonterminal[@usefulness='useless-in-grammar']">
+ <xsl:text>Nonterminals useless in grammar&#10;&#10;</xsl:text>
+ <xsl:for-each select="nonterminal[@usefulness='useless-in-grammar']">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="@name"/>
+ <xsl:text>&#10;</xsl:text>
+ </xsl:for-each>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="terminals" mode="unused-in-grammar">
+ <xsl:if test="terminal[@usefulness='unused-in-grammar']">
+ <xsl:text>Terminals unused in grammar&#10;&#10;</xsl:text>
+ <xsl:for-each select="terminal[@usefulness='unused-in-grammar']">
+ <xsl:sort select="@symbol-number" data-type="number"/>
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="@name"/>
+ <xsl:text>&#10;</xsl:text>
+ </xsl:for-each>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="rules" mode="useless-in-grammar">
+ <xsl:variable name="set" select="rule[@usefulness='useless-in-grammar']"/>
+ <xsl:if test="$set">
+ <xsl:text>Rules useless in grammar&#10;</xsl:text>
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param name="rule-set" select="$set"/>
+ </xsl:call-template>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="grammar" mode="useless-in-parser">
+ <xsl:variable
+ name="set" select="rules/rule[@usefulness='useless-in-parser']"
+ />
+ <xsl:if test="$set">
+ <xsl:text>Rules useless in parser due to conflicts&#10;</xsl:text>
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param name="rule-set" select="$set"/>
+ </xsl:call-template>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="grammar">
+ <xsl:text>Grammar&#10;</xsl:text>
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param
+ name="rule-set" select="rules/rule[@usefulness!='useless-in-grammar']"
+ />
+ </xsl:call-template>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="terminals"/>
+ <xsl:apply-templates select="nonterminals"/>
+</xsl:template>
+
+<xsl:template name="style-rule-set">
+ <xsl:param name="rule-set"/>
+ <xsl:for-each select="$rule-set">
+ <xsl:apply-templates select=".">
+ <xsl:with-param name="pad" select="'3'"/>
+ <xsl:with-param name="prev-lhs">
+ <xsl:if test="position()>1">
+ <xsl:variable name="position" select="position()"/>
+ <xsl:value-of select="$rule-set[$position - 1]/lhs"/>
+ </xsl:if>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="grammar/terminals">
+ <xsl:text>Terminals, with rules where they appear&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="terminal"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="grammar/nonterminals">
+ <xsl:text>Nonterminals, with rules where they appear&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="nonterminal[@usefulness!='useless-in-grammar']"/>
+</xsl:template>
+
+<xsl:template match="terminal">
+ <xsl:value-of select="@name"/>
+ <xsl:call-template name="line-wrap">
+ <xsl:with-param name="first-line-length">
+ <xsl:choose>
+ <xsl:when test="string-length(@name) &gt; 66">0</xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="66 - string-length(@name)" />
+ </xsl:otherwise>
+ </xsl:choose>
+ </xsl:with-param>
+ <xsl:with-param name="line-length" select="66" />
+ <xsl:with-param name="text">
+ <xsl:value-of select="concat(' (', @token-number, ')')"/>
+ <xsl:for-each select="key('bison:ruleByRhs', @name)">
+ <xsl:value-of select="concat(' ', @number)"/>
+ </xsl:for-each>
+ </xsl:with-param>
+ </xsl:call-template>
+</xsl:template>
+
+<xsl:template match="nonterminal">
+ <xsl:value-of select="@name"/>
+ <xsl:value-of select="concat(' (', @symbol-number, ')')"/>
+ <xsl:text>&#10;</xsl:text>
+ <xsl:variable name="output">
+ <xsl:call-template name="line-wrap">
+ <xsl:with-param name="line-length" select="66" />
+ <xsl:with-param name="text">
+ <xsl:text> </xsl:text>
+ <xsl:if test="key('bison:ruleByLhs', @name)">
+ <xsl:text>on@left:</xsl:text>
+ <xsl:for-each select="key('bison:ruleByLhs', @name)">
+ <xsl:value-of select="concat(' ', @number)"/>
+ </xsl:for-each>
+ </xsl:if>
+ <xsl:if test="key('bison:ruleByRhs', @name)">
+ <xsl:if test="key('bison:ruleByLhs', @name)">
+ <xsl:text>, </xsl:text>
+ </xsl:if>
+ <xsl:text>on@right:</xsl:text>
+ <xsl:for-each select="key('bison:ruleByRhs', @name)">
+ <xsl:value-of select="concat(' ', @number)"/>
+ </xsl:for-each>
+ </xsl:if>
+ </xsl:with-param>
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:value-of select="translate($output, '@', ' ')" />
+</xsl:template>
+
+<xsl:template match="automaton" mode="conflicts">
+ <xsl:variable name="conflict-report">
+ <xsl:apply-templates select="state" mode="conflicts"/>
+ </xsl:variable>
+ <xsl:if test="string-length($conflict-report) != 0">
+ <xsl:value-of select="$conflict-report"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="state" mode="conflicts">
+ <xsl:variable name="conflict-counts">
+ <xsl:apply-templates select="." mode="bison:count-conflicts" />
+ </xsl:variable>
+ <xsl:variable
+ name="sr-count" select="substring-before($conflict-counts, ',')"
+ />
+ <xsl:variable
+ name="rr-count" select="substring-after($conflict-counts, ',')"
+ />
+ <xsl:if test="$sr-count > 0 or $rr-count > 0">
+ <xsl:value-of select="concat('State ', @number, ' conflicts:')"/>
+ <xsl:if test="$sr-count > 0">
+ <xsl:value-of select="concat(' ', $sr-count, ' shift/reduce')"/>
+ <xsl:if test="$rr-count > 0">
+ <xsl:value-of select="(',')"/>
+ </xsl:if>
+ </xsl:if>
+ <xsl:if test="$rr-count > 0">
+ <xsl:value-of select="concat(' ', $rr-count, ' reduce/reduce')"/>
+ </xsl:if>
+ <xsl:value-of select="'&#10;'"/>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="automaton">
+ <xsl:apply-templates select="state">
+ <xsl:with-param name="pad" select="'3'"/>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="automaton/state">
+ <xsl:param name="pad"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:text>State </xsl:text>
+ <xsl:value-of select="@number"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="itemset/item">
+ <xsl:with-param name="pad" select="$pad"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="actions/transitions">
+ <xsl:with-param name="type" select="'shift'"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="actions/errors"/>
+ <xsl:apply-templates select="actions/reductions"/>
+ <xsl:apply-templates select="actions/transitions">
+ <xsl:with-param name="type" select="'goto'"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="solved-conflicts"/>
+</xsl:template>
+
+<xsl:template match="actions/transitions">
+ <xsl:param name="type"/>
+ <xsl:if test="transition[@type = $type]">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="transition[@type = $type]">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="transition[@type = $type]"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="actions/errors">
+ <xsl:if test="error">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="error">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="error"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="actions/reductions">
+ <xsl:if test="reduction">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="reduction">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="reduction"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="item">
+ <xsl:param name="pad"/>
+ <xsl:param name="prev-rule-number"
+ select="preceding-sibling::item[1]/@rule-number"/>
+ <xsl:apply-templates
+ select="key('bison:ruleByNumber', current()/@rule-number)"
+ >
+ <xsl:with-param name="itemset" select="'true'"/>
+ <xsl:with-param name="pad" select="$pad"/>
+ <xsl:with-param
+ name="prev-lhs"
+ select="key('bison:ruleByNumber', $prev-rule-number)/lhs[text()]"
+ />
+ <xsl:with-param name="point" select="@point"/>
+ <xsl:with-param name="lookaheads">
+ <xsl:apply-templates select="lookaheads"/>
+ </xsl:with-param>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="rule">
+ <xsl:param name="itemset"/>
+ <xsl:param name="pad"/>
+ <xsl:param name="prev-lhs"/>
+ <xsl:param name="point"/>
+ <xsl:param name="lookaheads"/>
+
+ <xsl:if test="$itemset != 'true' and not($prev-lhs = lhs[text()])">
+ <xsl:text>&#10;</xsl:text>
+ </xsl:if>
+
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="string(@number)"/>
+ <xsl:with-param name="pad" select="number($pad)"/>
+ </xsl:call-template>
+ <xsl:text> </xsl:text>
+
+ <!-- LHS -->
+ <xsl:choose>
+ <xsl:when test="$itemset != 'true' and $prev-lhs = lhs[text()]">
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="'|'"/>
+ <xsl:with-param name="pad" select="number(string-length(lhs[text()])) + 1"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:when test="$itemset = 'true' and $prev-lhs = lhs[text()]">
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="'|'"/>
+ <xsl:with-param name="pad" select="number(string-length(lhs[text()])) + 1"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="lhs"/>
+ <xsl:text>:</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+
+ <!-- RHS -->
+ <xsl:for-each select="rhs/*">
+ <xsl:if test="position() = $point + 1">
+ <xsl:text> .</xsl:text>
+ </xsl:if>
+ <xsl:if test="$itemset = 'true' and name(.) != 'empty'">
+ <xsl:apply-templates select="."/>
+ </xsl:if>
+ <xsl:if test="$itemset != 'true'">
+ <xsl:apply-templates select="."/>
+ </xsl:if>
+ <xsl:if test="position() = last() and position() = $point">
+ <xsl:text> .</xsl:text>
+ </xsl:if>
+ </xsl:for-each>
+ <xsl:if test="$lookaheads">
+ <xsl:value-of select="$lookaheads"/>
+ </xsl:if>
+
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="symbol">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="."/>
+</xsl:template>
+
+<xsl:template match="empty">
+ <xsl:text> %empty</xsl:text>
+</xsl:template>
+
+<xsl:template match="lookaheads">
+ <xsl:text> [</xsl:text>
+ <xsl:apply-templates select="symbol"/>
+ <xsl:text>]</xsl:text>
+</xsl:template>
+
+<xsl:template match="lookaheads/symbol">
+ <xsl:value-of select="."/>
+ <xsl:if test="position() != last()">
+ <xsl:text>, </xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="transition">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:choose>
+ <xsl:when test="@type = 'shift'">
+ <xsl:text>shift, and go to state </xsl:text>
+ <xsl:value-of select="@state"/>
+ </xsl:when>
+ <xsl:when test="@type = 'goto'">
+ <xsl:text>go to state </xsl:text>
+ <xsl:value-of select="@state"/>
+ </xsl:when>
+ </xsl:choose>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="error">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:text>error</xsl:text>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of select="text()"/>
+ <xsl:text>)</xsl:text>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="reduction">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:if test="@enabled = 'false'">
+ <xsl:text>[</xsl:text>
+ </xsl:if>
+ <xsl:choose>
+ <xsl:when test="@rule = 'accept'">
+ <xsl:text>accept</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:text>reduce using rule </xsl:text>
+ <xsl:value-of select="@rule"/>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of
+ select="key('bison:ruleByNumber', current()/@rule)/lhs[text()]"/>
+ <xsl:text>)</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:if test="@enabled = 'false'">
+ <xsl:text>]</xsl:text>
+ </xsl:if>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="solved-conflicts">
+ <xsl:if test="resolution">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="resolution"/>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="resolution">
+ <xsl:text> Conflict between rule </xsl:text>
+ <xsl:value-of select="@rule"/>
+ <xsl:text> and token </xsl:text>
+ <xsl:value-of select="@symbol"/>
+ <xsl:text> resolved as </xsl:text>
+ <xsl:if test="@type = 'error'">
+ <xsl:text>an </xsl:text>
+ </xsl:if>
+ <xsl:value-of select="@type"/>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of select="."/>
+ <xsl:text>).&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template name="max-width-symbol">
+ <xsl:param name="node"/>
+ <xsl:variable name="longest">
+ <xsl:for-each select="$node">
+ <xsl:sort data-type="number" select="string-length(@symbol)"
+ order="descending"/>
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="string-length(@symbol)"/>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:variable>
+ <xsl:value-of select="$longest"/>
+</xsl:template>
+
+<xsl:template name="lpad">
+ <xsl:param name="str" select="''"/>
+ <xsl:param name="pad" select="0"/>
+ <xsl:variable name="diff" select="$pad - string-length($str)" />
+ <xsl:choose>
+ <xsl:when test="$diff &lt; 0">
+ <xsl:value-of select="$str"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$diff"/>
+ </xsl:call-template>
+ <xsl:value-of select="$str"/>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="rpad">
+ <xsl:param name="str" select="''"/>
+ <xsl:param name="pad" select="0"/>
+ <xsl:variable name="diff" select="$pad - string-length($str)"/>
+ <xsl:choose>
+ <xsl:when test="$diff &lt; 0">
+ <xsl:value-of select="$str"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="$str"/>
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$diff"/>
+ </xsl:call-template>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="line-wrap">
+ <xsl:param name="line-length"/> <!-- required -->
+ <xsl:param name="first-line-length" select="$line-length"/>
+ <xsl:param name="text"/> <!-- required -->
+ <xsl:choose>
+ <xsl:when test="normalize-space($text) = ''" />
+ <xsl:when test="string-length($text) &lt;= $first-line-length">
+ <xsl:value-of select="concat($text, '&#10;')" />
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:variable name="break-pos">
+ <xsl:call-template name="ws-search">
+ <xsl:with-param name="text" select="$text" />
+ <xsl:with-param name="start" select="$first-line-length+1" />
+ </xsl:call-template>
+ </xsl:variable>
+ <xsl:value-of select="substring($text, 1, $break-pos - 1)" />
+ <xsl:text>&#10;</xsl:text>
+ <xsl:call-template name="line-wrap">
+ <xsl:with-param name="line-length" select="$line-length" />
+ <xsl:with-param
+ name="text" select="concat(' ', substring($text, $break-pos+1))"
+ />
+ </xsl:call-template>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="ws-search">
+ <xsl:param name="text"/> <!-- required -->
+ <xsl:param name="start"/> <!-- required -->
+ <xsl:variable name="search-text" select="substring($text, $start)" />
+ <xsl:choose>
+ <xsl:when test="not(contains($search-text, ' '))">
+ <xsl:value-of select="string-length($text)+1" />
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of
+ select="$start + string-length(substring-before($search-text, ' '))"
+ />
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+</xsl:stylesheet>
diff --git a/gnuwin32/bin/data/xslt/xml2xhtml.xsl b/gnuwin32/bin/data/xslt/xml2xhtml.xsl
new file mode 100644
index 00000000..d2cfed4c
--- /dev/null
+++ b/gnuwin32/bin/data/xslt/xml2xhtml.xsl
@@ -0,0 +1,745 @@
+<?xml version="1.0" encoding="UTF-8"?>
+
+<!--
+ xml2html.xsl - transform Bison XML Report into XHTML.
+
+ Copyright (C) 2007-2013 Free Software Foundation, Inc.
+
+ This file is part of Bison, the GNU Compiler Compiler.
+
+ This program is free software: you can redistribute it and/or modify
+ it under the terms of the GNU General Public License as published by
+ the Free Software Foundation, either version 3 of the License, or
+ (at your option) any later version.
+
+ This program is distributed in the hope that it will be useful,
+ but WITHOUT ANY WARRANTY; without even the implied warranty of
+ MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE. See the
+ GNU General Public License for more details.
+
+ You should have received a copy of the GNU General Public License
+ along with this program. If not, see <http://www.gnu.org/licenses/>.
+
+ Written by Wojciech Polak <polak@gnu.org>.
+ -->
+
+<xsl:stylesheet version="1.0"
+ xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
+ xmlns="http://www.w3.org/1999/xhtml"
+ xmlns:bison="http://www.gnu.org/software/bison/">
+
+<xsl:import href="bison.xsl"/>
+
+<xsl:output method="xml" encoding="UTF-8"
+ doctype-public="-//W3C//DTD XHTML 1.0 Strict//EN"
+ doctype-system="http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd"
+ indent="yes"/>
+
+<xsl:template match="/">
+ <html>
+ <head>
+ <title>
+ <xsl:value-of select="bison-xml-report/filename"/>
+ <xsl:text> - GNU Bison XML Automaton Report</xsl:text>
+ </title>
+ <style type="text/css"><![CDATA[
+ body {
+ font-family: "Nimbus Sans L", Arial, sans-serif;
+ font-size: 9pt;
+ }
+ a:link {
+ color: #1f00ff;
+ text-decoration: none;
+ }
+ a:visited {
+ color: #1f00ff;
+ text-decoration: none;
+ }
+ a:hover {
+ color: red;
+ }
+ #menu a {
+ text-decoration: underline;
+ }
+ .i {
+ font-style: italic;
+ }
+ .pre {
+ font-family: monospace;
+ white-space: pre;
+ }
+ ol.decimal {
+ list-style-type: decimal;
+ }
+ ol.lower-alpha {
+ list-style-type: lower-alpha;
+ }
+ .point {
+ color: #cc0000;
+ }
+ #footer {
+ margin-top: 3.5em;
+ font-size: 7pt;
+ }
+ ]]></style>
+ </head>
+ <body>
+ <xsl:apply-templates select="bison-xml-report"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <div id="footer"><hr />This document was generated using
+ <a href="http://www.gnu.org/software/bison/" title="GNU Bison">
+ GNU Bison <xsl:value-of select="/bison-xml-report/@version"/></a>
+ XML Automaton Report.<br />
+ <!-- default copying notice -->
+ Verbatim copying and distribution of this entire page is
+ permitted in any medium, provided this notice is preserved.</div>
+ </body>
+ </html>
+</xsl:template>
+
+<xsl:template match="bison-xml-report">
+ <h1>GNU Bison XML Automaton Report</h1>
+ <p>
+ input grammar: <span class="i"><xsl:value-of select="filename"/></span>
+ </p>
+
+ <xsl:text>&#10;&#10;</xsl:text>
+ <h3>Table of Contents</h3>
+ <ul id="menu">
+ <li>
+ <a href="#reductions">Reductions</a>
+ <ul class="lower-alpha">
+ <li><a href="#nonterminals_useless_in_grammar">Nonterminals useless in grammar</a></li>
+ <li><a href="#terminals_unused_in_grammar">Terminals unused in grammar</a></li>
+ <li><a href="#rules_useless_in_grammar">Rules useless in grammar</a></li>
+ <xsl:if test="grammar/rules/rule[@usefulness='useless-in-parser']">
+ <li><a href="#rules_useless_in_parser">Rules useless in parser due to conflicts</a></li>
+ </xsl:if>
+ </ul>
+ </li>
+ <li><a href="#conflicts">Conflicts</a></li>
+ <li>
+ <a href="#grammar">Grammar</a>
+ <ul class="lower-alpha">
+ <li><a href="#grammar">Itemset</a></li>
+ <li><a href="#terminals">Terminal symbols</a></li>
+ <li><a href="#nonterminals">Nonterminal symbols</a></li>
+ </ul>
+ </li>
+ <li><a href="#automaton">Automaton</a></li>
+ </ul>
+ <xsl:apply-templates select="grammar" mode="reductions"/>
+ <xsl:apply-templates select="grammar" mode="useless-in-parser"/>
+ <xsl:apply-templates select="automaton" mode="conflicts"/>
+ <xsl:apply-templates select="grammar"/>
+ <xsl:apply-templates select="automaton"/>
+</xsl:template>
+
+<xsl:template match="grammar" mode="reductions">
+ <h2>
+ <a name="reductions"/>
+ <xsl:text> Reductions</xsl:text>
+ </h2>
+ <xsl:apply-templates select="nonterminals" mode="useless-in-grammar"/>
+ <xsl:apply-templates select="terminals" mode="unused-in-grammar"/>
+ <xsl:apply-templates select="rules" mode="useless-in-grammar"/>
+</xsl:template>
+
+<xsl:template match="nonterminals" mode="useless-in-grammar">
+ <h3>
+ <a name="nonterminals_useless_in_grammar"/>
+ <xsl:text> Nonterminals useless in grammar</xsl:text>
+ </h3>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:if test="nonterminal[@usefulness='useless-in-grammar']">
+ <p class="pre">
+ <xsl:for-each select="nonterminal[@usefulness='useless-in-grammar']">
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="@name"/>
+ <xsl:text>&#10;</xsl:text>
+ </xsl:for-each>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </p>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="terminals" mode="unused-in-grammar">
+ <h3>
+ <a name="terminals_unused_in_grammar"/>
+ <xsl:text> Terminals unused in grammar</xsl:text>
+ </h3>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:if test="terminal[@usefulness='unused-in-grammar']">
+ <p class="pre">
+ <xsl:for-each select="terminal[@usefulness='unused-in-grammar']">
+ <xsl:sort select="@symbol-number" data-type="number"/>
+ <xsl:text> </xsl:text>
+ <xsl:value-of select="@name"/>
+ <xsl:text>&#10;</xsl:text>
+ </xsl:for-each>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </p>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="rules" mode="useless-in-grammar">
+ <h3>
+ <a name="rules_useless_in_grammar"/>
+ <xsl:text> Rules useless in grammar</xsl:text>
+ </h3>
+ <xsl:text>&#10;</xsl:text>
+ <xsl:variable name="set" select="rule[@usefulness='useless-in-grammar']"/>
+ <xsl:if test="$set">
+ <p class="pre">
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param name="rule-set" select="$set"/>
+ </xsl:call-template>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </p>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="grammar" mode="useless-in-parser">
+ <xsl:variable
+ name="set" select="rules/rule[@usefulness='useless-in-parser']"
+ />
+ <xsl:if test="$set">
+ <h2>
+ <a name="rules_useless_in_parser"/>
+ <xsl:text> Rules useless in parser due to conflicts</xsl:text>
+ </h2>
+ <xsl:text>&#10;</xsl:text>
+ <p class="pre">
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param name="rule-set" select="$set"/>
+ </xsl:call-template>
+ </p>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="grammar">
+ <h2>
+ <a name="grammar"/>
+ <xsl:text> Grammar</xsl:text>
+ </h2>
+ <xsl:text>&#10;</xsl:text>
+ <p class="pre">
+ <xsl:call-template name="style-rule-set">
+ <xsl:with-param
+ name="rule-set" select="rules/rule[@usefulness!='useless-in-grammar']"
+ />
+ </xsl:call-template>
+ </p>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:apply-templates select="terminals"/>
+ <xsl:apply-templates select="nonterminals"/>
+</xsl:template>
+
+<xsl:template name="style-rule-set">
+ <xsl:param name="rule-set"/>
+ <xsl:for-each select="$rule-set">
+ <xsl:apply-templates select=".">
+ <xsl:with-param name="pad" select="'3'"/>
+ <xsl:with-param name="prev-lhs">
+ <xsl:if test="position()>1">
+ <xsl:variable name="position" select="position()"/>
+ <xsl:value-of select="$rule-set[$position - 1]/lhs"/>
+ </xsl:if>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:for-each>
+</xsl:template>
+
+<xsl:template match="automaton" mode="conflicts">
+ <h2>
+ <a name="conflicts"/>
+ <xsl:text> Conflicts</xsl:text>
+ </h2>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <xsl:variable name="conflict-report">
+ <xsl:apply-templates select="state" mode="conflicts"/>
+ </xsl:variable>
+ <xsl:if test="string-length($conflict-report) != 0">
+ <p class="pre">
+ <xsl:copy-of select="$conflict-report"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ </p>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="state" mode="conflicts">
+ <xsl:variable name="conflict-counts">
+ <xsl:apply-templates select="." mode="bison:count-conflicts" />
+ </xsl:variable>
+ <xsl:variable
+ name="sr-count" select="substring-before($conflict-counts, ',')"
+ />
+ <xsl:variable
+ name="rr-count" select="substring-after($conflict-counts, ',')"
+ />
+ <xsl:if test="$sr-count > 0 or $rr-count > 0">
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#state_', @number)"/>
+ </xsl:attribute>
+ <xsl:value-of select="concat('State ', @number)"/>
+ </a>
+ <xsl:text> conflicts:</xsl:text>
+ <xsl:if test="$sr-count > 0">
+ <xsl:value-of select="concat(' ', $sr-count, ' shift/reduce')"/>
+ <xsl:if test="$rr-count > 0">
+ <xsl:value-of select="(',')"/>
+ </xsl:if>
+ </xsl:if>
+ <xsl:if test="$rr-count > 0">
+ <xsl:value-of select="concat(' ', $rr-count, ' reduce/reduce')"/>
+ </xsl:if>
+ <xsl:value-of select="'&#10;'"/>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="grammar/terminals">
+ <h3>
+ <a name="terminals"/>
+ <xsl:text> Terminals, with rules where they appear</xsl:text>
+ </h3>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <p class="pre">
+ <xsl:apply-templates select="terminal"/>
+ </p>
+ <xsl:text>&#10;&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="grammar/nonterminals">
+ <h3>
+ <a name="nonterminals"/>
+ <xsl:text> Nonterminals, with rules where they appear</xsl:text>
+ </h3>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <p class="pre">
+ <xsl:apply-templates
+ select="nonterminal[@usefulness!='useless-in-grammar']"
+ />
+ </p>
+</xsl:template>
+
+<xsl:template match="terminal">
+ <b><xsl:value-of select="@name"/></b>
+ <xsl:value-of select="concat(' (', @token-number, ')')"/>
+ <xsl:for-each select="key('bison:ruleByRhs', @name)">
+ <xsl:apply-templates select="." mode="number-link"/>
+ </xsl:for-each>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="nonterminal">
+ <b><xsl:value-of select="@name"/></b>
+ <xsl:value-of select="concat(' (', @symbol-number, ')')"/>
+ <xsl:text>&#10; </xsl:text>
+ <xsl:if test="key('bison:ruleByLhs', @name)">
+ <xsl:text>on left:</xsl:text>
+ <xsl:for-each select="key('bison:ruleByLhs', @name)">
+ <xsl:apply-templates select="." mode="number-link"/>
+ </xsl:for-each>
+ </xsl:if>
+ <xsl:if test="key('bison:ruleByRhs', @name)">
+ <xsl:if test="key('bison:ruleByLhs', @name)">
+ <xsl:text>&#10; </xsl:text>
+ </xsl:if>
+ <xsl:text>on right:</xsl:text>
+ <xsl:for-each select="key('bison:ruleByRhs', @name)">
+ <xsl:apply-templates select="." mode="number-link"/>
+ </xsl:for-each>
+ </xsl:if>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="rule" mode="number-link">
+ <xsl:text> </xsl:text>
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#rule_', @number)"/>
+ </xsl:attribute>
+ <xsl:value-of select="@number"/>
+ </a>
+</xsl:template>
+
+<xsl:template match="automaton">
+ <h2>
+ <a name="automaton"/>
+ <xsl:text> Automaton</xsl:text>
+ </h2>
+ <xsl:apply-templates select="state">
+ <xsl:with-param name="pad" select="'3'"/>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="automaton/state">
+ <xsl:param name="pad"/>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <h3>
+ <a>
+ <xsl:attribute name="name">
+ <xsl:value-of select="concat('state_', @number)"/>
+ </xsl:attribute>
+ </a>
+ <xsl:text>state </xsl:text>
+ <xsl:value-of select="@number"/>
+ </h3>
+ <xsl:text>&#10;&#10;</xsl:text>
+ <p class="pre">
+ <xsl:apply-templates select="itemset/item">
+ <xsl:with-param name="pad" select="$pad"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="actions/transitions">
+ <xsl:with-param name="type" select="'shift'"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="actions/errors"/>
+ <xsl:apply-templates select="actions/reductions"/>
+ <xsl:apply-templates select="actions/transitions">
+ <xsl:with-param name="type" select="'goto'"/>
+ </xsl:apply-templates>
+ <xsl:apply-templates select="solved-conflicts"/>
+ </p>
+</xsl:template>
+
+<xsl:template match="actions/transitions">
+ <xsl:param name="type"/>
+ <xsl:if test="transition[@type = $type]">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="transition[@type = $type]">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="transition[@type = $type]"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="actions/errors">
+ <xsl:if test="error">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="error">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="error"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="actions/reductions">
+ <xsl:if test="reduction">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="reduction">
+ <xsl:with-param name="pad">
+ <xsl:call-template name="max-width-symbol">
+ <xsl:with-param name="node" select="reduction"/>
+ </xsl:call-template>
+ </xsl:with-param>
+ </xsl:apply-templates>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="item">
+ <xsl:param name="pad"/>
+ <xsl:param name="prev-rule-number"
+ select="preceding-sibling::item[1]/@rule-number"/>
+ <xsl:apply-templates
+ select="key('bison:ruleByNumber', current()/@rule-number)"
+ >
+ <xsl:with-param name="itemset" select="'true'"/>
+ <xsl:with-param name="pad" select="$pad"/>
+ <xsl:with-param name="prev-lhs"
+ select="key('bison:ruleByNumber', $prev-rule-number)/lhs[text()]"
+ />
+ <xsl:with-param name="point" select="@point"/>
+ <xsl:with-param name="lookaheads">
+ <xsl:apply-templates select="lookaheads"/>
+ </xsl:with-param>
+ </xsl:apply-templates>
+</xsl:template>
+
+<xsl:template match="rule">
+ <xsl:param name="itemset"/>
+ <xsl:param name="pad"/>
+ <xsl:param name="prev-lhs"/>
+ <xsl:param name="point"/>
+ <xsl:param name="lookaheads"/>
+
+ <xsl:if test="$itemset != 'true' and not($prev-lhs = lhs[text()])">
+ <xsl:text>&#10;</xsl:text>
+ </xsl:if>
+
+ <xsl:if test="$itemset != 'true'">
+ <a>
+ <xsl:attribute name="name">
+ <xsl:value-of select="concat('rule_', @number)"/>
+ </xsl:attribute>
+ </a>
+ </xsl:if>
+ <xsl:text> </xsl:text>
+
+ <xsl:choose>
+ <xsl:when test="$itemset = 'true'">
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#rule_', @number)"/>
+ </xsl:attribute>
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="string(@number)"/>
+ <xsl:with-param name="pad" select="number($pad)"/>
+ </xsl:call-template>
+ </a>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="string(@number)"/>
+ <xsl:with-param name="pad" select="number($pad)"/>
+ </xsl:call-template>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:text> </xsl:text>
+
+ <!-- LHS -->
+ <xsl:choose>
+ <xsl:when test="$itemset != 'true' and $prev-lhs = lhs[text()]">
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="'|'"/>
+ <xsl:with-param name="pad" select="number(string-length(lhs[text()])) + 2"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:when test="$itemset = 'true' and $prev-lhs = lhs[text()]">
+ <xsl:call-template name="lpad">
+ <xsl:with-param name="str" select="'|'"/>
+ <xsl:with-param name="pad" select="number(string-length(lhs[text()])) + 2"/>
+ </xsl:call-template>
+ </xsl:when>
+ <xsl:otherwise>
+ <span class="i">
+ <xsl:value-of select="lhs"/>
+ </span>
+ <xsl:text> &#8594;</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+
+ <!-- RHS -->
+ <xsl:for-each select="rhs/*">
+ <xsl:if test="position() = $point + 1">
+ <xsl:text> </xsl:text>
+ <span class="point">.</span>
+ </xsl:if>
+ <xsl:if test="$itemset = 'true' and name(.) != 'empty'">
+ <xsl:apply-templates select="."/>
+ </xsl:if>
+ <xsl:if test="$itemset != 'true'">
+ <xsl:apply-templates select="."/>
+ </xsl:if>
+ <xsl:if test="position() = last() and position() = $point">
+ <xsl:text> </xsl:text>
+ <span class="point">.</span>
+ </xsl:if>
+ </xsl:for-each>
+ <xsl:if test="$lookaheads">
+ <xsl:value-of select="$lookaheads"/>
+ </xsl:if>
+
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="symbol">
+ <xsl:text> </xsl:text>
+ <xsl:choose>
+ <xsl:when test="name(key('bison:symbolByName', .)) = 'nonterminal'">
+ <span class="i"><xsl:value-of select="."/></span>
+ </xsl:when>
+ <xsl:otherwise>
+ <b><xsl:value-of select="."/></b>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template match="empty">
+ <xsl:text> &#949;</xsl:text>
+</xsl:template>
+
+<xsl:template match="lookaheads">
+ <xsl:text> [</xsl:text>
+ <xsl:apply-templates select="symbol"/>
+ <xsl:text>]</xsl:text>
+</xsl:template>
+
+<xsl:template match="lookaheads/symbol">
+ <xsl:value-of select="."/>
+ <xsl:if test="position() != last()">
+ <xsl:text>, </xsl:text>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="transition">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:choose>
+ <xsl:when test="@type = 'shift'">
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#state_', @state)"/>
+ </xsl:attribute>
+ <xsl:value-of select="concat('shift, and go to state ', @state)"/>
+ </a>
+ </xsl:when>
+ <xsl:when test="@type = 'goto'">
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#state_', @state)"/>
+ </xsl:attribute>
+ <xsl:value-of select="concat('go to state ', @state)"/>
+ </a>
+ </xsl:when>
+ </xsl:choose>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="error">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:text>error</xsl:text>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of select="text()"/>
+ <xsl:text>)</xsl:text>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="reduction">
+ <xsl:param name="pad"/>
+ <xsl:text> </xsl:text>
+ <xsl:call-template name="rpad">
+ <xsl:with-param name="str" select="string(@symbol)"/>
+ <xsl:with-param name="pad" select="number($pad) + 2"/>
+ </xsl:call-template>
+ <xsl:if test="@enabled = 'false'">
+ <xsl:text>[</xsl:text>
+ </xsl:if>
+ <xsl:choose>
+ <xsl:when test="@rule = 'accept'">
+ <xsl:text>accept</xsl:text>
+ </xsl:when>
+ <xsl:otherwise>
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#rule_', @rule)"/>
+ </xsl:attribute>
+ <xsl:value-of select="concat('reduce using rule ', @rule)"/>
+ </a>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of
+ select="key('bison:ruleByNumber', current()/@rule)/lhs[text()]"
+ />
+ <xsl:text>)</xsl:text>
+ </xsl:otherwise>
+ </xsl:choose>
+ <xsl:if test="@enabled = 'false'">
+ <xsl:text>]</xsl:text>
+ </xsl:if>
+ <xsl:text>&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template match="solved-conflicts">
+ <xsl:if test="resolution">
+ <xsl:text>&#10;</xsl:text>
+ <xsl:apply-templates select="resolution"/>
+ </xsl:if>
+</xsl:template>
+
+<xsl:template match="resolution">
+ <xsl:text> Conflict between </xsl:text>
+ <a>
+ <xsl:attribute name="href">
+ <xsl:value-of select="concat('#rule_', @rule)"/>
+ </xsl:attribute>
+ <xsl:value-of select="concat('rule ',@rule)"/>
+ </a>
+ <xsl:text> and token </xsl:text>
+ <xsl:value-of select="@symbol"/>
+ <xsl:text> resolved as </xsl:text>
+ <xsl:if test="@type = 'error'">
+ <xsl:text>an </xsl:text>
+ </xsl:if>
+ <xsl:value-of select="@type"/>
+ <xsl:text> (</xsl:text>
+ <xsl:value-of select="."/>
+ <xsl:text>).&#10;</xsl:text>
+</xsl:template>
+
+<xsl:template name="max-width-symbol">
+ <xsl:param name="node"/>
+ <xsl:variable name="longest">
+ <xsl:for-each select="$node">
+ <xsl:sort data-type="number" select="string-length(@symbol)"
+ order="descending"/>
+ <xsl:if test="position() = 1">
+ <xsl:value-of select="string-length(@symbol)"/>
+ </xsl:if>
+ </xsl:for-each>
+ </xsl:variable>
+ <xsl:value-of select="$longest"/>
+</xsl:template>
+
+<xsl:template name="lpad">
+ <xsl:param name="str" select="''"/>
+ <xsl:param name="pad" select="0"/>
+ <xsl:variable name="diff" select="$pad - string-length($str)" />
+ <xsl:choose>
+ <xsl:when test="$diff &lt; 0">
+ <xsl:value-of select="$str"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$diff"/>
+ </xsl:call-template>
+ <xsl:value-of select="$str"/>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="rpad">
+ <xsl:param name="str" select="''"/>
+ <xsl:param name="pad" select="0"/>
+ <xsl:variable name="diff" select="$pad - string-length($str)"/>
+ <xsl:choose>
+ <xsl:when test="$diff &lt; 0">
+ <xsl:value-of select="$str"/>
+ </xsl:when>
+ <xsl:otherwise>
+ <xsl:value-of select="$str"/>
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$diff"/>
+ </xsl:call-template>
+ </xsl:otherwise>
+ </xsl:choose>
+</xsl:template>
+
+<xsl:template name="space">
+ <xsl:param name="repeat">0</xsl:param>
+ <xsl:param name="fill" select="' '"/>
+ <xsl:if test="number($repeat) &gt;= 1">
+ <xsl:call-template name="space">
+ <xsl:with-param name="repeat" select="$repeat - 1"/>
+ <xsl:with-param name="fill" select="$fill"/>
+ </xsl:call-template>
+ <xsl:value-of select="$fill"/>
+ </xsl:if>
+</xsl:template>
+
+</xsl:stylesheet>