Heavily extended the intents example

These intents features are now available:
- requests from the system-ui
- disambiguation when no applicationId is specified
- requesting from/replying to an in-process app
  (green is always running as a single-process app)
- private intents (blue-window-private)
- intents that require capabilities
  (only the sysui and red can call rotate-window on blue)

Also, the example wrapper script is now able to deal with
developer builds.

Change-Id: I9ff2d6012b2c9cf29e32abaaa7d4fa3b3122944e
Reviewed-by: Daniel d'Andrada <daniel.dandrada@luxoft.com>

2 files changed, 261 insertions, 0 deletions

diff --git a/examples/applicationmanager/intents/shared/IntentClient.qml b/examples/applicationmanager/intents/shared/IntentClient.qml
new file mode 100644
index 00000000..87f36561
--- /dev/null
+++ b/examples/applicationmanager/intents/shared/IntentClient.qml
@@ -0,0 +1,133 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 Pelagicore AG
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the Pelagicore Application Manager.
+**
+** $QT_BEGIN_LICENSE:BSD-QTAS$
+** Commercial License Usage
+** Licensees holding valid commercial Qt Automotive Suite licenses may use
+** this file in accordance with the commercial license agreement provided
+** with the Software or, alternatively, in accordance with the terms
+** contained in a written agreement between you and The Qt Company.  For
+** licensing terms and conditions see https://www.qt.io/terms-conditions.
+** For further information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+** SPDX-License-Identifier: BSD-3-Clause
+**
+****************************************************************************/
+
+import QtQuick 2.11
+import QtApplicationManager 1.0
+
+ApplicationManagerWindow {
+    id: root
+    property string flavor: ApplicationInterface.applicationId.split(".")[1]
+
+    IntentPage {
+        id: intentPage
+        anchors.fill: parent
+        flavor: root.flavor
+        title: ApplicationInterface.name["en"]
+
+        onRequest: {
+            var request = IntentClient.createIntentRequest(intentId, applicationId, parameters)
+            request.onFinished.connect(function() {
+                intentPage.setResult(request.requestId, request.succeeded,
+                                     request.succeeded ? request.result : request.errorMessage)
+            })
+        }
+
+        RotationAnimation on rotation {
+            id: rotationAnimation
+            running: false
+            duration: 500; from: 0; to: 360
+        }
+
+        SequentialAnimation  on scale {
+            id: scaleAnimation
+            running: false
+            PropertyAnimation { from: 1; to: 0.5 }
+            PropertyAnimation { from: 0.5; to: 1 }
+        }
+
+        SequentialAnimation on color {
+            id: blinkAnimation
+            running: false
+            ColorAnimation { to: "black" }
+            ColorAnimation { to: "white" }
+        }
+
+        SequentialAnimation on color {
+            id: blueAnimation
+            running: false
+            ColorAnimation { to: "blue"; duration: 2000 }
+            ColorAnimation { to: "white" }
+        }
+    }
+
+    IntentHandler {
+        intentIds: "rotate-window"
+        onReceivedRequest: {
+            rotationAnimation.start()
+            request.sendReply({ "done": true })
+        }
+    }
+
+    IntentHandler {
+        intentIds: "scale-window"
+        onReceivedRequest: {
+            scaleAnimation.start()
+            request.sendReply({ "done": true })
+        }
+    }
+
+    IntentHandler {
+        intentIds: "blink-window"
+        onReceivedRequest: {
+            blinkAnimation.start()
+            request.sendReply({ "done": true })
+        }
+    }
+
+    IntentHandler {
+        intentIds: "blue-window-private"
+        onReceivedRequest: {
+            blueAnimation.start()
+            request.sendReply({ "done": true })
+        }
+    }
+}
diff --git a/examples/applicationmanager/intents/shared/IntentPage.qml b/examples/applicationmanager/intents/shared/IntentPage.qml
new file mode 100644
index 00000000..7709a236
--- /dev/null
+++ b/examples/applicationmanager/intents/shared/IntentPage.qml
@@ -0,0 +1,128 @@
+/****************************************************************************
+**
+** Copyright (C) 2018 Pelagicore AG
+** Contact: https://www.qt.io/licensing/
+**
+** This file is part of the Pelagicore Application Manager.
+**
+** $QT_BEGIN_LICENSE:BSD-QTAS$
+** Commercial License Usage
+** Licensees holding valid commercial Qt Automotive Suite licenses may use
+** this file in accordance with the commercial license agreement provided
+** with the Software or, alternatively, in accordance with the terms
+** contained in a written agreement between you and The Qt Company.  For
+** licensing terms and conditions see https://www.qt.io/terms-conditions.
+** For further information use the contact form at https://www.qt.io/contact-us.
+**
+** BSD License Usage
+** Alternatively, you may use this file under the terms of the BSD license
+** as follows:
+**
+** "Redistribution and use in source and binary forms, with or without
+** modification, are permitted provided that the following conditions are
+** met:
+**   * Redistributions of source code must retain the above copyright
+**     notice, this list of conditions and the following disclaimer.
+**   * Redistributions in binary form must reproduce the above copyright
+**     notice, this list of conditions and the following disclaimer in
+**     the documentation and/or other materials provided with the
+**     distribution.
+**   * Neither the name of The Qt Company Ltd nor the names of its
+**     contributors may be used to endorse or promote products derived
+**     from this software without specific prior written permission.
+**
+**
+** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
+** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
+** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
+** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
+** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
+** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
+** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
+** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
+** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
+**
+** $QT_END_LICENSE$
+**
+** SPDX-License-Identifier: BSD-3-Clause
+**
+****************************************************************************/
+
+import QtQuick 2.11
+import QtQuick.Controls 2.4
+import QtQuick.Layouts 1.4
+import QtApplicationManager 1.0
+
+Rectangle {
+    id: root
+    property string flavor
+    property string title: flavor
+
+    function setResult(requestId, succeeded, result) {
+        lblRequestId.text = requestId
+        lblRequestStatus.text = succeeded ? "Result:" : "Error:"
+        lblResult.text = JSON.stringify(result)
+    }
+
+    signal request(string intentId, string applicationId, var parameters)
+
+    color: "white"
+    Rectangle {
+        opacity: 0.5
+        anchors.fill: parent
+        radius: 5
+        border.width: 1
+        border.color: root.color
+        gradient: Gradient {
+            GradientStop { position: 0.0; color: root.flavor }
+            GradientStop { position: 1.0; color: root.color }
+        }
+    }
+
+    GridLayout {
+        id: grid
+        anchors.fill: parent
+        anchors.margins: 5
+        rowSpacing: 0
+        columns: 2
+
+        Label {
+            text: root.title
+            font.bold: true;
+            horizontalAlignment: Text.AlignHCenter
+            Layout.columnSpan: 2
+            Layout.fillWidth: true
+        }
+        Label { text: "Intent:" }
+        ComboBox {
+            id: cbIntent
+            model: [ "rotate-window", "scale-window", "blink-window", "blue-window-private" ]
+            Layout.fillWidth: true
+        }
+        Label { text: "Application:" }
+        ComboBox {
+            id: cbApplication
+            model: [ "<not specified>", "intents.red", "intents.green", "intents.blue" ]
+            Layout.fillWidth: true
+        }
+        Button {
+            id: btRequest
+            text: "Request"
+            Layout.columnSpan: 2
+            Layout.fillWidth: true
+            Layout.alignment: Qt.AlignCenter
+
+            onClicked: {
+                var appId = cbApplication.currentIndex === 0 ? "" : cbApplication.currentText
+                root.request(cbIntent.currentText, appId, { "Request": { "Parameters": { "Testing": 1 }}})
+            }
+        }
+        Label { text: "Request:" }
+        Label { id: lblRequestId; Layout.fillWidth: true }
+        Label { id: lblRequestStatus }
+        Label { id: lblResult; Layout.fillWidth: true }
+        Item { Layout.fillHeight: true }
+    }
+}