Say hello to Android multi arch build in one go

Multi arch build in one go is need to support the new .aab packaging format.

By default the users apps are built for all Android ABIs: arm64-v8a armeabi-v7a x86_64 x86
The user can pass ANDROID_ABIS to qmake to filter the ABIs during development,
e.g. qmake ANDROID_ABIS="arm64-v8a armeabi-v7a" will build only for arm ABIs.

[ChangeLog][Android] Android multi arch build in one go,
needed to support the new .aab packaging format.

Change-Id: I3a64caf9621c2a195863976a62a57cdf47e6e3b5
Reviewed-by: Eskil Abrahamsen Blomfeldt <eskil.abrahamsen-blomfeldt@qt.io>

4 files changed, 113 insertions, 34 deletions

diff --git a/mkspecs/features/android/android.prf b/mkspecs/features/android/android.prf
index 0e6f4a4592..a12c17c4ed 100644
--- a/mkspecs/features/android/android.prf
+++ b/mkspecs/features/android/android.prf
@@ -16,17 +16,22 @@ APK_PATH = $$shell_path($$OUT_PWD/android-build/$${TARGET}.apk)
 }
 QMAKE_EXTRA_TARGETS *= apk apk_install_target
 
-contains(TEMPLATE, ".*app") {
-    !android_app {
-        !contains(TARGET, ".so"): TARGET = lib$${TARGET}.so
-        QMAKE_LFLAGS += -Wl,-soname,$$shell_quote($$TARGET)
+build_pass {
+    contains(TEMPLATE, ".*app") {
+        !android_app {
+            !contains(TARGET, ".so") {
+                single_arch:TARGET = lib$${TARGET}.so
+                       else:TARGET = lib$${TARGET}_$${QT_ARCH}.so
+            }
+            QMAKE_LFLAGS += -Wl,-soname,$$shell_quote($$TARGET)
 
-        android_install {
-            target.path=/libs/$$ANDROID_TARGET_ARCH/
-            INSTALLS *= target
+            android_install {
+                target.path=/libs/$$ANDROID_TARGET_ARCH/
+                INSTALLS *= target
+            }
         }
+    } else: contains(TEMPLATE, "lib"):!static:!QTDIR_build:android_install {
+        target.path = /libs/$$ANDROID_TARGET_ARCH/
+        INSTALLS *= target
     }
-} else: contains(TEMPLATE, "lib"):!static:!QTDIR_build:android_install {
-    target.path = /libs/$$ANDROID_TARGET_ARCH/
-    INSTALLS *= target
 }
diff --git a/mkspecs/features/android/android_deployment_settings.prf b/mkspecs/features/android/android_deployment_settings.prf
index 48943fa0f4..998a985bb5 100644
--- a/mkspecs/features/android/android_deployment_settings.prf
+++ b/mkspecs/features/android/android_deployment_settings.prf
@@ -17,32 +17,21 @@ contains(TEMPLATE, ".*app"):!build_pass:!android-embedded {
     isEmpty(NDK_ROOT): NDK_ROOT = $$DEFAULT_ANDROID_NDK_ROOT
     FILE_CONTENT += "   \"ndk\": $$emitString($$NDK_ROOT),"
 
-    equals(ANDROID_USE_LLVM, true) {
-        FILE_CONTENT += "   \"toolchain-prefix\": \"llvm\","
-        FILE_CONTENT += "   \"tool-prefix\": \"llvm\","
-    } else {
-        NDK_TOOLCHAIN_PREFIX = $$(ANDROID_NDK_TOOLCHAIN_PREFIX)
-        isEmpty(NDK_TOOLCHAIN_PREFIX) {
-            equals(ANDROID_TARGET_ARCH, x86): NDK_TOOLCHAIN_PREFIX = x86
-            else: equals(ANDROID_TARGET_ARCH, x86_64): NDK_TOOLCHAIN_PREFIX = x86_64
-            else: equals(ANDROID_TARGET_ARCH, arm64-v8a): NDK_TOOLCHAIN_PREFIX = aarch64-linux-android
-            else: NDK_TOOLCHAIN_PREFIX = arm-linux-androideabi
-        }
-        FILE_CONTENT += "   \"toolchain-prefix\": $$emitString($$NDK_TOOLCHAIN_PREFIX),"
-        FILE_CONTENT += "   \"tool-prefix\": $$emitString($$NDK_TOOLS_PREFIX),"
-    }
-
-    NDK_TOOLCHAIN_VERSION = $$(ANDROID_NDK_TOOLCHAIN_VERSION)
-    isEmpty(NDK_TOOLCHAIN_VERSION): NDK_TOOLCHAIN_VERSION = $$DEFAULT_ANDROID_NDK_TOOLCHAIN_VERSION
-    FILE_CONTENT += "   \"toolchain-version\": $$emitString($$NDK_TOOLCHAIN_VERSION),"
+    FILE_CONTENT += "   \"toolchain-prefix\": \"llvm\","
+    FILE_CONTENT += "   \"tool-prefix\": \"llvm\","
 
     NDK_HOST = $$(ANDROID_NDK_HOST)
     isEmpty(NDK_HOST): NDK_HOST = $$DEFAULT_ANDROID_NDK_HOST
     FILE_CONTENT += "   \"ndk-host\": $$emitString($$NDK_HOST),"
 
-    ANDROID_TARGET_ARCH = $$(ANDROID_TARGET_ARCH)
-    isEmpty(ANDROID_TARGET_ARCH): ANDROID_TARGET_ARCH = $$DEFAULT_ANDROID_TARGET_ARCH
-    FILE_CONTENT += "   \"target-architecture\": $$emitString($$ANDROID_TARGET_ARCH),"
+    for (arch, ANDROID_ABIS) {
+        equals(arch, x86): libs_arch = i686-linux-android
+        else: equals(arch, x86_64): libs_arch = x86_64-linux-android
+        else: equals(arch, arm64-v8a): libs_arch = aarch64-linux-android
+        else: libs_arch = arm-linux-androideabi
+        ARCHS += "$$emitString($$arch):$$emitString($$libs_arch)"
+    }
+    FILE_CONTENT += "   \"architectures\": {$$join(ARCHS,", ")},"
 
     # Explicitly set qt dependencies of application for deployment
     !isEmpty(ANDROID_DEPLOYMENT_DEPENDENCIES): \
@@ -74,9 +63,8 @@ contains(TEMPLATE, ".*app"):!build_pass:!android-embedded {
         QML_ROOT_PATH = $$_PRO_FILE_PWD_
     FILE_CONTENT += "   \"qml-root-path\": $$emitString($$QML_ROOT_PATH),"
     FILE_CONTENT += "   \"stdcpp-path\": $$emitString($$ANDROID_STDCPP_PATH),"
-    FILE_CONTENT += "   \"useLLVM\": $$ANDROID_USE_LLVM,"
-
-    FILE_CONTENT += "   \"application-binary\": $$emitString($$absolute_path($$DESTDIR, $$OUT_PWD)/$$TARGET)"
+    FILE_CONTENT += ""
+    FILE_CONTENT += "   \"application-binary\": $$emitString($$TARGET)"
     FILE_CONTENT += "}"
 
     isEmpty(ANDROID_DEPLOYMENT_SETTINGS_FILE): ANDROID_DEPLOYMENT_SETTINGS_FILE = $$OUT_PWD/android-$$TARGET-deployment-settings.json
diff --git a/mkspecs/features/android/default_pre.prf b/mkspecs/features/android/default_pre.prf
new file mode 100644
index 0000000000..d4f84a8fcc
--- /dev/null
+++ b/mkspecs/features/android/default_pre.prf
@@ -0,0 +1,76 @@
+load(default_pre)
+
+build_pass:armeabi-v7a {
+    QT_ARCH = armeabi-v7a
+} else:build_pass:arm64-v8a {
+    QT_ARCH = arm64-v8a
+} else:build_pass:x86 {
+    QT_ARCH = x86
+} else:build_pass:x86_64 {
+    QT_ARCH = x86_64
+} else {
+    # default architecture
+    QT_ARCH = arm64-v8a
+}
+
+DEFAULT_ANDROID_TARGET_ARCH=$${QT_ARCH}
+
+ANDROID_TARGET_ARCH = $$(ANDROID_TARGET_ARCH)
+isEmpty(ANDROID_TARGET_ARCH): ANDROID_TARGET_ARCH = $$DEFAULT_ANDROID_TARGET_ARCH
+
+# Follow https://android.googlesource.com/platform/ndk/+/ndk-release-r20/docs/BuildSystemMaintainers.md
+
+equals(ANDROID_TARGET_ARCH, armeabi-v7a): \
+    QMAKE_CFLAGS = -target armv7a-linux-androideabi$$replace(ANDROID_PLATFORM, "android-", "")
+else: equals(ANDROID_TARGET_ARCH, arm64-v8a): \
+    QMAKE_CFLAGS = -target aarch64-linux-android$$replace(ANDROID_PLATFORM, "android-", "")
+else: equals(ANDROID_TARGET_ARCH, x86): \
+    QMAKE_CFLAGS = -target i686-linux-android$$replace(ANDROID_PLATFORM, "android-", "") -mstackrealign
+else: equals(ANDROID_TARGET_ARCH, x86_64): \
+    QMAKE_CFLAGS = -target x86_64-linux-android$$replace(ANDROID_PLATFORM, "android-", "")
+
+QMAKE_CFLAGS += -fno-limit-debug-info
+
+QMAKE_LINK    = $$QMAKE_CXX $$QMAKE_CFLAGS
+
+ANDROID_STDCPP_PATH = $$NDK_LLVM_PATH/sysroot/usr/lib/
+
+# -fstack-protector-strong offers good protection against stack smashing attacks.
+# It is (currently) enabled only on Android because we know for sure that Android compilers supports it
+QMAKE_CFLAGS += -fPIC -fstack-protector-strong -DANDROID
+
+
+equals(ANDROID_TARGET_ARCH, armeabi-v7a) | equals(ANDROID_TARGET_ARCH, armeabi) {
+    CONFIG               += optimize_size
+    QMAKE_CFLAGS_DEBUG    = -g -marm -O0
+    QMAKE_CFLAGS_RELEASE += -mthumb
+    QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO += -mthumb
+}
+
+QMAKE_CXXFLAGS_RELEASE_WITH_DEBUGINFO = $$QMAKE_CFLAGS_RELEASE_WITH_DEBUGINFO
+
+QMAKE_CXXFLAGS          = $$QMAKE_CFLAGS
+QMAKE_CXXFLAGS_WARN_ON  = $$QMAKE_CFLAGS_WARN_ON
+QMAKE_CXXFLAGS_WARN_OFF = $$QMAKE_CFLAGS_WARN_OFF
+QMAKE_CXXFLAGS_RELEASE  = $$QMAKE_CFLAGS_RELEASE
+QMAKE_CXXFLAGS_DEBUG    = $$QMAKE_CFLAGS_DEBUG
+QMAKE_CXXFLAGS_SHLIB    = $$QMAKE_CFLAGS_SHLIB
+QMAKE_CXXFLAGS_YACC     = $$QMAKE_CFLAGS_YACC
+QMAKE_CXXFLAGS_THREAD   = $$QMAKE_CFLAGS_THREAD
+
+QMAKE_LIBS_EGL          = -lEGL
+QMAKE_LIBS_OPENGL_ES2   = -lGLESv2
+
+# modifications to linux.conf
+QMAKE_AR                = $${CROSS_COMPILE}ar cqs
+QMAKE_OBJCOPY           = $${CROSS_COMPILE}objcopy
+QMAKE_NM                = $${CROSS_COMPILE}nm -P
+
+QMAKE_STRIP             =
+#$${CROSS_COMPILE}strip
+
+QMAKE_RANLIB            = $${CROSS_COMPILE}ranlib
+QMAKE_LINK_SHLIB        = $$QMAKE_LINK
+QMAKE_LFLAGS            =
+
+QMAKE_LIBS_PRIVATE      = -llog -lz -lm -ldl -lc
diff --git a/mkspecs/features/android/resolve_config.prf b/mkspecs/features/android/resolve_config.prf
new file mode 100644
index 0000000000..c542017e31
--- /dev/null
+++ b/mkspecs/features/android/resolve_config.prf
@@ -0,0 +1,10 @@
+load(resolve_config)
+
+!host_build:!single_arch:!java:android {
+    isEmpty(ANDROID_ABIS): ANDROID_ABIS = $$ALL_ANDROID_ABIS
+
+    ALL_ABIS = $$join(ANDROID_ABIS, _and_)
+    CONFIG += $$ALL_ABIS build_all
+    addExclusiveBuildsProper($$ALL_ABIS, $$ANDROID_ABIS)
+    unset(ALL_ABIS)
+}