Share the multi-arch infrastructure between UIKit and macOS

There's no reason for this to be separated, regardless of the
support status of i386 macOS builds. Additional architectures may
appear in the future (and currently there's actually 3 - i386,
x86_64, and x86_64h for Haswell CPUs). So this feature could be
used to get combined generic x86_64 and Haswell builds. Some
system libraries appear to have an x86_64h slice in Sierra.

[ChangeLog][Build System] Support for universal binaries on macOS
has been re-introduced.

Change-Id: I1c89904addf024431fdb3ad03ea8ab85da7240ad
Reviewed-by: Oswald Buddenhagen <oswald.buddenhagen@theqtcompany.com>
Reviewed-by: Jake Petroules <jake.petroules@qt.io>

2 files changed, 92 insertions, 40 deletions

diff --git a/mkspecs/features/mac/default_post.prf b/mkspecs/features/mac/default_post.prf
index 7e6a845024..c799487354 100644
--- a/mkspecs/features/mac/default_post.prf
+++ b/mkspecs/features/mac/default_post.prf
@@ -1,4 +1,9 @@
 load(default_post)
+
+# Ensure that we process sdk.prf first, as it will update QMAKE_CXX
+# and friends that other features/extra compilers may depend on.
+sdk: load(sdk)
+
 !no_objective_c:CONFIG += objective_c
 
 qt {
@@ -33,18 +38,54 @@ qt {
 
 !bitcode: QMAKE_LFLAGS += $$QMAKE_LFLAGS_HEADERPAD
 
-macx-xcode:!isEmpty(QMAKE_XCODE_DEBUG_INFORMATION_FORMAT) {
-    debug_information_format.name = DEBUG_INFORMATION_FORMAT
-    debug_information_format.value = $$QMAKE_XCODE_DEBUG_INFORMATION_FORMAT
-    debug_information_format.build = debug
-    QMAKE_MAC_XCODE_SETTINGS += debug_information_format
+macx-xcode {
+    !isEmpty(QMAKE_XCODE_DEBUG_INFORMATION_FORMAT) {
+        debug_information_format.name = DEBUG_INFORMATION_FORMAT
+        debug_information_format.value = $$QMAKE_XCODE_DEBUG_INFORMATION_FORMAT
+        debug_information_format.build = debug
+        QMAKE_MAC_XCODE_SETTINGS += debug_information_format
+    }
+
+    QMAKE_XCODE_ARCHS =
+
+    arch_device.name = "ARCHS[sdk=$${device.sdk}*]"
+    arch_device.value = $$QMAKE_APPLE_DEVICE_ARCHS
+    QMAKE_XCODE_ARCHS += $$QMAKE_APPLE_DEVICE_ARCHS
+    QMAKE_MAC_XCODE_SETTINGS += arch_device
+
+    simulator {
+        arch_simulator.name = "ARCHS[sdk=$${simulator.sdk}*]"
+        arch_simulator.value = $$QMAKE_APPLE_SIMULATOR_ARCHS
+        QMAKE_XCODE_ARCHS += $$QMAKE_APPLE_SIMULATOR_ARCHS
+        QMAKE_MAC_XCODE_SETTINGS += arch_simulator
+    }
+
+    only_active_arch.name = ONLY_ACTIVE_ARCH
+    only_active_arch.value = YES
+    only_active_arch.build = debug
+    QMAKE_MAC_XCODE_SETTINGS += only_active_arch
+} else {
+    VALID_ARCHS =
+    !simulator|simulator_and_device: VALID_ARCHS += $$QMAKE_APPLE_DEVICE_ARCHS
+    simulator: VALID_ARCHS += $$QMAKE_APPLE_SIMULATOR_ARCHS
+
+    single_arch: VALID_ARCHS = $$first(VALID_ARCHS)
+
+    ACTIVE_ARCHS = $(filter $(EXPORT_VALID_ARCHS), $(ARCHS))
+    ARCH_ARGS = $(foreach arch, $(if $(EXPORT_ACTIVE_ARCHS), $(EXPORT_ACTIVE_ARCHS), $(EXPORT_VALID_ARCHS)), -arch $(arch))
+
+    QMAKE_EXTRA_VARIABLES += VALID_ARCHS ACTIVE_ARCHS ARCH_ARGS
+
+    arch_flags = $(EXPORT_ARCH_ARGS)
+
+    QMAKE_CFLAGS += $$arch_flags
+    QMAKE_CXXFLAGS += $$arch_flags
+    QMAKE_LFLAGS += $$arch_flags
+
+    QMAKE_PCH_ARCHS = $$VALID_ARCHS
 }
 
 cache(QMAKE_XCODE_DEVELOPER_PATH, stash)
 cache(QMAKE_XCODE_VERSION, stash)
 
 QMAKE_XCODE_LIBRARY_SUFFIX = $$qtPlatformTargetSuffix()
-
-# Ensure that we process sdk.prf first, as it will update QMAKE_CXX
-# and friends that other features/extra compilers may depend on.
-sdk: load(sdk)
diff --git a/mkspecs/features/mac/sdk.prf b/mkspecs/features/mac/sdk.prf
index 0d43fbe5a1..087212f45b 100644
--- a/mkspecs/features/mac/sdk.prf
+++ b/mkspecs/features/mac/sdk.prf
@@ -49,25 +49,33 @@ for(tool, $$list(QMAKE_CC QMAKE_CXX QMAKE_FIX_RPATH QMAKE_AR QMAKE_RANLIB QMAKE_
 }
 
 !equals(MAKEFILE_GENERATOR, XCODE) {
-    uikit:!host_build {
-        ios: deployment_target = $$QMAKE_IOS_DEPLOYMENT_TARGET
-        tvos: deployment_target = $$QMAKE_TVOS_DEPLOYMENT_TARGET
-        watchos: deployment_target = $$QMAKE_WATCHOS_DEPLOYMENT_TARGET
-
-        !simulator|simulator_and_device: device_archs = $$QMAKE_APPLE_DEVICE_ARCHS
-        simulator: simulator_archs = $$QMAKE_APPLE_SIMULATOR_ARCHS
-        archs = $$device_archs $$simulator_archs
+    macos: deployment_target = $$QMAKE_MACOSX_DEPLOYMENT_TARGET
+    ios: deployment_target = $$QMAKE_IOS_DEPLOYMENT_TARGET
+    tvos: deployment_target = $$QMAKE_TVOS_DEPLOYMENT_TARGET
+    watchos: deployment_target = $$QMAKE_WATCHOS_DEPLOYMENT_TARGET
+
+    !simulator|simulator_and_device: device_archs = $$QMAKE_APPLE_DEVICE_ARCHS
+    simulator: simulator_archs = $$QMAKE_APPLE_SIMULATOR_ARCHS
+    archs = $$device_archs $$simulator_archs
+
+    single_arch {
+        device_archs = $$first(device_archs)
+        simulator_archs = $$first(simulator_archs)
+        archs = $$first(archs)
+    }
 
+    # If we're doing a simulator_and_device build, device and simulator architectures
+    # use different paths and flags for the sysroot and deployment target switch, so we
+    # must multiplex them across multiple architectures using -Xarch. Otherwise we fall
+    # back to the simple path. This is not strictly necessary but results in cleaner
+    # command lines and makes it easier for people to override EXPORT_VALID_ARCHS to
+    # limit individual rules to a different set of architecture(s) from the overall
+    # build (such as machtest in QtCore).
+    simulator_and_device {
         QMAKE_XARCH_CFLAGS =
         QMAKE_XARCH_LFLAGS =
         QMAKE_EXTRA_VARIABLES += QMAKE_XARCH_CFLAGS QMAKE_XARCH_LFLAGS
 
-        single_arch {
-            device_archs = $$first(device_archs)
-            simulator_archs = $$first(simulator_archs)
-            archs = $$first(archs)
-        }
-
         for(arch, archs) {
             contains(simulator_archs, $$arch) {
                 sdk = $$simulator.sdk
@@ -95,27 +103,30 @@ for(tool, $$list(QMAKE_CC QMAKE_CXX QMAKE_FIX_RPATH QMAKE_AR QMAKE_RANLIB QMAKE_
                 QMAKE_XARCH_LFLAGS_$${arch}
         }
 
-        QMAKE_CFLAGS_USE_PRECOMPILE =
-        for(arch, archs) {
-            QMAKE_CFLAGS_USE_PRECOMPILE += \
-                -Xarch_$${arch} \
-                -include${QMAKE_PCH_OUTPUT_$${arch}}
-        }
-        QMAKE_CXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
-        QMAKE_OBJCFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
-        QMAKE_OBJCXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
-
-        QMAKE_PCH_OUTPUT_EXT = _${QMAKE_PCH_ARCH}$${QMAKE_PCH_OUTPUT_EXT}
-    } else: osx {
-        version_identifier = macosx
-        deployment_target = $$QMAKE_MACOSX_DEPLOYMENT_TARGET
+        QMAKE_CFLAGS += $(EXPORT_QMAKE_XARCH_CFLAGS)
+        QMAKE_CXXFLAGS += $(EXPORT_QMAKE_XARCH_CFLAGS)
+        QMAKE_LFLAGS += $(EXPORT_QMAKE_XARCH_LFLAGS)
+    } else {
+        simulator: \
+            version_identifier = $$simulator.deployment_identifier
+        else: \
+            version_identifier = $$device.deployment_identifier
         version_min_flag = -m$${version_identifier}-version-min=$$deployment_target
         QMAKE_CFLAGS += -isysroot $$QMAKE_MAC_SDK_PATH $$version_min_flag
         QMAKE_CXXFLAGS += -isysroot $$QMAKE_MAC_SDK_PATH $$version_min_flag
         QMAKE_LFLAGS += -Wl,-syslibroot,$$QMAKE_MAC_SDK_PATH $$version_min_flag
     }
 
-    QMAKE_CFLAGS += $(EXPORT_QMAKE_XARCH_CFLAGS)
-    QMAKE_CXXFLAGS += $(EXPORT_QMAKE_XARCH_CFLAGS)
-    QMAKE_LFLAGS += $(EXPORT_QMAKE_XARCH_LFLAGS)
+    # Enable precompiled headers for multiple architectures
+    QMAKE_CFLAGS_USE_PRECOMPILE =
+    for(arch, archs) {
+        QMAKE_CFLAGS_USE_PRECOMPILE += \
+            -Xarch_$${arch} \
+            -include${QMAKE_PCH_OUTPUT_$${arch}}
+    }
+    QMAKE_CXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+    QMAKE_OBJCFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+    QMAKE_OBJCXXFLAGS_USE_PRECOMPILE = $$QMAKE_CFLAGS_USE_PRECOMPILE
+
+    QMAKE_PCH_OUTPUT_EXT = _${QMAKE_PCH_ARCH}$${QMAKE_PCH_OUTPUT_EXT}
 }