CMake: Choose better defaults for qt_add_plugin STATIC/SHARED

There was a recent behavior change where the public CMake API
qt_add_plugin API took into account the value of BUILD_SHARED_LIBS
to decide whether the plugin should be a static or shared library.

Instead, use the following new behavior

 - If no explicit option STATIC / SHARED option is passed, default to
   whatever flavor Qt was built as.
   Aka if Qt was configured with -shared, qt_add_plugin defaults
   to creating shared plugins. If it's a -static Qt, create static
   plugins.
 - If an explicit STATIC / SHARED option is set, override the default
   computed value with the given value.

As a result BUILD_SHARED_LIBS does not affect Qt plugins anymore. This
is more in line with Qt expectations.

Add SHARED as a new valid option to pass to qt_add_plugin (it wasn't
before).

Add tests to check for the above behavior.

Amends aa4a1006cbccbc180c600f9b4dc9e882bb5ed5ca

Fixes: QTBUG-92361
Task-number: QTBUG-88763
Change-Id: Iae806024ddd5cf10cfe58ddbcebd2818084b0bd7
Reviewed-by: Joerg Bornemann <joerg.bornemann@qt.io>
(cherry picked from commit d0c2425d791edd75e35cce65ddbcfaab9a7f16ed)
Reviewed-by: Qt Cherry-pick Bot <cherrypick_bot@qt-project.org>

6 files changed, 96 insertions, 4 deletions

diff --git a/CMakeLists.txt b/CMakeLists.txt
index 2e05aa52e8..316430391d 100644
--- a/CMakeLists.txt
+++ b/CMakeLists.txt
@@ -71,6 +71,10 @@ if(NOT QT_BUILD_STANDALONE_TESTS)
     option(BUILD_SHARED_LIBS "Build Qt statically or dynamically" ON)
     set(QT_BUILD_SHARED_LIBS ${BUILD_SHARED_LIBS})
 
+    # This variable is also set in Qt6CoreConfigExtras.cmake, but it's not loaded when building
+    # qtbase. Set it here so qt_add_plugin can compute the proper plugin flavor.
+    set(QT6_IS_SHARED_LIBS_BUILD ${BUILD_SHARED_LIBS})
+
     ## Should this Qt be built with Werror?
     option(WARNINGS_ARE_ERRORS "Build Qt with warnings as errors" ${FEATURE_developer_build})
 
diff --git a/src/corelib/Qt6CTestMacros.cmake b/src/corelib/Qt6CTestMacros.cmake
index 9062985ac0..5a96e15ea6 100644
--- a/src/corelib/Qt6CTestMacros.cmake
+++ b/src/corelib/Qt6CTestMacros.cmake
@@ -114,10 +114,19 @@ function(_qt_internal_set_up_test_run_environment testname)
 endfunction()
 
 # Checks if the test project can be built successfully.
+#
+# TESTNAME: a custom test name to use instead of the one derived from the source directory name
+# BUILD_OPTIONS: a list of -D style CMake definitions to pass to ctest's --build-options (which
+#                are ultimately passed to the CMake invocation of the test project)
 macro(_qt_internal_test_expect_pass _dir)
-  cmake_parse_arguments(_ARGS "" "BINARY" "" ${ARGN})
-  string(REPLACE "(" "_" testname "${_dir}")
-  string(REPLACE ")" "_" testname "${testname}")
+  cmake_parse_arguments(_ARGS "" "BINARY;TESTNAME" "BUILD_OPTIONS" ${ARGN})
+
+  if(_ARGS_TESTNAME)
+      set(testname "${_ARGS_TESTNAME}")
+  else()
+      string(REPLACE "(" "_" testname "${_dir}")
+      string(REPLACE ")" "_" testname "${testname}")
+  endif()
 
   set(__expect_pass__prefixes "${CMAKE_PREFIX_PATH}")
   string(REPLACE ";" "\;" __expect_pass__prefixes "${__expect_pass__prefixes}")
@@ -131,6 +140,7 @@ macro(_qt_internal_test_expect_pass _dir)
       --build-makeprogram "${CMAKE_MAKE_PROGRAM}"
       --build-project "${_dir}"
       --build-options "-DCMAKE_PREFIX_PATH=${__expect_pass__prefixes}" ${BUILD_OPTIONS_LIST}
+                      ${_ARGS_BUILD_OPTIONS}
       --test-command ${_ARGS_BINARY})
   add_test(${testname} ${CMAKE_CTEST_COMMAND} ${ctest_command_args})
   if(_ARGS_BINARY)
diff --git a/src/corelib/Qt6CoreMacros.cmake b/src/corelib/Qt6CoreMacros.cmake
index 9e9b0f1e56..3d1a10ff0a 100644
--- a/src/corelib/Qt6CoreMacros.cmake
+++ b/src/corelib/Qt6CoreMacros.cmake
@@ -1423,6 +1423,7 @@ endfunction()
 macro(_qt_internal_get_add_plugin_keywords option_args single_args multi_args)
     set(${option_args}
         STATIC
+        SHARED
     )
     set(${single_args}
         TYPE
@@ -1455,7 +1456,27 @@ function(qt6_add_plugin target)
         unset(arg_CLASSNAME)
     endif()
 
-    if (arg_STATIC OR NOT BUILD_SHARED_LIBS)
+    if(arg_STATIC AND arg_SHARED)
+        message(FATAL_ERROR
+            "Both STATIC and SHARED options were given. Only one of the two should be used."
+        )
+    endif()
+
+    # If no explicit STATIC/SHARED option is set, default to the flavor of the Qt build.
+    if(QT6_IS_SHARED_LIBS_BUILD)
+        set(create_static_plugin FALSE)
+    else()
+        set(create_static_plugin TRUE)
+    endif()
+
+    # Explicit option takes priority over the computed default.
+    if(arg_STATIC)
+        set(create_static_plugin TRUE)
+    elseif(arg_SHARED)
+        set(create_static_plugin FALSE)
+    endif()
+
+    if (create_static_plugin)
         add_library(${target} STATIC)
         target_compile_definitions(${target} PRIVATE QT_STATICPLUGIN)
     else()
diff --git a/tests/auto/cmake/CMakeLists.txt b/tests/auto/cmake/CMakeLists.txt
index 317541f984..b43aa8f0a6 100644
--- a/tests/auto/cmake/CMakeLists.txt
+++ b/tests/auto/cmake/CMakeLists.txt
@@ -226,3 +226,5 @@ _qt_internal_test_expect_pass(test_versionless_targets)
 
 _qt_internal_test_expect_pass(test_add_resources_binary_generated
                               BINARY test_add_resources_binary_generated)
+
+include(test_plugin_shared_static_flavor.cmake)
diff --git a/tests/auto/cmake/test_plugin_shared_static_flavor.cmake b/tests/auto/cmake/test_plugin_shared_static_flavor.cmake
new file mode 100644
index 0000000000..a906bfebbc
--- /dev/null
+++ b/tests/auto/cmake/test_plugin_shared_static_flavor.cmake
@@ -0,0 +1,24 @@
+_qt_internal_test_expect_pass(test_plugin_shared_static_flavor
+                              TESTNAME test_plugin_flavor_static
+                              BUILD_OPTIONS
+                              "-DPLUGIN_OPTIONS=STATIC"
+                              "-DEXPECTED_PLUGIN_TARGET_TYPE=STATIC_LIBRARY")
+
+_qt_internal_test_expect_pass(test_plugin_shared_static_flavor
+                              TESTNAME test_plugin_flavor_shared
+                              BUILD_OPTIONS
+                              "-DPLUGIN_OPTIONS=SHARED"
+                              "-DEXPECTED_PLUGIN_TARGET_TYPE=MODULE_LIBRARY")
+
+if(QT6_IS_SHARED_LIBS_BUILD)
+    set(expected_plugin_target_type "MODULE_LIBRARY")
+else()
+    set(expected_plugin_target_type "STATIC_LIBRARY")
+endif()
+
+# Check default computed value when no explicit option is set.
+_qt_internal_test_expect_pass(test_plugin_shared_static_flavor
+                              TESTNAME test_plugin_flavor_derived_from_qt_type
+                              BUILD_OPTIONS
+                              "-DPLUGIN_OPTIONS="
+                              "-DEXPECTED_PLUGIN_TARGET_TYPE=${expected_plugin_target_type}")
diff --git a/tests/auto/cmake/test_plugin_shared_static_flavor/CMakeLists.txt b/tests/auto/cmake/test_plugin_shared_static_flavor/CMakeLists.txt
new file mode 100644
index 0000000000..12d7affc51
--- /dev/null
+++ b/tests/auto/cmake/test_plugin_shared_static_flavor/CMakeLists.txt
@@ -0,0 +1,31 @@
+cmake_minimum_required(VERSION 3.14)
+
+project(test_plugin_flavor)
+
+if (EXISTS "${CMAKE_CURRENT_LIST_DIR}/FindPackageHints.cmake")
+    include("${CMAKE_CURRENT_LIST_DIR}/FindPackageHints.cmake")
+endif()
+
+find_package(Qt6Core REQUIRED HINTS ${Qt6Tests_PREFIX_PATH})
+
+qt6_add_plugin(test_plugin ${PLUGIN_OPTIONS})
+
+set(plugin_source_path "${CMAKE_CURRENT_BINARY_DIR}/plugin.cpp")
+file(GENERATE OUTPUT "${plugin_source_path}" CONTENT "int foo() {return 0;}")
+target_sources(test_plugin PRIVATE "${plugin_source_path}")
+
+get_target_property(plugin_target_type test_plugin TYPE)
+
+if(NOT EXPECTED_PLUGIN_TARGET_TYPE)
+    message(FATAL_ERROR "No value given for EXPECTED_PLUGIN_TARGET_TYPE variable")
+endif()
+
+if(NOT plugin_target_type STREQUAL "${EXPECTED_PLUGIN_TARGET_TYPE}")
+    set(info "")
+    list(APPEND info "PLUGIN_OPTIONS: ${PLUGIN_OPTIONS}")
+    list(APPEND info "QT6_IS_SHARED_LIBS_BUILD: ${QT6_IS_SHARED_LIBS_BUILD}")
+    list(APPEND info "EXPECTED_PLUGIN_TARGET_TYPE: ${EXPECTED_PLUGIN_TARGET_TYPE}")
+    list(JOIN info "\n" info)
+    message(FATAL_ERROR
+            "Computed plugin target type '${plugin_target_type}' did not match expected type '${EXPECTED_PLUGIN_TARGET_TYPE}'\n${info}")
+endif()